nix: Setup home-manager

Profiles added for:
- Generic `qutrc` user on ARM64 machines
- `qutrc@big-brain`: ARM64
- `qutrc@medium-brain`: ARM64
- `qutrc@gcs`: x86-64

flake.nix

@@ -32,6 +32,10 @@
       url = "github:numtide/treefmt-nix";
       inputs.nixpkgs.follows = "nixpkgs";
     };
+    home-manager = {
+      url = "github:nix-community/home-manager";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
   };
   outputs =
     {
@@ -45,7 +49,7 @@
       pyproject-build-systems,
       treefmt-nix,
       ...
-    }:
+    }@inputs:
     nix-ros-overlay.inputs.flake-utils.lib.eachDefaultSystem (
       system:
       let
@@ -247,7 +251,10 @@
           # formatting = treefmtEval.config.build.check self;
         };
       }
-    );
+    )
+    // {
+      homeConfigurations = (import ./software/home-manager/default.nix) inputs;
+    };
   nixConfig = {
     # note from James Nichol - I set up a custom cache at https://qutrc-roar.cachix.org
     # Currently I'm compiling for x86-64 and aarch64 on my machine and pushing to it whenever I make changes

software/home-manager/cli-programs/bat.nix

@@ -0,0 +1,18 @@
+{ pkgs, ... }:
+{
+  programs.bat = {
+    enable = true;
+    package = pkgs.unstable.bat;
+    extraPackages = with pkgs.bat-extras; [
+      batdiff
+      batman
+      batgrep
+      prettybat
+    ];
+  };
+  home.shellAliases = {
+    # bat extra tools
+    man = "batman";
+    bgrp = "batgrep";
+  };
+}

software/home-manager/cli-programs/default.nix

@@ -0,0 +1,16 @@
+{ ... }:
+{
+  imports = [
+    ./editors
+    ./search-tools
+
+    ./bat.nix
+    ./direnv.nix
+    ./eza.nix
+    ./git.nix
+    ./misc-utils.nix
+    ./nix.nix
+    ./term-multiplexing.nix
+    ./zoxide.nix
+  ];
+}

software/home-manager/cli-programs/direnv.nix

@@ -0,0 +1,17 @@
+{ pkgs, ... }:
+{
+  programs.direnv = {
+    enable = true;
+    nix-direnv.enable = true;
+    config = {
+      global = {
+        hide_env_diff = true;
+      };
+    };
+  };
+  programs.zsh.oh-my-zsh = {
+    plugins = [
+      "direnv"
+    ];
+  };
+}

software/home-manager/cli-programs/editors/default.nix

@@ -0,0 +1,10 @@
+{ pkgs, ... }:
+{
+  imports = [
+    ./neovim.nix
+  ];
+  home.packages = with pkgs; [
+    nano
+    vim
+  ];
+}

software/home-manager/cli-programs/editors/neovim.nix

@@ -0,0 +1,14 @@
+{ ... }:
+{
+  programs.neovim = {
+    enable = true;
+  };
+
+  home.sessionVariables = {
+    EDITOR = "nvim";
+  };
+
+  home.shellAliases = {
+    n = "nvim";
+  };
+}

software/home-manager/cli-programs/eza.nix

@@ -0,0 +1,14 @@
+{ ... }:
+{
+  programs.eza = {
+    enable = true;
+  };
+  home.shellAliases = {
+    # ls -> eza
+    ls = "eza --icons=auto";
+    la = "eza -a --icons=auto";
+    ll = "eza -al --icons=auto";
+    lt = "eza -RT --icons=auto --git-ignore";
+    llt = "eza -alRT --icons=auto --git-ignore";
+  };
+}

software/home-manager/cli-programs/git.nix

@@ -0,0 +1,31 @@
+{ pkgs, ... }:
+{
+  programs.git = {
+    enable = true;
+    delta = {
+      enable = true;
+      options = {
+        # https://dandavison.github.io/delta/hyperlinks.html
+        hyperlinks = true;
+        hyperlinks-file-link-format = "vscode://file/{path}:{line}";
+        navigate = true;
+        side-by-side = true;
+        line-numbers = true;
+        true-color = "always";
+      };
+    };
+    extraConfig = {
+      diff = {
+        color-moved = "default";
+      };
+      merge = {
+        # https://dandavison.github.io/delta/merge-conflicts.html
+        conflict-style = "zdiff3";
+      };
+    };
+  };
+  programs.gh = {
+    enable = true;
+    package = pkgs.unstable.gh;
+  };
+}

software/home-manager/cli-programs/misc-utils.nix

@@ -0,0 +1,16 @@
+{ pkgs, ... }:
+{
+  home.packages = with pkgs; [
+    wishlist
+    tldr
+    iperf3
+  ];
+
+  programs.btop = {
+    enable = true;
+    settings = {
+      update_ms = 200;
+      cpu_graph_lower = "user";
+    };
+  };
+}

software/home-manager/cli-programs/nix.nix

@@ -0,0 +1,19 @@
+{ pkgs, username, ... }:
+{
+  programs.nh = {
+    enable = true;
+    flake = "/home/${username}/perseus-v2";
+  };
+  home.packages = with pkgs; [
+    nix-output-monitor
+    nixd
+  ];
+
+  home.shellAliases = {
+    and = "nom develop";
+    nds = "nom develop -c $SHELL";
+    nb = "nom build";
+    nfc = "nix flake check --impure .";
+    nhs = "nh home switch";
+  };
+}

software/home-manager/cli-programs/search-tools/default.nix

@@ -0,0 +1,8 @@
+{ ... }:
+{
+  imports = [
+    ./fzf.nix
+  ];
+  programs.fd.enable = true;
+  programs.ripgrep.enable = true;
+}

software/home-manager/cli-programs/search-tools/fzf.nix

@@ -0,0 +1,9 @@
+{ ... }:
+{
+  programs.fzf.enable = true;
+  programs.zsh.oh-my-zsh = {
+    plugins = [
+      "fzf"
+    ];
+  };
+}

software/home-manager/cli-programs/term-multiplexing.nix

@@ -0,0 +1,44 @@
+{
+  pkgs,
+  lib,
+  config,
+  ...
+}:
+{
+  options = {
+    programs.tmux.bg-color = lib.mkOption {
+      type = lib.types.str;
+      default = "color32"; # default to a nice blue
+    };
+  };
+  config = {
+    programs.tmux = {
+      shortcut = "space";
+      clock24 = true;
+      terminal = "tmux-256color";
+      extraConfig = ''
+        set -g status-bg ${config.programs.tmux.bg-color}
+      '';
+      tmuxinator.enable = config.programs.tmux.enable;
+      tmuxp.enable = config.programs.tmux.enable;
+    };
+    programs.zsh = {
+      oh-my-zsh = lib.mkIf config.programs.tmux.enable {
+        plugins = [
+          "tmux"
+        ];
+      };
+      initExtra = lib.mkIf config.programs.zellij.enable ''
+        eval "$(zellij setup --generate-auto-start=zsh)"
+      '';
+    };
+
+    programs.zellij = {
+      enable = true;
+      package = pkgs.unstable.zellij;
+      enableBashIntegration = config.programs.bash.enable;
+      enableZshIntegration = config.programs.zsh.enable;
+      settings = { };
+    };
+  };
+}

software/home-manager/cli-programs/tmux.nix

@@ -0,0 +1,32 @@
+{
+  lib,
+  options,
+  config,
+  ...
+}:
+{
+  options = {
+    programs.tmux.bg-color = lib.mkOption {
+      type = lib.types.str;
+      default = "color32"; # default to a nice teal
+    };
+  };
+  config = {
+    programs.tmux = {
+      enable = true;
+      shortcut = "space";
+      clock24 = true;
+      terminal = "tmux-256color";
+      extraConfig = ''
+        set -g status-bg ${config.programs.tmux.bg-color}
+      '';
+      tmuxinator.enable = true;
+      tmuxp.enable = true;
+    };
+    programs.zsh.oh-my-zsh = {
+      plugins = [
+        "tmux"
+      ];
+    };
+  };
+}

software/home-manager/cli-programs/zoxide.nix

@@ -0,0 +1,9 @@
+{ ... }:
+{
+  programs.zoxide.enable = true;
+  home.shellAliases = {
+    # cd -> zoxide
+    cd = "z";
+    ".." = "z ..";
+  };
+}