chore: wip nix

flake.nix

@@ -0,0 +1,26 @@
+{
+  description = "pygls: The Generic Language Server Framework";
+
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
+    utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = { self, nixpkgs, utils }:
+
+    utils.lib.eachDefaultSystem(system:
+      let
+        pkgs = import nixpkgs { inherit system; };
+        python-wasi = pkgs.callPackage ./nix/python-wasi.nix {};
+        # TODO: Perhaps an overlay would allow callPackage to know what python-wasi is.
+        mkPythonWASIShell = pkgs.callPackage ./nix/python.nix { python-wasi = python-wasi; };
+      in {
+
+        devShells.default = mkPythonWASIShell {
+          pyPackages = with pkgs.python311Packages; [
+            lsprotocol
+          ];
+        };
+      }
+    );
+}

nix/python-wasi.nix

@@ -0,0 +1,17 @@
+{ fetchzip, stdenv }:
+
+stdenv.mkDerivation {
+  pname = "python-wasi";
+  version = "3.11.4";
+
+  src = fetchzip {
+    url = "https://github.com/brettcannon/cpython-wasi-build/releases/download/v3.11.4/python-3.11.4-wasi_sdk-16.zip";
+    stripRoot = false;
+    sha256 = "sha256-AZGdgpRvHcu6FY/a7capldjDhTpkfhGkqYnm127nAN8=";
+  };
+
+  buildCommand = ''
+   mkdir $out
+   cp -r $src/* $out
+  '';
+}

nix/python.nix

@@ -0,0 +1,32 @@
+{ lib
+, python-wasi
+, mkShell
+, stdenv
+, wasmtime
+, writeShellScriptBin
+}:
+
+{ pyPackages ? []
+}:
+
+let
+
+  pyDeps = lib.concatMap (pkg: lib.remove pkg.pythonModule pkg.requiredPythonModules) pyPackages;
+  allPackages = lib.unique (pyPackages ++ pyDeps);
+
+  pythonPath = lib.concatMapStringsSep ":" (pkg: "${pkg}/lib/python3.11/site-packages") allPackages;
+
+  python = writeShellScriptBin "python-wasi" ''
+   exec ${wasmtime}/bin/wasmtime run ${python-wasi}/python.wasm \
+     --env PYTHONHOME=${python-wasi} \
+     --env PYTHONPATH='.:${pythonPath}' \
+     --dir ${python-wasi} \
+     ${lib.concatMapStringsSep "\\\n  " (pkg: "--dir '${pkg}/lib/python3.11/site-packages' ") allPackages} \
+     --dir . \
+     -- "$@"
+  '';
+
+in mkShell {
+  name = "python-wasi";
+  packages = [ python ];
+}