feat: nix development environment for subnet

m1/avalanche-network-runner.nix

@@ -0,0 +1,28 @@
+{ pkgs ? import <nixpkgs> {} }:
+
+pkgs.buildGoModule rec {
+  pname = "avalanche-network-runner";
+  version = "1.7.5";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "ava-labs";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "A54KNB9BGKvGp2UsP46U5HteiCOOKrnYatDXUAc/BIg=";
+  };
+
+  vendorHash = null;
+  vendor = true;
+
+  nativeBuildInputs = with pkgs; [git cacert blst];
+  buildInputs = with pkgs; [cacert blst];
+
+  buildPhase = ''
+    export GOPROXY=direct
+    go build -v -ldflags="-X 'github.com/ava-labs/avalanche-network-runner/cmd.Version=${version}'" -mod=readonly
+  '';
+
+  installPhase = ''
+    install -Dm755 ./avalanche-network-runner $out/bin/avalanche-network-runner
+  '';
+}

m1/flake.nix

@@ -0,0 +1,93 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    rust-overlay.url = "github:oxalica/rust-overlay";
+    flake-utils.url = "github:numtide/flake-utils";
+  };
+
+  outputs = {
+    self,
+    nixpkgs,
+    rust-overlay,
+    flake-utils,
+    ...
+    }:
+    flake-utils.lib.eachSystem ["aarch64-darwin" "x86_64-linux"] (
+      system: let
+        overlays = [(import rust-overlay)];
+        pkgs = import nixpkgs {
+          inherit system overlays;
+        };
+        avalanche-network-runner = import ./avalanche-network-runner.nix { inherit pkgs; };
+
+        rust = pkgs.rust-bin.fromRustupToolchainFile ./rust-toolchain;
+
+        rustPlatform = pkgs.makeRustPlatform {
+          cargo = rust;
+          rustc = rust;
+        };
+
+        runtimeDependencies = with pkgs; [
+          openssl
+        ];
+
+        frameworks = pkgs.darwin.apple_sdk.frameworks;
+
+        buildDependencies = with pkgs; [
+            libclang.lib
+            libz
+            clang
+            pkg-config
+            rustPlatform.bindgenHook]
+          ++ runtimeDependencies
+          ++ lib.optionals stdenv.isDarwin [
+            frameworks.Security
+            frameworks.CoreServices
+            frameworks.SystemConfiguration
+            frameworks.AppKit
+          ];
+
+        developmentDependencies = with pkgs; [
+            rust
+            avalanchego
+            avalanche-network-runner
+          ]
+          ++ buildDependencies;
+
+        subnet-cargo-toml = builtins.fromTOML (builtins.readFile ./subnet/Cargo.toml);
+      in
+        with pkgs; {
+          packages = flake-utils.lib.flattenTree rec {
+            subnet = rustPlatform.buildRustPackage {
+              pname = subnet-cargo-toml.package.name;
+              version = subnet-cargo-toml.package.version;
+
+              env = { LIBCLANG_PATH = "${libclang.lib}/lib"; }
+              // (lib.optionalAttrs (stdenv.cc.isClang && stdenv.isDarwin) { NIX_LDFLAGS = "-l${stdenv.cc.libcxx.cxxabi.libName}"; });
+
+              src = ./.;
+              cargoLock = {
+                lockFile = ./Cargo.lock;
+              };
+
+              nativeBuildInputs = buildDependencies;
+              buildInputs = runtimeDependencies;
+
+              doCheck = false;
+            };
+
+            default = subnet;
+          };
+
+          devShells.default = mkShell {
+            buildInputs = developmentDependencies;
+
+            shellHook = ''
+              ${lib.optionalString (stdenv.cc.isClang && stdenv.isDarwin) "export NIX_LDFLAGS='-l${stdenv.cc.libcxx.cxxabi.libName}'"}
+              export PATH=$PATH:${avalanche-network-runner}/bin
+              export LIBCLANG_PATH="${pkgs.libclang.lib}/lib"
+            '';
+          };
+        }
+    );
+}