feature/modular-outputs: Enable and refactor flake with modular outputs

.github/workflows/check.yaml

@@ -18,6 +18,8 @@ jobs:
         uses: cachix/install-nix-action@v30
         with:
           nix_path: nixpkgs=channel:nixos-unstable
+          extra_nix_config: |
+            experimental-features = flakes nix-command pipe-operators
 
       # - name: Set up Magic Nix Cache
       #   uses: DeterminateSystems/magic-nix-cache-action@main

checks/default.nix

@@ -3,7 +3,7 @@
   pre-commit-check = pre-commit-hooks.lib.${system}.run {
     src = ./.;
     hooks = {
-      nil.enable = true;
+      # nil.enable = true;
       nixfmt-rfc-style.enable = true;
       prettier = {
         enable = true;

flake.nix

@@ -45,6 +45,7 @@
 
     pre-commit-hooks = {
       url = "github:cachix/git-hooks.nix";
+      inputs.nixpkgs.follows = "nixpkgs";
     };
 
     sops-nix = {
@@ -59,29 +60,19 @@
       flake-utils,
       nixpkgs,
       pre-commit-hooks,
-      nix-darwin,
-      home-manager,
       ...
     }@inputs:
     let
-      callModule =
-        modulePath: extraArgs:
-        import modulePath ({ callModule = callModule; } // self.outputs // inputs // extraArgs);
+      inherit ((import ./lib/outputs.nix inputs).lib) callOutputs;
     in
-    {
-      darwinConfigurations = callModule ./darwinConfigurations { };
-      nixosConfigurations = callModule ./nixosConfigurations { };
-
-      inherit (callModule ./modules { }) darwinModules homeModules nixosModules;
-    }
-    // flake-utils.lib.eachDefaultSystem (
+    flake-utils.lib.eachDefaultSystem (
       system:
       let
         pkgs = import nixpkgs { inherit system; };
       in
       {
         # Checks pre-commit-hooks
-        checks = callModule ./checks { inherit system; };
+        checks = import ./checks { inherit pre-commit-hooks system; };
 
         # Development shell with necessary tools
         devShells =
@@ -101,5 +92,9 @@
         # Formatter for this flake
         formatter = pkgs.nixfmt-rfc-style;
       }
-    );
+    )
+    // callOutputs {
+      directory = ./.;
+      inherit inputs;
+    };
 }

homeConfigurations/mozilla.nix

@@ -1,9 +1,8 @@
-{
-  homeModules,
-  pkgs,
-  lib,
-  ...
-}:
+{ self, ... }:
+let
+  inherit (self) homeModules;
+in
+{ pkgs, lib, ... }:
 {
   imports = with homeModules; [
     Alacritty

homeConfigurations/personal.nix

@@ -1,9 +1,8 @@
-{
-  homeModules,
-  pkgs,
-  lib,
-  ...
-}:
+{ self, ... }:
+let
+  inherit (self) homeModules;
+in
+{ pkgs, lib, ... }:
 {
   imports = with homeModules; [
     Alacritty

nixosConfigurations/hosts/h2946065/configuration.nix → hosts/h2946065/configuration.nix

@@ -1,7 +1,11 @@
-{ nixosModules, pkgs, ... }:
+{ self, ... }@inputs:
+let
+  inherit (self) nixosModules;
+in
+{ pkgs, ... }:
 {
   imports = with nixosModules; [
-    ./virtual-disk-MBR.nix
+    (import ./virtual-disk-MBR.nix inputs)
     hardware.libvirtd
     nix
     personal-cloud

hosts/h2946065/outputs.nix

@@ -0,0 +1,13 @@
+{ nixpkgs, sops-nix, ... }@inputs:
+let
+  inherit (nixpkgs.lib) nixosSystem;
+in
+{
+  nixosConfigurations.h2946065 = nixosSystem {
+    modules = [
+      sops-nix.nixosModules.sops
+      (import ./configuration.nix inputs)
+      ../../secrets
+    ];
+  };
+}

darwinConfigurations/hosts/mozilla-macbook-pro.nix → hosts/michaels-mbp-mozilla/configuration.nix

@@ -1,6 +1,7 @@
-{ darwinModules, pkgs, ... }:
+{ self, ... }:
+{ pkgs, ... }:
 {
-  imports = with darwinModules; [
+  imports = with self.darwinModules; [
     environment
     home-manager
     nix
@@ -12,6 +13,11 @@
     config.allowUnfree = true;
   };
 
+  networking = {
+    computerName = "Michaels MacBook Pro at Mozilla";
+    hostName = "michaels-mbp-mozilla";
+  };
+
   users.users.mozilla = {
     createHome = true;
     description = "Michael van Straten";

hosts/michaels-mbp-mozilla/outputs.nix

@@ -0,0 +1,12 @@
+{ nix-darwin, home-manager, ... }@inputs:
+{
+  darwinConfigurations = {
+    "michaels-mbp-mozilla" = nix-darwin.lib.darwinSystem {
+      system = "aarch64-darwin";
+      modules = [
+        home-manager.darwinModule
+        (import ./configuration.nix inputs)
+      ];
+    };
+  };
+}

darwinConfigurations/hosts/personal-macbook-pro.nix → hosts/michaels-mbp/configuration.nix

@@ -1,4 +1,8 @@
-{ darwinModules, pkgs, ... }:
+{ self, ... }@inputs:
+let
+  inherit (self) darwinModules;
+in
+{ pkgs, ... }:
 {
   imports = with darwinModules; [
     environment
@@ -14,7 +18,7 @@
 
   networking = {
     computerName = "Michaels MacBook Pro";
-    hostName = "michaels-macbook-pro";
+    hostName = "michaels-mbp";
   };
 
   users.users.michaelvanstraten = {
@@ -29,7 +33,7 @@
 
   security.pam.enableSudoTouchIdAuth = true;
 
-  home-manager.users.michaelvanstraten = import ../../homeConfigurations/personal.nix;
+  home-manager.users.michaelvanstraten = import ../../homeConfigurations/personal.nix inputs;
 
   environment.systemPackages = with pkgs; [ darwin.trash ];
 }

hosts/michaels-mbp/outputs.nix

@@ -0,0 +1,12 @@
+{ nix-darwin, home-manager, ... }@inputs:
+{
+  darwinConfigurations = {
+    "michaels-mbp" = nix-darwin.lib.darwinSystem {
+      system = "aarch64-darwin";
+      modules = [
+        home-manager.darwinModule
+        (import ./configuration.nix inputs)
+      ];
+    };
+  };
+}

hosts/rack-01/intel-nucs/configuration.nix

@@ -0,0 +1,19 @@
+{ self, sops-nix, ... }:
+{ ... }:
+{
+  imports =
+    with self.nixosModules;
+    [
+      format.raw-efi
+      hardware.intel-nuc
+      nix
+      personal-cloud
+      ssh
+      users
+    ]
+    ++ [ sops-nix.nixosModules.sops ];
+
+  console.keyMap = "de";
+
+  system.stateVersion = "25.11";
+}

hosts/rack-01/intel-nucs/outputs.nix

@@ -0,0 +1,17 @@
+{ nixpkgs, self, ... }@inputs:
+let
+  inherit (nixpkgs.lib) nixosSystem;
+in
+({
+  nixosConfigurations = builtins.mapAttrs (
+    hostname: isMaster:
+    nixosSystem {
+      modules = [
+        (if isMaster then self.nixosModules.roles.k8s-master else self.nixosModules.roles.k8s-worker)
+        ../../../secrets
+        (import ./configuration.nix inputs)
+        { networking.hostName = hostname; }
+      ];
+    }
+  ) { "rack-01-k8s-master-nuc-01" = true; };
+})

lib/callModule.nix

@@ -0,0 +1,10 @@
+{ ... }@inputs:
+modulePath: _:
+let
+  module = import modulePath;
+  isFlakeModule =
+    module:
+    builtins.isFunction module
+    && (builtins.functionArgs module |> builtins.intersectAttrs inputs) != { };
+in
+if isFlakeModule module then module inputs else module

lib/callOutputs.nix

@@ -0,0 +1,19 @@
+{ nixpkgs, ... }@inputs':
+let
+  inherit (nixpkgs.lib.attrsets) recursiveUpdate;
+  inherit (nixpkgs.lib.filesystem) listFilesRecursive;
+in
+{
+  directory,
+  inputs ? inputs',
+  outputPattern ? ".*/outputs\\.nix$",
+}:
+let
+  isOutputFile = path: (builtins.match outputPattern path) != null;
+  evaluateOutputFile = outputFile: import outputFile inputs;
+in
+listFilesRecursive directory
+|> builtins.map (path: builtins.toString path)
+|> builtins.filter isOutputFile
+|> builtins.map evaluateOutputFile
+|> builtins.foldl' recursiveUpdate { }

lib/modulesFromDirectoryRecursive.nix

@@ -0,0 +1,10 @@
+{ self, nixpkgs, ... }:
+let
+  inherit (nixpkgs.lib.filesystem) packagesFromDirectoryRecursive;
+  inherit (self.lib) callModule;
+in
+directory:
+packagesFromDirectoryRecursive {
+  callPackage = callModule;
+  inherit directory;
+}

lib/outputs.nix

@@ -0,0 +1,7 @@
+inputs: {
+  lib = {
+    callModule = import ./callModule.nix inputs;
+    callOutputs = import ./callOutputs.nix inputs;
+    modulesFromDirectoryRecursive = import ./modulesFromDirectoryRecursive.nix inputs;
+  };
+}

modules/darwin/home-manager.nix

@@ -1,8 +1,6 @@
-{ specialArgs, ... }:
 {
   home-manager = {
     backupFileExtension = "before-home-manager";
-    extraSpecialArgs = specialArgs;
     useGlobalPkgs = true;
     useUserPackages = true;
     verbose = true;

modules/darwin/nix.nix

@@ -7,8 +7,9 @@
     linux-builder.enable = false;
     settings = {
       experimental-features = [
-        "nix-command"
         "flakes"
+        "nix-command"
+        "pipe-operators"
       ];
       trusted-users = [ "@admin" ];
     };

modules/darwin/packages.nix

@@ -1,4 +1,5 @@
-{ nixpkgs-firefox-darwin, pkgs, ... }:
+{ nixpkgs-firefox-darwin, ... }:
+{ pkgs, ... }:
 {
   nixpkgs = {
     overlays = [ nixpkgs-firefox-darwin.overlay ];

modules/home-manager/Alacritty.nix

@@ -1,4 +1,5 @@
-{ cyberdream-theme, pkgs, ... }:
+{ cyberdream-theme, ... }:
+{ pkgs, ... }:
 {
   fonts.fontconfig.enable = true;
   home.packages = [ pkgs.nerdfonts ];

modules/home-manager/Firefox.nix

@@ -1,4 +1,5 @@
-{ BetterFox, config, ... }:
+{ BetterFox, ... }:
+{ config, ... }:
 {
   programs.firefox = {
     # Let Firefox package be managed by the system