Merge pull request #5 from michaelvanstraten/initial-nixos-configs

Add initial nixos configuration for first rack machine

flake.nix

@@ -40,6 +40,28 @@
       ...
     }@inputs:
     {
+      nixosConfigurations =
+        let
+          lib = nixpkgs.lib;
+          hostConfigurations = lib.filesystem.listFilesRecursive ./nixos/hosts;
+        in
+        lib.mergeAttrsList (
+          builtins.map (
+            hostConfiguration:
+            let
+              nixosConfiguration = nixpkgs.lib.nixosSystem {
+                modules = [ hostConfiguration ];
+                specialArgs = {
+                  make-disk-image = import "${nixpkgs}/nixos/lib/make-disk-image.nix";
+                };
+              };
+            in
+            {
+              ${nixosConfiguration.config.networking.hostName} = nixosConfiguration;
+            }
+          ) hostConfigurations
+        );
+
       # apps = nixinate.nixinate.aarch64-linux self;
     }
     // flake-utils.lib.eachDefaultSystem (

nixos/hosts/rack-01/k8s-master-nuc-01.nix

@@ -0,0 +1,19 @@
+{ ... }:
+{
+  imports = [
+    ../../modules
+    ../../modules/hardware/intel-nuc.nix
+    ../../modules/roles/k8s-master.nix
+    ../../modules/format/raw-efi.nix
+  ];
+
+  networking.hostName = "rack-01-k8s-master-nuc-01";
+
+  _module.args.nixinate = {
+    host = "tarox-1";
+    sshUser = "michael";
+    buildOn = "remote";
+    substituteOnTarget = true;
+    hermetic = false;
+  };
+}

nixos/modules/default.nix

@@ -0,0 +1,12 @@
+{ ... }:
+{
+  system.stateVersion = "25.11";
+
+  console.keyMap = "de";
+
+  imports = [
+    ./nix.nix
+    ./ssh.nix
+    ./users.nix
+  ];
+}

nixos/modules/format/raw-efi.nix

@@ -0,0 +1,14 @@
+{
+  config,
+  lib,
+  pkgs,
+  make-disk-image,
+  ...
+}:
+{
+  system.build.disk-image = make-disk-image {
+    inherit config lib pkgs;
+    partitionTableType = "efi";
+    format = "raw";
+  };
+}

nixos/modules/hardware/intel-nuc.nix

@@ -0,0 +1,30 @@
+{ lib, ... }:
+{
+  nixpkgs.hostPlatform = "x86_64-linux";
+
+  boot = {
+    growPartition = true;
+    kernelParams = [ "console=tty0" ];
+    initrd.availableKernelModules = [ "uas" ];
+  };
+
+  fileSystems."/boot" = {
+    device = "/dev/disk/by-label/ESP";
+    fsType = "vfat";
+  };
+
+  boot.loader = {
+    timeout = lib.mkDefault 3;
+    grub = {
+      device = "nodev";
+      efiSupport = true;
+      efiInstallAsRemovable = true;
+    };
+  };
+
+  fileSystems."/" = {
+    device = "/dev/disk/by-label/nixos";
+    autoResize = true;
+    fsType = "ext4";
+  };
+}

nixos/modules/nix.nix

@@ -0,0 +1,13 @@
+{ pkgs, ... }:
+{
+  nix = {
+    package = pkgs.nix;
+    settings = {
+      experimental-features = [
+        "nix-command"
+        "flakes"
+      ];
+      trusted-users = [ "@wheel" ];
+    };
+  };
+}

nixos/modules/roles/k8s-master.nix

@@ -0,0 +1,10 @@
+{ lib, ... }:
+{
+  services.etcd.enable = true;
+  # services.kubernetes = {
+  #   apiserver.enable = lib.mkDefault true;
+  #   scheduler.enable = lib.mkDefault true;
+  #   controllerManager.enable = true;
+  #   kubelet.enable = true;
+  # };
+}

nixos/modules/ssh.nix

@@ -0,0 +1,11 @@
+{ ... }:
+{
+  services.openssh = {
+    enable = true;
+    ports = [ 62518 ];
+    settings = {
+      PasswordAuthentication = false;
+      PermitRootLogin = "no";
+    };
+  };
+}

nixos/modules/users.nix

@@ -0,0 +1,11 @@
+{ ... }:
+{
+  users.users.michael = {
+    extraGroups = [ "wheel" ];
+    isNormalUser = true;
+    openssh.authorizedKeys.keys = [
+      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIF8OCYTaHjQy7Y7bRmxzVwNBgnD9P21UQPzVpJ3NKwVV"
+    ];
+    initialPassword = "fsbEh&PzR9Eo";
+  };
+}