Add rules for outputting bsp dependencies (#97)

bazel_rules/bsp4bazel_setup.bzl → bazel_rules/bsp4bazel.bzl

@@ -1,4 +1,5 @@
 load("//private:load_tool.bzl", "load_tool")
+load("//private:bsp_workspace_deps.bzl", _bsp_workspace_deps = "bsp_workspace_deps")
 
 # <--- Updated automatically by release job
 _bsp4bazel_version = "0.0.30"
@@ -23,4 +24,10 @@ def _bsp4bazel_load(platform):
 
 def bsp4bazel_setup():
     _bsp4bazel_load("linux-x86")
-    _bsp4bazel_load("macos-x86")
+    _bsp4bazel_load("macos-x86")
+
+def bsp_workspace_deps(name = "bsp_workspace_deps"):
+    if (name != "bsp_workspace_deps"):
+        fail("name must be 'bsp_workspace_deps'")
+
+    _bsp_workspace_deps(name = name)

bazel_rules/bsp_target_info_aspect.bzl

@@ -62,7 +62,7 @@ def bsp_target_info_aspect_impl(target, ctx):
 
         return [
             OutputGroupInfo(
-                bsp_output = depset([json_output_file] + semanticdb_classpath + compile_classpath),
+                bsp_output = depset([json_output_file]),
             ),
         ]
 

bazel_rules/private/bsp_workspace_deps.bzl

@@ -0,0 +1,60 @@
+load("@io_bazel_rules_scala//scala/private/toolchain_deps:toolchain_deps.bzl", "find_deps_info_on")
+
+def _copy_files(ctx, files):
+    output_files = []
+
+    for file in files:
+        output_file = ctx.actions.declare_file(ctx.attr.name + "_" + file.basename)
+
+        ctx.actions.run_shell(
+            inputs = [file],
+            outputs = [output_file],
+            command = "cp {src} {out}".format(src = file.path, out = output_file.path),
+        )
+
+        output_files.append(output_file)
+
+    return output_files
+
+def _bsp_workspace_deps_impl(ctx):
+    """
+    This function copies the dependencies for the BSP workspace into a known output location.
+
+    Args:
+        ctx: The context object.
+
+    Returns:
+        A list of dependencies for the BSP workspace.
+    """
+
+    compile_classpath = [
+        file
+        for deps in find_deps_info_on(ctx, "@io_bazel_rules_scala//scala:toolchain_type", "scala_compile_classpath").deps
+        for file in deps[JavaInfo].compile_jars.to_list()
+    ]
+
+    # Why not use the class_jar in SemanticdbInfo? Because it's a string, not a File, so we can't pass
+    # pass it to outputs.
+    # https://github.com/bazelbuild/rules_scala/issues/1527
+    semanticdb_classpath = [
+        file
+        for deps in find_deps_info_on(ctx, "@io_bazel_rules_scala//scala:toolchain_type", "semanticdb").deps
+        for file in deps[JavaInfo].compile_jars.to_list()
+    ]
+
+    scalac_output_files = _copy_files(ctx, compile_classpath)
+    semanticdb_output_files = _copy_files(ctx, semanticdb_classpath)
+
+    json_output_file = ctx.actions.declare_file(ctx.attr.name + ".json")
+    output_struct = struct(
+        scalac = [file.path for file in scalac_output_files],
+        semanticdb = [file.path for file in semanticdb_output_files],
+    )
+    ctx.actions.write(json_output_file, json.encode_indent(output_struct))
+
+    return [DefaultInfo(files = depset(scalac_output_files + semanticdb_output_files + [json_output_file]))]
+
+bsp_workspace_deps = rule(
+    implementation = _bsp_workspace_deps_impl,
+    toolchains = ["@io_bazel_rules_scala//scala:toolchain_type"],
+)

bazel_rules/test/rules.test.scala

@@ -4,7 +4,7 @@
 
 class BazelRulesTest extends munit.FunSuite:
 
-  def testBazelAspect[T](dir: os.Path)(implicit loc: munit.Location): Unit = {
+  def testBazelRules[T](dir: os.Path)(implicit loc: munit.Location): Unit = {
     test(s"should output bsp_target_info.json for $dir") {
       os.proc(
         dir / "bazel",
@@ -20,6 +20,22 @@ class BazelRulesTest extends munit.FunSuite:
       assert(os.exists(dir / "bazel-bin" / "src" / "example" / "example_bsp_target_info.json"))
       assert(os.exists(dir / "bazel-bin" / "src" / "example" / "foo" / "foo_bsp_target_info.json"))
     }
+
+    test(s"should output bsp_workspace_deps.json for $dir") {
+      os.proc(
+        dir / "bazel",
+        "build",
+        "//:bsp_workspace_deps",
+      ).call(cwd = dir)
+
+      assert(os.exists(dir / "bazel-bin" / "bsp_workspace_deps.json"))
+
+      val json = os.read(dir / "bazel-bin" / "bsp_workspace_deps.json")
+      assert(json.contains("semanticdb-scalac"), "No semanticdb dep")
+      assert(json.contains("scala-reflect"), "No scala-reflect dep")
+      assert(json.contains("scala-library"), "No scala-library dep")
+      assert(json.contains("scala-compiler"), "No scala-compiler dep")
+    }
   }
 
   test("should build examples/simple-no-errors") {
@@ -39,5 +55,5 @@ class BazelRulesTest extends munit.FunSuite:
     assertEquals(result.exitCode, 1)
   }
 
-  testBazelAspect(os.pwd / "examples" / "simple-no-errors")
-  testBazelAspect(os.pwd / "examples" / "simple-with-errors")
+  testBazelRules(os.pwd / "examples" / "simple-no-errors")
+  testBazelRules(os.pwd / "examples" / "simple-with-errors")

examples/simple-no-errors/BUILD

@@ -0,0 +1,3 @@
+load("@bsp4bazel-rules//:bsp4bazel.bzl", "bsp_workspace_deps")
+
+bsp_workspace_deps()

examples/simple-no-errors/WORKSPACE

@@ -59,6 +59,6 @@ local_repository(
     path = "../../bazel_rules",
 )
 
-load("@bsp4bazel-rules//:bsp4bazel_setup.bzl", "bsp4bazel_setup")
+load("@bsp4bazel-rules//:bsp4bazel.bzl", "bsp4bazel_setup")
 
 bsp4bazel_setup()

examples/simple-with-errors/BUILD

@@ -0,0 +1,3 @@
+load("@bsp4bazel-rules//:bsp4bazel.bzl", "bsp_workspace_deps")
+
+bsp_workspace_deps()

examples/simple-with-errors/WORKSPACE

@@ -55,6 +55,6 @@ local_repository(
     path = "../../bazel_rules",
 )
 
-load("@bsp4bazel-rules//:bsp4bazel_setup.bzl", "bsp4bazel_setup")
+load("@bsp4bazel-rules//:bsp4bazel.bzl", "bsp4bazel_setup")
 
 bsp4bazel_setup()