build.gradle

plugins {
	id 'fabric-loom' version '1.0.12'
	id 'maven-publish'
	id 'com.github.johnrengelman.shadow' version '7.1.2'
	id 'de.undercouch.download' version '5.3.0'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
	implementation 'jakarta.xml.ws:jakarta.xml.ws-api:2.3.3'
	implementation 'com.sun.xml.ws:jaxws-rt:2.3.2'
	implementation 'com.sun.xml.ws:rt:2.3.2'


	implementation files('lib/vboxjws.jar')
	shadow files('lib/vboxjws.jar')
}

tasks.register('getVirtualBoxSDK') {
	src "https://download.virtualbox.org/virtualbox/${project.vboxsdk_version}/VirtualBoxSDK-${project.vboxsdk_version}-${project.vboxsdk_revision}.zip"
	dest file('tmp/VirtualBoxSDK.zip')

	doLast {
		copy { from zipTree(file('tmp/VirtualBoxSDK.zip')) into file('tmp') }
		copy { from file('tmp/sdk/bindings/webservice/java/jax-ws/vboxjws.jar') into file('lib') }
		delete file('tmp')
	}
}
tasks.ideaSyncTask.dependsOn(getVirtualBoxSDK)

shadowJar {
	 configurations = [project.configurations.shadow]
	 baseName = "${project.archives_base_name}"
	 classifier = 'dev'
	 archiveVersion = "${project.mod_version}"
}

tasks.remapJar.dependsOn shadowJar

processResources {
	inputs.property "version", project.version
	duplicatesStrategy = DuplicatesStrategy.EXCLUDE

	from(sourceSets.main.resources.srcDirs) {
		include "fabric.mod.json"
		expand "version": project.version
	}

	from(sourceSets.main.resources.srcDirs) {
		exclude "fabric.mod.json"
	}
}

tasks.withType(JavaCompile).configureEach {
	options.encoding = "UTF-8"
}

tasks.register('sourcesJar') {
	classifier = "sources"
	from sourceSets.main.allSource
}

jar {
	from "LICENSE"
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	repositories {
		// uncomment to publish to the local maven
		// mavenLocal()
	}
}