build.gradle

plugins {
    id 'fabric-loom' version '0.10-SNAPSHOT'
    id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

apply from: "./simpleunittest.gradle"

minecraft {
}

repositories {
    maven {
        name = "Half's Repo"
        url = "https://raw.githubusercontent.com/Devan-Kerman/Devan-Repo/master/"
    }
    maven {
        name = 'CottonMC'
        url = 'https://server.bbkr.space/artifactory/libs-release'
    }
    maven {
        name = "RetryLife - Release"
        url = "https://release.maven.retrylife.ca"
    }
    maven {
        url "https://cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    // Minimap mods
    modImplementation "curse.maven:xaerosminimap-263420:3511446"
    modImplementation "curse.maven:xaerosworldmap-317780:3526759"

    // JSON
    implementation 'com.google.code.gson:gson:2.8.6'

    // Use JUnit test framework
    testImplementation 'junit:junit:4.13'

}

processResources {
    inputs.property "version", project.version
    duplicatesStrategy 'include'
    from(sourceSets.main.resources.srcDirs) {
        include "fabric.mod.json"
        expand "version": project.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude "fabric.mod.json"
    }
}

// ensure that the encoding is set to UTF-8, no matter what the system default is
// this fixes some edge cases with special characters not displaying correctly
// see http://yodaconditions.net/blog/fix-for-java-file-encoding-problems-with-gradle.html
tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
// if it is present.
// If you remove this task, sources will not be generated.
task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = "sources"
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

task copyJar(type: Copy){
    dependsOn jar
    from file("$buildDir/libs/${rootProject.name}-${project.version}.jar")
    into file("$buildDir/libs/")
    rename "${rootProject.name}-${project.version}.jar", "${rootProject.name}-release.jar"
}

// configure the maven publication
publishing {
    publications {
        mavenJava(MavenPublication) {
            // add all the jars that should be included when publishing to maven
            artifact(remapJar) {
                builtBy remapJar
            }
            artifact(sourcesJar) {
                builtBy remapSourcesJar
            }
        }
    }

    // select the repositories you want to publish to
    repositories {
        // uncomment to publish to the local maven
        // mavenLocal()
    }
}