build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'maven-publish'
    id 'com.github.ben-manes.versions' version '0.47.0'
}

group = 'cordelia'
version = '5.4.0.RELEASE' // semver from transmission server

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    withSourcesJar()
}

repositories {
    mavenCentral()
    maven {
        url "https://maven.sergeybochkov.com"
    }
}

dependencies {
    implementation platform('com.konghq:unirest-java-bom:4.0.3')
    implementation 'com.konghq:unirest-java-core'
    implementation 'com.konghq:unirest-objectmapper-jackson'
    implementation 'com.fasterxml.jackson.core:jackson-databind:2.15.2'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-jsr310:2.15.2'

    compileOnly 'ch.qos.logback:logback-classic:1.4.8'
    testImplementation 'ch.qos.logback:logback-classic:1.4.8'

    compileOnly 'org.projectlombok:lombok:1.18.28'
    annotationProcessor 'org.projectlombok:lombok:1.18.28'
    testCompileOnly 'org.projectlombok:lombok:1.18.28'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.28'

    testImplementation 'org.junit.jupiter:junit-jupiter:5.10.0'
    testImplementation 'org.assertj:assertj-core:3.24.2'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
}

tasks.named('test') {
    useJUnitPlatform()
}

publishing {
    repositories {
        maven {
            url = "https://maven.sergeybochkov.com/releases"
            credentials {
                username = "$reposilite_user"
                password = "$reposilite_password"
            }
        }
    }
    publications {
        maven(MavenPublication) {
            from components.java
        }
    }
}