sample-findr.taste

/*

Taste Examples on google.com, written in plain Findr style

 */

import com.google.common.base.Predicate
import org.openqa.selenium.By
import org.openqa.selenium.Keys
import org.openqa.selenium.WebElement

import static com.pojosontheweb.taste.Taste.*

suite('Google Tests Findr') {

    add test('text search') {

        webDriver.get 'http://www.google.com'

        findr()
            .elem(By.id('lst-ib'))
            .sendKeys('pojos on the web')

        findr()
            .elem(By.cssSelector('button.lsb'))
            .where(attrEquals('value', 'Search'))
            .click()

        findr()
            .elem(By.id('search'))
            .elemList(By.cssSelector('h3.r'))
            .at(0)
            .elem(By.tagName('a'))
            .where(textContains('POJOs on the Web'))
            .eval()

    }

    add test('images search') {

        webDriver.get 'http://www.google.com'

        findr()
            .elemList(By.tagName('a'))
            .where(textEquals('Images'))
            .at(0)
            .click()

        findr()
            .elem(By.id('lst-ib'))
            .sendKeys('pojos on the web', Keys.ENTER)

        findr()
            .elemList(By.cssSelector('a.rg_l'))
            .where({ WebElement e ->
            e.getAttribute('href').contains 'www.pojosontheweb.com'
        } as Predicate)
            .at(0)
            .click()

        findr()
            .elemList(By.cssSelector('a.irc_vpl.irc_but'))
            .where(textEquals('Visit page'))
            .at(0)
            .click()

        findr()
            .elem(By.cssSelector('div.jumbotron h1'))
            .where(textEquals('POJOs on the Web!'))
            .eval()
    }

}