build.gradle

apply plugin: 'com.android.library'

ext {
    libraryVersion = '0.1.1'
}

buildscript {
    repositories {
        jcenter()
        maven { url 'https://maven.google.com' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.2'
        classpath 'com.jfrog.bintray.gradle:gradle-bintray-plugin:1.7.3'
        classpath 'com.github.dcendents:android-maven-gradle-plugin:1.5'
    }
}

allprojects {
    repositories {
        jcenter()
        maven { url 'https://maven.google.com' }
    }
}

android {
    compileSdkVersion 25
    buildToolsVersion "25.0.3"

    defaultConfig {
        minSdkVersion 9
        targetSdkVersion 25
        versionCode 1
        versionName libraryVersion

        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"

    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {
        exclude group: 'com.android.support', module: 'support-annotations'
    })
    compile 'com.android.support:appcompat-v7:25.3.1'
    testCompile 'junit:junit:4.12'
}

apply plugin: 'com.github.dcendents.android-maven'
apply plugin: 'com.jfrog.bintray'

group = 'br.com.vivareal'
version = libraryVersion

install {
    repositories.mavenInstaller {
        pom.project {
            name 'Cuid Android'
            description 'Cuid implementation for Android projects'
            url 'https://github.com/VivaReal/cuid-android'
            inceptionYear '2016'

            packaging 'aar'
            groupId 'br.com.vivareal'
            artifactId 'cuid-android'
            version libraryVersion

            scm {
                connection 'https://github.com/VivaReal/cuid-android.git'
                url 'https://github.com/VivaReal/cuid-android'

            }

            licenses {
                license {
                    name 'MIT License'
                    url 'http://www.opensource.org/licenses/mit-license.php'
                }
            }

            developers {[
                    developer {
                        id 'marktani'
                        name 'Nilan Marktanner'
                        email 'nilan.marktanner@gmail.com'
                    },
                    developer {
                        id 'atoji'
                        name 'Alexandre Atoji'
                        email 'alexandre.atoji@vivareal.com'
                    },
            ]}
        }
    }
}

Properties properties = new Properties()
properties.load(project.rootProject.file('local.properties').newDataInputStream())

bintray {
    user = properties.getProperty("bintray.user")
    key = properties.getProperty("bintray.apikey")
    configurations = ['archives']
    pkg {
        repo = 'maven'
        name = 'cuid-android'
        userOrg = 'vivareal'
        licenses = ['MIT']
        vcsUrl = 'https://github.com/VivaReal/cuid-android.git'
        version {
            name = libraryVersion
            vcsTag = libraryVersion
        }
    }
}