build.gradle

plugins {
	id 'org.springframework.boot' version '2.5.4'
	id 'io.spring.dependency-management' version '1.0.11.RELEASE'
	id 'java'
	id "com.moowork.node" version "1.3.1"
}

apply plugin: "com.moowork.node"

group = 'com.naturemobility'
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}
ext {
	set('springCloudVersion', "2020.0.3")
}
dependencies {
	// Spring Boot Starter
	testImplementation 'org.springframework.boot:spring-boot-starter-test'

	// Lombok
	compileOnly 'org.projectlombok:lombok:1.18.22'
	annotationProcessor 'org.projectlombok:lombok:1.18.22'
	testCompileOnly 'org.projectlombok:lombok:1.18.22'
	testAnnotationProcessor 'org.projectlombok:lombok:1.18.22'

	//log4j
	compileOnly 'org.bgee.log4jdbc-log4j2:log4jdbc-log4j2-jdbc4:1.16'

	implementation group: 'ch.qos.logback', name: 'logback-core', version: '1.2.9'
	implementation group: 'ch.qos.logback', name: 'logback-classic', version: '1.2.9'
	implementation group: 'org.slf4j', name: 'slf4j-api', version: '1.7.32'
	implementation group: 'org.slf4j', name: 'jul-to-slf4j', version: '1.7.32'
	implementation group: 'org.apache.logging.log4j', name: 'log4j-to-slf4j', version: '2.16.0'
	implementation group: 'org.apache.logging.log4j', name: 'log4j-api', version: '2.16.0'

	// DB
	runtimeOnly 'mysql:mysql-connector-java'
	implementation 'org.mybatis.spring.boot:mybatis-spring-boot-starter:2.2.0'

	// Web
	implementation 'org.springframework.boot:spring-boot-starter-web'

	// Security, Authentication
	implementation 'org.springframework.boot:spring-boot-starter-security'
	implementation 'io.jsonwebtoken:jjwt-api:0.11.2'
	runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.2','io.jsonwebtoken:jjwt-jackson:0.11.2'

	// AOP
	implementation 'org.springframework.boot:spring-boot-starter-aop'

	//Config Server Client
	implementation 'org.springframework.cloud:spring-cloud-starter-config'
	implementation 'org.springframework.cloud:spring-cloud-starter-bootstrap'

	//actuator
	implementation 'org.springframework.boot:spring-boot-starter-actuator'

	//slack 설정
	implementation 'com.github.maricn:logback-slack-appender:1.4.0'

	//profile 마다 다른 logback 설정
	implementation 'org.codehaus.janino:janino:3.1.6'

	//Gson
	implementation 'com.google.code.gson:gson:2.8.7'

	//json
	implementation 'org.json:json:20220320'

	//redis
	implementation 'org.springframework.boot:spring-boot-starter-data-redis:2.4.0'

	//aws s3
	implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

	//temp
	annotationProcessor "org.springframework.boot:spring-boot-configuration-processor"

	//thymeleaf
	implementation 'org.springframework.boot:spring-boot-starter-thymeleaf:2.6.7'

	//Swagger
//	implementation 'io.springfox:springfox-boot-starter:3.0.0'
}

dependencyManagement {
	imports {
		mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
	}
}

test {
	useJUnitPlatform()
}


//react와 묶어서 빌드하기
//cmd에서 gradlew clean build 후 실행하면 8080포트에서도 react view가 나타남
def frontendDir = "$projectDir/../wholeinone-client"//react 프로젝트 주소

sourceSets {
	main {
		resources {
			srcDirs = ["$projectDir/src/main/resources"]
		}
	}
}

processResources {
	dependsOn "copyReactBuildFiles"
}

task installReact(type: Exec) {
	workingDir "$frontendDir"
	inputs.dir "$frontendDir"
	group = BasePlugin.BUILD_GROUP
	if (System.getProperty('os.name').toLowerCase(Locale.ROOT).contains('windows')) {
//		commandLine "npm.cmd", "audit", "fix"
		commandLine 'npm.cmd', 'install', "--save" ,"--legacy-peer-deps"
	} else {
//		commandLine "npm", "audit", "fix"
		commandLine 'npm', 'install', "--save" ,"--legacy-peer-deps"
	}
}

task buildReact(type: Exec) {
	dependsOn "installReact"
	workingDir "$frontendDir"
	inputs.dir "$frontendDir"
	group = BasePlugin.BUILD_GROUP
	if (System.getProperty('os.name').toLowerCase(Locale.ROOT).contains('windows')) {
		commandLine "npm.cmd", "run-script", "build"
	} else {
		commandLine "npm", "run-script", "build"
	}
}

task copyReactBuildFiles(type: Copy) {
	dependsOn "buildReact"
	from "$frontendDir/build"
	into "$projectDir/src/main/resources/static"
}