build.gradle

plugins {
	id 'fabric-loom' version '0.12-SNAPSHOT'
	id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

// Following by example, using semantic versioning
String v = 'v' + project.mod_version
if ("0" != project.release_candidate) {
	v += "-rc" + project.release_candidate
}
version = v + '+mc' + project.minecraft_version

repositories {
	// Add repositories to retrieve artifacts from in here.
	// You should only use this when depending on other mods because
	// Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
	// See https://docs.gradle.org/current/userguide/declaring_repositories.html
	// for more information about repositories.
	maven {
		name "SquidDev"
		url "https://squiddev.cc/maven"
	}

	mavenCentral()

	//maven { url 'https://jitpack.io' }


	maven {
		name "NucleMaven™"
		url "https://maven.nucleoid.xyz"
	}

	// Seems dead?
	maven {
		name "Basique's Maven"
		url "https://basique.top/maven"
	}
}

dependencies {
	// To change the versions see the gradle.properties file
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
	modImplementation include("org.squiddev:Cobalt:${project.cobalt}")
	modImplementation include("net.fabricmc:tiny-mappings-parser:${project.tiny_parser}")
	modImplementation include("me.basiqueevangelist:enhanced-reflection:${project.enhanced_reflections}")
	//modImplementation include("com.github.BasiqueEvangelist:EnhancedReflection:${project.enhanced_reflections}")
	modImplementation include("io.netty:netty-codec-http:4.1.77.Final")
	modImplementation "eu.pb4:placeholder-api:${project.placeholder_api}"


	// Used for testing Scripts. No code in the repo should depend on these
	//modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api}"
	//modImplementation "eu.pb4:polymer:${project.polymer}"
}

processResources {
	inputs.property "version", project.mod_version

	filesMatching("fabric.mod.json") {
		expand "mod_version": project.mod_version
	}
}

tasks.withType(JavaCompile).configureEach {
	// Minecraft 1.18 (1.18-pre2) upwards uses Java 17.
	it.options.release = 17
}

java {
	// Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
	// if it is present.
	// If you remove this line, sources will not be generated.
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${project.archives_base_name}"}
	}
}

// configure the maven publication
publishing {
	publications {
		mavenJava(MavenPublication) {
			from components.java
		}
	}

	// See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
	repositories {
		// Add repositories to publish to here.
		// Notice: This block does NOT have the same function as the block in the top level.
		// The repositories here will be used for publishing your artifact, not for
		// retrieving dependencies.
	}
}