build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '2.7.17'
    id 'io.spring.dependency-management' version '1.0.15.RELEASE'
    id 'jacoco'
}

group = 'kr.bb'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '11'
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

ext {
    set('springCloudVersion', "2021.0.8")
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.cloud:spring-cloud-starter-config'
    implementation 'org.springframework.cloud:spring-cloud-starter-netflix-eureka-client'
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    implementation "org.springframework.cloud:spring-cloud-starter-bus-kafka"
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'mysql:mysql-connector-java:8.0.33'
    runtimeOnly 'com.h2database:h2'
    implementation 'org.mapstruct:mapstruct:1.5.3.Final'
    annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.3.Final'
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.4.RELEASE'
    implementation 'org.springframework.cloud:spring-cloud-aws-messaging:2.2.4.RELEASE'
    implementation 'org.springframework.kafka:spring-kafka'
    implementation 'software.amazon.awssdk:sns:2.21.37'
    implementation 'io.github.lotteon-maven:blooming-blooms-utils:202401190225'
    // https://mvnrepository.com/artifact/org.springframework.boot/spring-boot-starter-aop
    implementation 'org.springframework.boot:spring-boot-starter-aop:2.7.17'
    // https://mvnrepository.com/artifact/io.micrometer/micrometer-registry-prometheus
    implementation 'io.micrometer:micrometer-registry-prometheus:1.12.2'


    // redis
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation("it.ozimov:embedded-redis:0.7.2")
    implementation 'org.redisson:redisson-spring-boot-starter:3.17.0'

    // testcontainers
    testImplementation "org.junit.jupiter:junit-jupiter:5.8.1"
    testImplementation "org.testcontainers:testcontainers:1.17.6"
    testImplementation "org.testcontainers:junit-jupiter:1.17.6"

    testImplementation 'org.mockito:mockito-core:4.8.0'

}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

tasks.named('bootBuildImage') {
    builder = 'paketobuildpacks/builder-jammy-base:latest'
}

tasks.named('test') {
    useJUnitPlatform()
}

// jacoco
jacoco {
    toolVersion = '0.8.5'
}

jacocoTestCoverageVerification {
    violationRules {
        rule {
            enabled = true
            element = 'CLASS'

            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.80
            }
            excludes = ["*.mapper*", "**.emitter.**", "**.infrastructure.**", "**.aop.**", "**.annotation.**"]
        }
    }
}

test {
    jacoco {
        destinationFile = file("$buildDir/jacoco/jacoco.exec")
        excludes += ["**/errors/**",
                     "**/api/**",
                     "**/mapper/**",
                     "**/handler/**",
                     "**/common/**",
                     "**/api/**",
                     "**/emitter/**",
                     "**/aop/**",
                     "**/annotation/**"
        ]
    }
    useJUnitPlatform()
    finalizedBy 'jacocoTestReport'
}

jacocoTestReport {
    reports {
        html.required = true
    }
    def Qdomains = []
    for (qPattern in '**/QA'..'**/QZ') {
        Qdomains.add(qPattern + '*')
    }
    afterEvaluate {
        classDirectories.setFrom(
                files(classDirectories.files.collect {
                    fileTree(dir: it, excludes: [
                            "**/*Application*",
                            "**/*generated*",
                            "**/*mapper*",
                            "**/*Config*",
                            "**/*Dto*",
                            "**/emitter/**",
                            "**/aop/**",
                            "**/annotation/**"
                    ] + Qdomains)
                })
        )
    }
    finalizedBy 'jacocoTestCoverageVerification'
}