Ctrl-r for shell history but also bulk select and remove from history

[rieje]

Ctrl-r is super useful for shell history but along with Enter to insert the command to the prompt, I would like (within the same Ctrl-r interface, preferably) to also switch to interface where selecting an entry removes it from history. It should support selecting multiple entries and repeat filtering to select additional entries to remove (only except with e.g. Ctrl-c).

Any ideas on how to implement this if it's not implemented already?

[LangLangBart]

Caution

Please note that this feature is experimental and should be used with caution. Some
users have reported issues with this feature, so use at your own risk. Additionally, it is not
being actively updated to match the latest changes in the original fzf version, which may result
in missing features or functionality.

This setup requires 3 things:

• a modified fzf-history-widget
• the assigned FZF_CTRL_R_OPTS environment variable with a complex keybinding for deletion and
  reloading
• assigned HISTFILE, HISTSIZE, and SAVEHIST environment variables

Note

The values assigned to FZF_CTRL_R_OPTS can also be incorporated into the modified
fzf-history-widget. However, I found this method simpler to avoid complications with quotation
marks.

If you place everything in your .zshrc, after sourcing fzf (source <(fzf --zsh)),
it should work seamlessly. The history will always be read from your $HISTFILE, thus I also set
this option:

setopt SHARE_HISTORY  # Share history between all sessions.

More details on how the deletion works can be found in: #3522

modified-fzf-history-widget() {
  local selected
  setopt localoptions noglobsubst noposixbuiltins pipefail no_aliases no_bash_rematch 2> /dev/null
  # appends the current shell history buffer to the HISTFILE
  builtin fc -AI $HISTFILE
  # pushes entries from the $HISTFILE onto a stack and uses this history
  builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST
  selected="$(builtin fc -rl 1 |
    awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, "", cmd); if (!seen[cmd]++) print $0 }' |
    FZF_DEFAULT_OPTS="--height ${FZF_TMUX_HEIGHT:-40%} ${FZF_DEFAULT_OPTS-} -n2..,.. --scheme=history --bind=ctrl-r:toggle-sort,ctrl-z:ignore ${FZF_CTRL_R_OPTS-} --query=${(qqq)LBUFFER} --multi" $(__fzfcmd))"
  local ret=$?
	if [[ -n $selected ]]; then
    if [[ "$selected" =~ ^[[:blank:]]*[[:digit:]]+ ]]; then
	  builtin fc -pa "$HISTFILE"
	  zle vi-fetch-history -n "$MATCH"
    else # selected is a custom query, not from history
      LBUFFER="$selected"
    fi
  fi
  # Read the history from the history file into the history list
  builtin fc -R $HISTFILE
  zle reset-prompt
  return $ret
}
zle -N modified-fzf-history-widget
bindkey "^R" modified-fzf-history-widget


export FZF_CTRL_R_OPTS="$(
	cat <<'FZF_FTW'
--bind "ctrl-d:execute-silent(zsh -ic 'builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; for i in {+1}; do ignore+=( \"${(b)history[$i]}\" );done;
	HISTORY_IGNORE=\"(${(j:|:)ignore})\";builtin fc -W $HISTFILE')+reload:builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; builtin fc -rl 1 |
	awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, \"\", cmd); if (!seen[cmd]++) print $0 }'"
--bind 'enter:accept-or-print-query'
--header 'enter select · ^d remove'
--prompt ' Global History > '
FZF_FTW
)"


# 'ZDOTDIR' is a Parameter used by the shell, it refers to the location of your 
# shell startup files (see 'man zshparam')
export HISTFILE="${ZDOTDIR:-$HOME}"/.zsh_history
export HISTSIZE=12000
export SAVEHIST=10000

EDIT: use builtin and read history when exiting fzf widget

[Drugoy]

@LangLangBart I tried, it works and reloads just fine in a container, but I either fail to follow your last instruction or it doesn't solve the problem outside the container.
How should the resulting FZF_CTRL_R_OPTS env look like, if zsh's binary path is /usr/bin/zsh?
like this?

export FZF_CTRL_R_OPTS="$(
	cat <<'FZF_FTW'
--with-shell='/usr/bin/zsh -fc'
--bind "ctrl-d:execute-silent(/usr/bin/zsh -ic 'builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; for i in {+1}; do ignore+=( \"${(b)history[$i]}\" ); done;
	HISTORY_IGNORE=\"(${(j:|:)ignore})\";builtin fc -W $HISTFILE')+reload:builtin fc -p $HISTFILE $HISTSIZE $SAVEHIST; builtin fc -rl 1 |
	awk '{ cmd=$0; sub(/^[ \t]*[0-9]+\**[ \t]+/, \"\", cmd); if (!seen[cmd]++) print $0 }'"
--bind 'enter:accept-or-print-query'
--header 'enter select · ^d remove'
--prompt ' Global History > '
FZF_FTW
)"

[LangLangBart]

--with-shell='/usr/bin/zsh -fc'

Yes, correct.

or it doesn't solve the problem outside the container.

I will add a note that the feature is experimental and should be used at your own risk. If you like
to continue you could provide your zsh options. I will try to reproduce it on my system. Any other
special zsh oddities do you use, anything in .zshenv? A public .dotfiles repo would be helpful.

unsetopt KSH_OPTION_PRINT
setopt

tested it with debian:12 as well (works in the container)

docker run --interactive --tty --rm debian:12 sh -c 'apt update && apt install -y wget zsh;
  mkdir /fzf-bin
  wget https://github.com/junegunn/fzf/releases/download/v0.57.0/fzf-0.57.0-linux_amd64.tar.gz
  tar -xvf fzf-0.57.0-linux_amd64.tar.gz -C /fzf-bin
  {
    echo "export PATH=\"/fzf-bin:\$PATH\""
    echo "source <(fzf --zsh)"
    echo "setopt interactivecomments share_history"
    echo "export FZF_DEFAULT_OPTS=\"--with-shell='\''/bin/zsh -fc'\''\""
  } >> ~/.zshrc; zsh'

[Drugoy]

I've debugged my ~/.zshrc to the point where I cut almost everything and the issue was still reproducible with it (even in the container).
Then I noticed that I had

HISTFILE=~/.histfile
HISTSIZE=100000
SAVEHIST=100000

in it instead of

export HISTFILE=~/.histfile
export HISTSIZE=100000
export SAVEHIST=100000

and that's what was breaking the functionality.
I remember trying to narrow down the number of exported variables 'to reduce the pollution' (in favor of just setting variables when possible) and now it finally bit my ass...

Thanks you, @LangLangBart !

[LangLangBart]

and that's what was breaking the functionality.

Thanks for pulling through (always good to know what the issue was). You might try to remove --with-shell from your FZF_CTRL_R_OPTS, it was suggested by me to ensure that the command is run with zsh.

Note

fzf runs the command with $SHELL -c if SHELL is set, otherwise with sh -c

[andrevmatos]

Thank you @LangLangBart , @Drugoy and @YasserKa .
That was it for me as well, and I managed to get it fixed by exporting the environment variables as well.
@YasserKa 's example seems to be more maintainable on the long run, but don't work with current fzf, which uses perl to handle multiline history entries. It'd be great to have a final/current version.
Thank you all.