Setting pylsp.plugins.jedi.environment dynamically in workspace function failing

[aricodes-oss]

Hey all! I'm migrating my configuration over from lsp-mode to eglot and I am relatively inexperienced with elisp. I'm assuming I'm just making a simple mistake here, but my usecase is as follows:

I have many Python projects I work on, almost all of which use Poetry for managing dependencies. Poetry maintains its own virtual environments transparently to the user, but you can get the location via the command poetry env info -p. Since this needs to be calculated for every Python buffer individually, I set eglot-workspace-configuration to a function. Here's the relevant snippet from my config:

(defun locate-venv (dir)
  "Find a poetry venv."
  ;;poetry env info -p
  (let ((stdout-buffer (generate-new-buffer "tmp-poetry-stdout"))
        (default-directory dir))
    (unwind-protect
      (let
        ((exit-status
           (condition-case
             nil
             (call-process "poetry" nil (list stdout-buffer nil) nil "env" "info" "-p")
             (file-missing nil))))
        (if (eq exit-status 0)
          (progn
            (with-current-buffer stdout-buffer
              (string-trim (buffer-string))))))
      (kill-buffer stdout-buffer))))

(setq-default eglot-workspace-configuration
  (lambda (&rest args)
    (let ((venv-directory (locate-venv default-directory)))
      (message "Located venv: %s" venv-directory)
      '((:pylsp .
          (:plugins
            (:jedi_completion (:fuzzy t))
            (:jedi (:environment venv-directory))
            (:pydocstyle (:enabled nil))
            (:pycodestyle (:enabled nil))
            (:mccabe (:enabled nil))
            (:pyflakes (:enabled nil))
            (:flake8 (:enabled t))
            (:black (:enabled t))))))))

The error I'm seeing is as follows:

error in process filter: jsonrpc--json-encode: Wrong type argument: symbolp, (:jedi (:environment venv-directory))
error in process filter: Wrong type argument: symbolp, (:jedi (:environment venv-directory))

I did see a similar question asked for configuring pyright in #967 but I lack the fluency in elisp to fully understand and translate that over to my setup. Is there something obvious I'm missing?

[joaotavora]

Indeed this seems to be mostly down to Elisp problems. Try this

(setq-default eglot-workspace-configuration
  (lambda (&rest args)
    (let ((venv-directory (locate-venv default-directory)))
      (message "Located venv: %s" venv-directory)
      `((:pylsp .
          (:plugins
            ((:jedi_completion (:fuzzy t))
             (:jedi (:environment ,venv-directory))
             (:pydocstyle (:enabled nil))
             (:pycodestyle (:enabled nil))
             (:mccabe (:enabled nil))
             (:pyflakes (:enabled nil))
             (:flake8 (:enabled t))
             (:black (:enabled t)))))))))

And avoid setting eglot-workspace-configuration globally. As outlined here it should be directory-local.

[aricodes-oss]

That did get the string interpolated properly, thank you!! Unfortunately it is still throwing a similar error.

error in process filter: jsonrpc--json-encode: Wrong type argument: symbolp, (:jedi (:environment "/home/ari/.cache/pypoetry/virtualenvs/testbed-CYu1U8TN-py3.10"))
error in process filter: Wrong type argument: symbolp, (:jedi (:environment "/home/ari/.cache/pypoetry/virtualenvs/testbed-CYu1U8TN-py3.10"))

Is it possible that I have the configuration structured incorrectly? This is the document I'm referencing to see what the options are: https://github.com/python-lsp/python-lsp-server/blob/develop/CONFIGURATION.md

And avoid setting eglot-workspace-configuration globally. As outlined #967 (reply in thread) it should be directory-local.

Agreed! This is in a .dir-locals.el file in the top-level folder that holds my Python projects, since all of them use this same (or very similar) configuration.

[joaotavora]

Hmm, try this:

(setq-default eglot-workspace-configuration
  (lambda (&rest args)
    (let ((venv-directory (locate-venv default-directory)))
      (message "Located venv: %s" venv-directory)
      `((:pylsp .
          (:plugins
            (:jedi_completion (:fuzzy t)
             :jedi (:environment ,venv-directory)
             :pydocstyle (:enabled nil)
             :pycodestyle (:enabled nil)
             :mccabe (:enabled nil)
             :pyflakes (:enabled nil)
             :flake8 (:enabled t)
             :black (:enabled t))))))))

[aricodes-oss]

Apologies for the extremely late response, I wound up going out of town unexpectedly for a while. This works perfectly!!

You have my sincere gratitude for getting this sorted out, especially so quickly. If it's not too much trouble, would you be able to explain why that worked? I'm having a hard time locating the relevant section of the elisp documentation.

[aricodes-oss]

Solved by @joaotavora in the comments section here! #1030 (reply in thread)

I'm reposting the solution here so that Github will show it as the top accepted answer.

(setq-default eglot-workspace-configuration
  (lambda (&rest args)
    (let ((venv-directory (locate-venv default-directory)))
      (message "Located venv: %s" venv-directory)
      `((:pylsp .
          (:plugins
            (:jedi_completion (:fuzzy t)
             :jedi (:environment ,venv-directory)
             :pydocstyle (:enabled nil)
             :pycodestyle (:enabled nil)
             :mccabe (:enabled nil)
             :pyflakes (:enabled nil)
             :flake8 (:enabled t)
             :black (:enabled t))))))))

[djrmarques]

Thanks a lot for this thread. I finally got pylsp to guess my poetry env correctly!

[aiguofer]

Wooop! it took me waaaay to long to accomplish this, I should have just googled sooner but I was being stubborn.

Regarding the directory-local nature of configs... In my case I'm doing the same as OP except using the pyenv prefix as my jedi path. This applies to every single python project on my machine, so I'd prefer to make that global.

If I create a .dir-locals.el, do those extend or replace the workspace config? I'd rather not have to copy-paste the logic for setting the jedi path on every single python project I work on, so it'd be great to do that in global and simply apply the specific configs on a per project basis.