build.gradle

import io.getstream.chat.android.Dependencies
import io.getstream.chat.android.Configuration

apply plugin: 'com.android.library'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-kapt'
apply plugin: 'de.mannodermaus.android-junit5'
apply plugin: 'org.jlleitschuh.gradle.ktlint'

ext {
    PUBLISH_GROUP_ID = Configuration.artifactGroup
    PUBLISH_ARTIFACT_ID = 'stream-chat-android-offline'
    PUBLISH_VERSION = rootVersionName
}

apply from: "${rootDir}/scripts/publish-module.gradle"
apply from: "${rootDir}/scripts/android.gradle"

android {
    defaultConfig {
        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }

    testOptions.unitTests {
        includeAndroidResources = true
        returnDefaultValues = true
        all {
            testLogging {
                events 'failed', 'standardOut', 'standardError'
                showExceptions true
                showCauses true
                showStackTraces true
                exceptionFormat 'full'
            }
        }
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
        debug {
            testCoverageEnabled true
        }
    }
}

kapt {
    arguments {
        arg("room.incremental", "true")
    }
}

tasks.withType(org.jetbrains.kotlin.gradle.tasks.KotlinCompile).all {
    kotlinOptions {
        freeCompilerArgs += [
                '-progressive',
                '-Xexplicit-api=strict',
                '-Xopt-in=kotlin.RequiresOptIn',
                '-Xopt-in=io.getstream.chat.android.core.internal.InternalStreamChatApi',
        ]
    }
}

dependencies {
    api project(":stream-chat-android-client")

    // Kotlin
    implementation Dependencies.kotlinReflect
    implementation Dependencies.coroutinesCore

    // Google libs
    implementation Dependencies.androidxAppCompat
    implementation Dependencies.androidxCoreKtx
    implementation Dependencies.androidxLifecycleLiveDataKtx
    implementation Dependencies.roomRuntime
    implementation Dependencies.roomKtx
    kapt Dependencies.roomCompiler
    implementation Dependencies.workRuntimeKtx

    // Serialization
    implementation Dependencies.moshi
    kapt Dependencies.moshiCodegen

    // Tests
    testImplementation project(":stream-chat-android-test")
    testImplementation Dependencies.moshiKotlin

    testImplementation Dependencies.junitJupiterApi
    testImplementation Dependencies.junitJupiterParams
    testRuntimeOnly Dependencies.junitJupiterEngine
    testRuntimeOnly Dependencies.junitVintageEngine

    testImplementation Dependencies.androidxTest
    testImplementation Dependencies.androidxTestJunit
    testImplementation Dependencies.androidxArchCoreTest
    testImplementation Dependencies.androidxRecyclerview // for performance test
    testImplementation Dependencies.roomTesting
    testImplementation Dependencies.workTesting

    testImplementation Dependencies.coroutinesTest

    testImplementation Dependencies.robolectric
    testImplementation Dependencies.dotenv

    testImplementation Dependencies.kfixture
    testImplementation Dependencies.kluent
    testImplementation Dependencies.mockito
    testImplementation Dependencies.mockitoKotlin

    // Instrumentation tests
    androidTestImplementation Dependencies.androidxTestJunit
    androidTestImplementation Dependencies.espressoCore
    androidTestImplementation Dependencies.junit4
    androidTestImplementation Dependencies.kluent
    androidTestImplementation Dependencies.mockito
    androidTestImplementation Dependencies.mockitoKotlin
}