forked from luciaconde/ring-n-run
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathRINGNRUN.asm
1833 lines (1509 loc) · 60.8 KB
/
RINGNRUN.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;********************************************************************************************************************************************************************
; Proyecto Ring&Run
; By Lucia Conde & Jimena Cabrejas
; Si quieres crowdfundear este proyecto, manda tus donativos a S1B49, Mesa 4
ORG 003;
GOTO PROGPAL ;
;************************************************************************************************************************************************************************
; REGISTROS
;************************************************************************************************************************************************************************
;********************************************************************************************************************************************************************
LIST P=16F887 ; Microcontrolador
;********************************************************************************************************************************************************************
; Registros y ctes propias del micro
INCLUDE "P16F887.INC"
;********************************************************************************************************************************************************************
; Registros particulares del sistema
HORDEC EQU 20 ; Decenas de hora del reloj
HORUNI EQU 21 ; Unidades de hora del reloj
MINDEC EQU 22 ; Decenas de minuto del reloj
MINUNI EQU 23 ; Unidades de minuto del reloj
SEGDEC EQU 24
SEGUNI EQU 25
TICK EQU 2E ; Marca de paso de 1 segundo
CONT EQU 37 ; Contador de llamadas en 1 segundo
TICK2 EQU 38
DESP_HORDEC EQU 26 ; Decenas de hora del despertador
DESP_HORUNI EQU 27 ; Unidades de hora del despertador
DESP_MINDEC EQU 28 ; Decenas de minuto del despertador
DESP_MINUNI EQU 29 ; Unidades de minuto del despertador
DESP EQU 36 ; 1: despertador programado, 0: no despertador
HOR1 EQU 3A ; Variable auxiliar para guardar las decenas de hora
HOR2 EQU 3B ; Variable auxiliar para guardar las unidadas de hora
MIN1 EQU 3C ; Variable auxiliar para guardar las decenas de minuto
EventoT EQU 2A ; Variable para el tipo de evento
EventoD EQU 2B ; Variable para el dato del evento
Tecla_aux EQU 2C ; Variable auxiliar
estado EQU 2D ; Variable de estado
NumRan EQU d'200' ; 200 ranuras a 100us cada una 20ms
ranura EQU 39 ; Variable de ranura de la máquina de tiempos
TEC_numv EQU 33 ; Teclado: número de veces estable
TEC_ant EQU 34 ; Teclado: tecla anterior
TEC_flg EQU 35 ; Teclado: flags de control
F_rep EQU 0 ; Teclado: flag de tecla reportada (bit 0)
TMP1 EQU 2F ; Variable temporal
TMP2 EQU 30 ; Variable temporal
; Variables para salvado durante interrupción
SAVEPCL EQU 7C ; Salvado de PCLATH
SAVEFSR EQU 7D ; Salvado de FSR
SAVEST EQU 7E ; Salvado de Status
SAVEW EQU 7F ; Salvado de W (7F, FF, 17F, 1FF)
;************************************************************************************************************************************************************************
; Configuración de tiempo de timer 2
prescal2 EQU d'4' ; Valor del prescaler (1,4,16)
rperiod EQU d'5' ; Valor en el registro de período (0-256)
postscal EQU d'5' ; Valor calculado para el postscaler (1-16)
;**********************************************************************************
; Configuración de tiempo de timer 0
prescal0 EQU d'5' ; Valor del prescaler según tabla
; (0=>2, 1=>4, 2=>8,... 7=>256, 8=>1)
cnttmr0 EQU d'125' ; Valor en contador(0-255)
;************************************************************************************************************************************************************************
; Registros del motor
P_SERVO EQU PORTA ; Puerto en el que l oenganchas
b_SERVO EQU 2
servo_val EQU 40
servo_cnt EQU 41 ;
;************************************************************************************************************************************************************************
; Registros del piezoeléctrico
P_SOUND EQU PORTC ;
b_SOUND EQU 1 ; En que punto del puerto A lo enganchas, atención todo menos el 6 y 7
sound_val EQU 42 ;
sound_cnt0 EQU 43 ;
sound_cnt1 EQU 44 ;
;************************************************************************************************************************************************************************
; Puertos LCD
P_LCDen EQU PORTD ; Puerto de bit de enable(strobe) LCD
b_LCDen EQU 4 ; bit de enable(strobe) LCD
P_LCDrw EQU PORTD ; Puerto de bit de read/write LCD
b_LCDrw EQU 5 ; bit de read/write LCD
P_LCDdi EQU PORTD ; Puerto de bit de dato/instruccion LCD
b_LCDdi EQU 6 ; bit de dato/instruccion LCD
P_LCDDA EQU PORTD ; Puerto de dato de LCD (4 bits menos significat.)
;************************************************************************************************************************************************************************
; Instrucciones LCD
lcd_clr EQU b'00000001' ; LCD clear
cur_hm EQU b'00000010' ; Cursor to home
cur_sa EQU b'10000000' ; Cursor to indicated position
cur_on EQU b'00001010' ; Cursor on
cur_off EQU b'00001000' ; Cursor off
cur_rm EQU b'00010100' ; Cursor right move
cur_lm EQU b'00010000' ; Cursor left move
cur_l2 EQU b'11000000' ; Cursor en segunda línea
cur_rma EQU b'00000110' ; Cursor auto right move
cur_lma EQU b'00000100' ; Cursor auto left move
cur_nor EQU b'00000110' ; Cursor auto-move normal (izq a dch)
cur_cal EQU b'00000111' ; Cursor auto-move calculadora (dch a izq)
;************************************************************************************************************************************************************************
; Constantes de tiempo (pueden variar segun frecuencia
; de operacion del microcontrolador)
klcdw EQU 0FFh ; Constante para pausa
;************************************************************************************************************************************************************************
; Configuración LCD
lcd_set EQU b'00101000' ; LCD: 4 bits, 2 líneas, 5x7 puntos
lcd_mod EQU b'00000110' ; Movimiento del cursor hacia la derecha
lcd_on EQU b'00001100' ; Display on, cursor off, blink off
lcd_off EQU b'00001000' ; Display off
lcd_to EQU d'200' ; Time-out para display ocupado
;************************************************************************************************************************************************************************
; Puerto de teclado
PKYBD EQU PORTB ; El teclado ocupa el puerto B de 8 bits
;************************************************************************************************************************************************************************
; Constantes de teclado
selc1 EQU B'00000111' ; Selección de columna 1
selc2 EQU B'00001011' ; Selección de columna 2
selc3 EQU B'00001101' ; Selección de columna 3
selc4 EQU B'00001110' ; Selección de columna 4
selca EQU B'00000000' ; Selección de todas las columnas
nminv EQU 10 ; Numero mínimo de veces para detectar estabilidad
;************************************************************************************************************************************************************************
;***************************************
;*** INTERRUPCIONES ***
ORG 004 ; Dirección de Interrupcion
;***************************************
;************************************************************************************************************************************************************************
;************************************************************************************************************************************************************************
; INTERR
; Atención a interrupciones
; Crea cada un tick cada segundo
INTERR: ; Salvado general de registros
MOVWF SAVEW ; el registro W
MOVF STATUS,W ; el Status
CLRF STATUS ;
MOVWF SAVEST ;
MOVF FSR,W ; el registro indirecto FSR
MOVWF SAVEFSR ;
MOVF PCLATH,W ; el registro PCLATH
MOVWF SAVEPCL ;
CLRF PCLATH ; Se trabajarán interrupciones en primera pagina
;******************* Interrupción por timer2
INTTMR2:
BTFSS PIR1,TMR2IF ; Comprueba si es interrupción por TMR2
GOTO SIGINT ; si no lo es, busca otra posible interrupción
; Caso que hay interrupción por TMR2
BCF PIR1,TMR2IF ; Se resetea interrupcion para prox. vez
CALL MAQTIE ; Se inicia la rutina de atención
CALL GENSONIDO ; Suena
GOTO RETINT ;
SIGINT:
;******************* Fin interrupción por timer2
RETINT: ; Recuperación general de registros y retorno
MOVF SAVEPCL,W ; el registro PCLATH
MOVWF PCLATH ;
MOVF SAVEFSR,W ; el registro indirecto FSR
MOVWF FSR ;
MOVF SAVEST,W ; el Status
MOVWF STATUS ;
SWAPF SAVEW,F ; el registro W
SWAPF SAVEW,W ;
RETFIE ;
;************************************************************************************************************************************************************************
;***************************************
;*** PROGRAMA PRINCIPAL ***
;***************************************
;************************************************************************************************************************************************************************
;************************************************************************************************************************************************************************
; PROGPAL
; Programa principal
PROGPAL:
CALL INITPORTS ; Inicializamos los puertos de la PICTOR
CALL INITTEC ; Inicializamos el teclado
CALL INITLCD ; Inicializamos la pantalla
CALL INITTMR2 ; Inicializamos la interrupción
CALL INITRELOJ ; Inicializamos el cronómetro
CALL SERVO_INIT ; Inicializamos el motor
CALL INITESTADO ; Inicializamos el estado (estado 0)
BSF INTCON,7 ; Pone el GIE a 1
CALL VISRELOJ ; Se visualiza el reloj (empieza en 00:00:00)
CLRF CONT ; Se inicializan las variables de Gentick
CLRF TICK ; Se limpia la variable lógica TICK
LAZO:
CALL LEETECLA ; Se lee una tecla, se guarda en w
CALL ELIMREB ; Se elimina el rebote, y se vuelve a guardar en w
CALL REPORTT ; Te quedas solo con la tecla pulsada
CALL ENVEVENTO ; Se aplica la función (evento) pulsada
CALL MAQUEST ; Vamos a la máquina de estados
GOTO LAZO
;************************************************************************************************************************************************************************
;** MAQTIE
;** Máquina de tiempos
;** Para optimizar tiempos, debe ser puesta en la subpágina 0 (000h-0FFh)
;** Debe llamarse desde una interrupción de tiempo
ORG 030 ; Debe estar subpágina 0 para optimización en tiempo
MAQTIE:
INCF ranura,F ; Se actualiza la ranura del tiempo
MOVLW -NumRan ; Se verifica que no se haya
ADDWF ranura,W ; superado el valor maximo
BTFSC STATUS,C ; de ranuras en caso contrario
CLRF ranura ; se inicialza
MOVF ranura,W ;Se toma el numero de la ranura
ADDWF PCL,F ;Se salta a la ranura correspondiente
GOTO SERVO_CYC0 ; Ranura 000 -> Inicio de ciclo del servo
RETURN ; Ranura 001 ->
RETURN ; Ranura 002 ->
RETURN ; Ranura 003 ->
RETURN ; Ranura 004 ->
GOTO SERVO_CYC1 ; Ranura 005 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 006 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 007 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 008 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 009 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 010 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 011 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 012 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 013 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 014 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 015 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 016 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 017 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 018 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 019 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 020 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 021 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 022 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 023 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 024 -> ...
GOTO SERVO_CYC1 ; Ranura 025 ->
GOTO SERVO_CYC1 ; Ranura 026 ->
GOTO SERVO_CYC1 ; Ranura 027 ->
GOTO SERVO_CYC1 ; Ranura 028 ->
GOTO SERVO_CYC1 ; Ranura 029 ->
GOTO SERVO_CYC1 ; Ranura 030 ->
GOTO SERVO_CYC1 ; Ranura 031 ->
GOTO SERVO_CYC1 ; Ranura 032 ->
GOTO SERVO_CYC1 ; Ranura 033 ->
GOTO SERVO_CYC1 ; Ranura 034 ->
GOTO SERVO_CYC1 ; Ranura 035 ->
GOTO SERVO_CYC1 ; Ranura 036 ->
GOTO SERVO_CYC1 ; Ranura 037 ->
GOTO SERVO_CYC1 ; Ranura 038 ->
GOTO SERVO_CYC1 ; Ranura 039 ->
GOTO SERVO_CYC1 ; Ranura 040 ->
GOTO SERVO_CYC1 ; Ranura 041 ->
GOTO SERVO_CYC1 ; Ranura 042 ->
GOTO SERVO_CYC1 ; Ranura 043 ->
GOTO SERVO_CYC1 ; Ranura 044 ->
GOTO SERVO_CYC1 ; Ranura 045 ->
GOTO SERVO_CYC1 ; Ranura 046 ->
GOTO SERVO_CYC1 ; Ranura 047 ->
GOTO SERVO_CYC1 ; Ranura 048 ->
GOTO SERVO_CYC1 ; Ranura 049 ->
GOTO SERVO_CYC1 ; Ranura 050 ->
GOTO SERVO_CYC1 ; Ranura 051 ->
GOTO SERVO_CYC1 ; Ranura 052 ->
GOTO SERVO_CYC1 ; Ranura 053 ->
GOTO SERVO_CYC1 ; Ranura 054 ->
GOTO SERVO_CYC1 ; Ranura 055 ->
GOTO SERVO_CYC1 ; Ranura 056 ->
GOTO SERVO_CYC1 ; Ranura 057 ->
GOTO SERVO_CYC1 ; Ranura 058 ->
GOTO SERVO_CYC1 ; Ranura 059 ->
GOTO SERVO_CYC1 ; Ranura 060 ->
GOTO SERVO_CYC1 ; Ranura 061 ->
GOTO SERVO_CYC1 ; Ranura 062 ->
GOTO SERVO_CYC1 ; Ranura 063 ->
GOTO SERVO_CYC1 ; Ranura 064 ->
GOTO SERVO_CYC1 ; Ranura 065 ->
GOTO SERVO_CYC1 ; Ranura 066 ->
GOTO SERVO_CYC1 ; Ranura 067 ->
GOTO SERVO_CYC1 ; Ranura 068 ->
GOTO SERVO_CYC1 ; Ranura 069 ->
GOTO SERVO_CYC1 ; Ranura 070 ->
GOTO SERVO_CYC1 ; Ranura 071 ->
GOTO SERVO_CYC1 ; Ranura 072 ->
GOTO SERVO_CYC1 ; Ranura 073 ->
GOTO SERVO_CYC1 ; Ranura 074 ->
GOTO SERVO_CYC1 ; Ranura 075 ->
GOTO SERVO_CYC1 ; Ranura 076 ->
GOTO SERVO_CYC1 ; Ranura 077 ->
GOTO SERVO_CYC1 ; Ranura 078 ->
GOTO SERVO_CYC1 ; Ranura 079 ->
GOTO SERVO_CYC1 ; Ranura 080 ->
GOTO SERVO_CYC1 ; Ranura 081 ->
GOTO SERVO_CYC1 ; Ranura 082 ->
GOTO SERVO_CYC1 ; Ranura 083 ->
GOTO SERVO_CYC1 ; Ranura 084 ->
GOTO SERVO_CYC1 ; Ranura 085 ->
GOTO SERVO_CYC1 ; Ranura 086 ->
GOTO SERVO_CYC1 ; Ranura 087 ->
GOTO SERVO_CYC1 ; Ranura 088 ->
GOTO SERVO_CYC1 ; Ranura 089 ->
GOTO SERVO_CYC1 ; Ranura 090 ->
GOTO SERVO_CYC1 ; Ranura 091 ->
GOTO SERVO_CYC1 ; Ranura 092 ->
GOTO SERVO_CYC1 ; Ranura 093 ->
GOTO SERVO_CYC1 ; Ranura 094 ->
GOTO SERVO_CYC1 ; Ranura 095 ->
GOTO SERVO_CYC1 ; Ranura 096 -> ...
GOTO SERVO_CYC1 ; Ranura 097 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 098 -> Ciclo del servo
GOTO SERVO_CYC1 ; Ranura 099 -> Ciclo del servo
GOTO SERVO_CYC2 ; Ranura 100 -> Fin de ciclo de servo (obligado)
RETURN ; Ranura 101 ->
RETURN ; Ranura 102 ->
RETURN ; Ranura 103 ->
RETURN ; Ranura 104 ->
RETURN ; Ranura 105 ->
RETURN ; Ranura 106 ->
RETURN ; Ranura 107 ->
RETURN ; Ranura 108 ->
RETURN ; Ranura 109 ->
RETURN ; Ranura 110 ->
RETURN ; Ranura 111 ->
RETURN ; Ranura 112 ->
RETURN ; Ranura 113 ->
RETURN ; Ranura 114 ->
RETURN ; Ranura 115 ->
RETURN ; Ranura 116 ->
RETURN ; Ranura 117 ->
RETURN ; Ranura 118 ->
RETURN ; Ranura 119 ->
RETURN ; Ranura 120 ->
RETURN ; Ranura 121 ->
RETURN ; Ranura 122 ->
RETURN ; Ranura 123 ->
RETURN ; Ranura 124 ->
RETURN ; Ranura 125 ->
RETURN ; Ranura 126 ->
RETURN ; Ranura 127 ->
RETURN ; Ranura 128 ->
RETURN ; Ranura 129 ->
RETURN ; Ranura 130 ->
RETURN ; Ranura 131 ->
RETURN ; Ranura 132 ->
RETURN ; Ranura 133 ->
RETURN ; Ranura 134 ->
RETURN ; Ranura 135 ->
RETURN ; Ranura 136 ->
RETURN ; Ranura 137 ->
RETURN ; Ranura 138 ->
RETURN ; Ranura 139 ->
RETURN ; Ranura 140 ->
RETURN ; Ranura 141 ->
RETURN ; Ranura 142 ->
RETURN ; Ranura 143 ->
RETURN ; Ranura 144 ->
RETURN ; Ranura 145 ->
RETURN ; Ranura 146 ->
RETURN ; Ranura 147 ->
RETURN ; Ranura 148 ->
RETURN ; Ranura 149 ->
RETURN ; Ranura 150 ->
RETURN ; Ranura 151 ->
RETURN ; Ranura 152 ->
RETURN ; Ranura 153 ->
RETURN ; Ranura 154 ->
RETURN ; Ranura 155 ->
RETURN ; Ranura 156 ->
RETURN ; Ranura 157 ->
RETURN ; Ranura 158 ->
RETURN ; Ranura 159 ->
RETURN ; Ranura 160 ->
RETURN ; Ranura 161 ->
RETURN ; Ranura 162 ->
RETURN ; Ranura 163 ->
RETURN ; Ranura 164 ->
RETURN ; Ranura 165 ->
RETURN ; Ranura 166 ->
RETURN ; Ranura 167 ->
RETURN ; Ranura 168 ->
RETURN ; Ranura 169 ->
RETURN ; Ranura 170 ->
RETURN ; Ranura 171 ->
RETURN ; Ranura 172 ->
RETURN ; Ranura 173 ->
RETURN ; Ranura 174 ->
RETURN ; Ranura 175 ->
RETURN ; Ranura 176 ->
RETURN ; Ranura 177 ->
RETURN ; Ranura 178 ->
RETURN ; Ranura 179 ->
RETURN ; Ranura 180 ->
RETURN ; Ranura 181 ->
RETURN ; Ranura 182 ->
RETURN ; Ranura 183 ->
RETURN ; Ranura 184 ->
RETURN ; Ranura 185 ->
RETURN ; Ranura 186 ->
RETURN ; Ranura 187 ->
RETURN ; Ranura 188 ->
RETURN ; Ranura 189 ->
RETURN ; Ranura 190 -> Generación de 1 seg
RETURN ; Ranura 191 ->
RETURN ; Ranura 192 ->
RETURN ; Ranura 193 ->
RETURN ; Ranura 194 ->
RETURN ; Ranura 195 ->
RETURN ; Ranura 196 ->
RETURN ; Ranura 197 ->
RETURN ; Ranura 198 ->
GOTO GENTICK ; Ranura 199 -> Tick de 20ms para tiempo
;************************************************************************************************************************************************************************
;***************************************
;*** TABLAS Y MÁQUINAS ***
ORG 100
;***************************************
;************************************************************************************************************************************************************************
;************************************************************************************************************************************************************************
; TABLAS DE TRADUCCIÓN
;************************************************************************************************************************************************************************
;************************************************************************************************************************************************************************
; TRATECLA
; Traduce código de tecla al carácter correspondiente
; Recibe: W: código de tecla (0-16)
; Retorna: W: código de tecla traducido
; Nota: está preparado para trabajar en la página 100-1FF
TRATECLA:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
ADDWF PCL,F ;
RETLW 0 ; No tecla
RETLW 'A' ;
RETLW 'B' ;
RETLW 'C'
RETLW 'D'
RETLW d'3'
RETLW d'6'
RETLW d'9'
RETLW '#'
RETLW d'2'
RETLW d'5'
RETLW d'8'
RETLW d'0'
RETLW d'1'
RETLW d'4'
RETLW d'7'
RETLW '*'
;************************************************************************************************************************************************************************
; TRATECLA1
; Indica el tipo de tecla pulsada (número, letra o función)
; Recibe: W: código de tecla (0-16)
; Retorna: W: código de tecla traducido
; Nota: está preparado para trabajar en la página 100-1FF
TRATECLA1:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
ADDWF PCL,F ;
RETLW 0 ; No tecla
RETLW d'2' ; Tipos:
RETLW d'3' ; 0: Nada
RETLW d'4' ; 1: Números
RETLW d'5' ; 2: A (ajustar hora)
RETLW d'1' ; 3: B (apagar despertador)
RETLW d'1' ; 4: C (cancelar despertador)
RETLW d'1' ; 5: D (programar despertador)
RETLW 0 ; 6: * (cancelar operación)
RETLW d'1' ;
RETLW d'1'
RETLW d'1'
RETLW d'1'
RETLW d'1'
RETLW d'1'
RETLW d'1'
RETLW d'6'
;************************************************************************************************************************************************************************
; MÁQUINAS
;************************************************************************************************************************************************************************
;************************************************************************************************************************************************************************
; MAQUEST
; Maquina de estados
MAQUEST:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
MOVF estado,W ; Miramos en qué estado estamos
ADDWF PCL,F ; Saltamos a la rutina precisa
GOTO HORA ; Estado 0, está dando la hora
GOTO ESP_HORDEC ; Estado 1, cambiar hora: decena hora
GOTO ESP_HORUNI1 ; Estado 2, cambiar hora: unidad hora (si HORDEC=0 ó 1)
GOTO ESP_HORUNI2 ; Estado 3, cambiar hora: unidad hora (si HORDEC=2)
GOTO ESP_MINDEC ; Estado 4, cambiar hora: decena minuto
GOTO ESP_MINUNI ; Estado 5, cambiar hora: unidad minuto
GOTO ESP_DESPHORDEC ; Estado 6, configurar despertador: decena hora
GOTO ESP_DESPHORUNI1 ; Estado 7, configurar despertador: unidad hora (si HORDEC=0 ó 1)
GOTO ESP_DESPHORUNI2 ; Estado 8, configurar despertador: unidad hora (si HORDEC=2)
GOTO ESP_DESPMINDEC ; Estado 9, configurar despertador: decena minuto
GOTO ESP_DESPMINUNI ; Estado 10, configurar despertador: unidad minuto
GOTO DESPERTADOR ; Estado 11, ringing amphersand running
;************************************************************************************************************************************************************************
; MÁQUINAS DE EVENTOS
;************************************************************************************************************************************************************************
; Estado 0
HORA:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
RETURN ; Número
GOTO AC_CAMBIAHORA ; A
RETURN ; B
GOTO AC_CANCELDESP ; C
GOTO AC_PROGDESP ; D
RETURN ; *
GOTO AC_INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 1
ESP_HORDEC:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORDEC ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
RETURN ; Tick
;************************************************************************************************************************************************************************
; Estado 2
ESP_HORUNI1:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORUNI1 ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
RETURN ; Tick
;************************************************************************************************************************************************************************
; Estado 3
ESP_HORUNI2:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORUNI2 ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
RETURN ; Tick
;************************************************************************************************************************************************************************
; Estado 4
ESP_MINDEC:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERMINDEC ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
RETURN ; Tick
;************************************************************************************************************************************************************************
; Estado 5
ESP_MINUNI:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_GUARDAHORA ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
RETURN ; Tick
;************************************************************************************************************************************************************************
; Estado 6
ESP_DESPHORDEC:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORDEC ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
GOTO INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 7
ESP_DESPHORUNI1:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORUNI1 ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
GOTO INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 8
ESP_DESPHORUNI2:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERHORUNI2 ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
GOTO INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 9
ESP_DESPMINDEC:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_VERMINDEC ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
GOTO INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 10
ESP_DESPMINUNI:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
GOTO AC_GUARDADESP ; Número
RETURN ; A
RETURN ; B
RETURN ; C
RETURN ; D
GOTO AC_CANCELOP ; *
GOTO INCRELOJ ; Tick
;************************************************************************************************************************************************************************
; Estado 11
DESPERTADOR:
CLRF PCLATH ; Funciona en direcciones 100-1FF
BSF PCLATH,0 ;
BCF PCLATH,1 ;
CALL LEEVENTO ; Se comprueba el tipo de la tecla introducida
ADDWF PCL,F ;
RETURN ; No evento
RETURN ; Número
RETURN ; A
GOTO AC_APAGAR ; B
RETURN ; C
RETURN ; D
RETURN ; *
GOTO INCRELOJ ; Tick
; GOTO AC_RINGRUN ; Tick de sonido
;************************************************************************************************************************************************************************
;***************************************
;*** ACCIONES E INICIALIZACIONES ***
ORG 200
;***************************************
;************************************************************************************************************************************************************************
; ACCIONES
;************************************************************************************************************************************************************************
; AC_INCRELOJ
; Acción que incrementa un segundo el reloj y lo visualiza
AC_INCRELOJ:
CALL INCRELOJ
CALL VISRELOJ
RETURN
;************************************************************************************************************************************************************************
; AC_CAMBIAHORA
; Pasamos al estado de configurar la hora
AC_CAMBIAHORA:
MOVLW d'1' ; Pasamos al estado 1
MOVWF estado
MOVLW lcd_clr ; Se limpia la pantalla
CALL LCDIWR ;
RETURN
;************************************************************************************************************************************************************************
; AC_PROGDESP
; Pasamos al estado de configurar el despertador
AC_PROGDESP:
MOVLW d'6' ; Pasamos al estado 6
MOVWF estado
MOVLW lcd_clr ; Se limpia la pantalla
CALL LCDIWR ;
CALL VISDESP ;
RETURN
;************************************************************************************************************************************************************************
; AC_CANCELOP
; Volvemos al estado 0 (visualizar la hora)
AC_CANCELOP:
MOVLW lcd_clr ; Se limpia la pantalla
CALL LCDIWR ;
CALL INITESTADO ;
RETURN ;
;************************************************************************************************************************************************************************
; AC_CANCELDESP
; Cancelamos el despertador programado
AC_CANCELDESP:
MOVLW lcd_clr ; Se limpia la pantalla
CALL LCDIWR ;
RETURN
;************************************************************************************************************************************************************************
; AC_VERHORDEC
; Verificamos que el dígito introducido para las decenas de hora es correcto
AC_VERHORDEC:
CALL LEE_DATO ;
ADDLW -d'3' ; Miramos si es menor que dos
BTFSC STATUS,C ;
RETURN
CALL LEE_DATO ; Si no es igual a 2
XORLW d'2' ; vamos al lazo HORA1
BTFSS STATUS,Z ;
GOTO HORA1
; Si es igual a 2
CALL LEE_DATO ; Guardamos la cifra en HORDEC
MOVWF HOR1
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR ; Escribimos el número introducido en pantalla
INCF estado,F
INCF estado,F ; Aumentamos el estado dos veces
RETURN
HORA1:
CALL LEE_DATO ; Guardamos la cifra en HORDEC
MOVWF HOR1 ;
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR ; Escribimos el número introducido en pantalla
INCF estado,F ; Aumentamos el estado
RETURN
;************************************************************************************************************************************************************************
; AC_GUARDAHORUNI
; Guardamos las unidades de hora (puede ser cualquier valor de 0 a 9)
AC_VERHORUNI1:
CALL LEE_DATO
MOVWF HOR2
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR
INCF estado,F ; Pasamos a verificar las decenas de minuto
INCF estado,F
RETURN
;************************************************************************************************************************************************************************
; AC_VERHORUNI
; Verificamos las unidades de hora (tiene que ser menor que 4) y la guardamos si el valor es correcto
AC_VERHORUNI2:
CALL LEE_DATO ;
ADDLW -d'4' ; Miramos si es menor que cuatro
BTFSC STATUS,C ;
RETURN
DECF estado,F
GOTO AC_VERHORUNI1 ;
;************************************************************************************************************************************************************************
; AC_VERMINDEC
; Verificamos las decenas de minuto (tiene que ser menor que 6) y la guardamos si el valor es correcto
AC_VERMINDEC:
CALL LEE_DATO ;
ADDLW -d'6' ; Miramos si es menor que seis
BTFSC STATUS,C ;
RETURN
MOVLW ':' ; Se escriben dos puntos
CALL LCDDWR ;
CALL LEE_DATO
MOVWF MIN1
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR
MOVF estado,W ; ; Si no es igual a 2
XORLW d'4' ; vamos al lazo HORA1
BTFSS STATUS,Z ;
INCF estado,F
MOVLW d'10' ;
MOVWF estado ; Miramos si es menor que seis
RETURN ;
;************************************************************************************************************************************************************************
; AC_GUARDAHORA
; Verificamos las unidades de minuto (tiene que ser menor que cualquier valor, solo guardamos) y la guardamos si el valor es correcto
AC_GUARDAHORA:
CALL LEE_DATO ;Guardamos las unidades de minuto
MOVWF MINUNI
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR
MOVF HOR1,W
MOVWF HORDEC ;Guardamos las decenas de hora
MOVF HOR2,W
MOVWF HORUNI ;Guardamos las unidades de hora
MOVF MIN1,W
MOVWF MINDEC ;Guardamos las decenas de minuto
CALL INITESTADO ;
MOVLW lcd_clr ; Se limpia la pantalla
CALL LCDIWR ;
RETURN
;************************************************************************************************************************************************************************
; AC_GUARDADESP
; Guardamos la hora de despertador programada
AC_GUARDADESP:
CALL LEE_DATO
MOVWF DESP_MINUNI ;Guardamos las unidades de minuto
ADDLW '0' ; Se pasa a ASCII
CALL LCDDWR
MOVF HOR1,W
MOVWF DESP_HORDEC ;Guardamos las decenas de hora
MOVF HOR2,W