-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathphone_with_incipio_case.scad
1637 lines (1272 loc) · 54.9 KB
/
phone_with_incipio_case.scad
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
////////////////////////////////////////////////////////////////////////
// Initial Revision:
// 27-Mar-2016
//
// Author:
//
// David Crook <[email protected]>
//
// Inspired by:
//
// - http://www.thingiverse.com/thing:4382/ iPhone Bike Mount
// - http://www.thingiverse.com/thing:18020/ Dodge Ram Vent Mount for iPhone
//
// Description:
//
// I decided to re-implement this iphone sleeve phone, to fit my iPhone 6
// Plus case and using OpenSCAD
//
// Revisions/Notes:
//
// v1:
//
// - used .STL imported into OpenSCAD to base dimensions on, and firstly
// modeled my incipio iPhone case
//
// - after many iterations, experiments and tweaks, have an iPhone mount and
// sleeve for my bicycle. plan to work on a mount system for my car/truck
// next
//
// v2:
//
// - cupholder mount system for my truck
//
// - tweaks for cap
//
////////////////////////////////////////////////////////////////////////
use <files/iPhone_6_and_6_Plus_Mockups.scad>;
use <../libraries/MCAD/2Dshapes.scad>
use <../libraries/local-misc/wedge.scad>
e = 1/128; // small number
w = 81.5;
l = 161.9; //
h = 10.5; // at corners; elsewhere as low as 10.1 mm
iw = 77.8;
il = 158.1;
ih = 7.1;
tol = 0.2;
dw = w - iw;
dl = l - il;
dh = h - ih;
tw = (1/2) * dw ;
tl = (1/2) * dl ;
th = (1/2) * dh ;
cut_w = 73.3;
cut_l = 153.8;
cut_r = 9.5;
dcw = (w - cut_w) / 2;
dcl = (l - cut_l) / 2;
// http://www.amazon.com/IPhone-Incipio-Impact-Resistant-Translucent/dp/B00MUQ9V1Q
// "Incipio NGP Case for iPhone 6+"
// 6.5 x 3.3 x 0.5 inches
module incipioNgpCase () {
difference() {
// case outer dimensions
color ("Yellow") shell(w, l, h, 14);
// carve out iphone 6 Plus and some tolerance
translate([tw - tol, tl - tol, th]) {
shell(iw + 2*tol, il + 2*tol, ih + 2*tol, 9.5 + 2*tol);
}
// cut out above phone too (rounded rect with dimensions 73.3 x 153.8)
translate ([dcw,dcl,th+ih-tol])
linear_extrude(height = 10, center = false, convexity = 10)
complexRoundSquare([cut_w, cut_l],
[cut_r, cut_r],
[cut_r, cut_r],
[cut_r, cut_r],
[cut_r, cut_r],
center = false);
}
}
module sleeveForEncasediPhone (w, l, h, tweak_mount_surface, with_cap) {
tolerance = 0.5;
CONTROL_RENDER_cutoff_top = !true;
CONTROL_RENDER_experiment3 = !true;
CONTROL_RENDER_experiment4 = !true;
CONTROL_RENDER_experiment5 = true;
wantThinner = true;
//wantThinner = false;
sleeveSideThickness = wantThinner ? 3.0 : 3.5;
sleeveBottomThickness = wantThinner ? 3.0 : 3.5;
sleeveTopThickness = wantThinner ? 3.0 : 3.5;
sleeveBaseThickness = wantThinner ? 3.0 : 3.5;
base_l = sleeveBaseThickness;
sleeveInner_w = tolerance + w + tolerance;
sleeveInner_h = tolerance + h + tolerance;
sleeveInner_r = 1.7;
buttonsIncludedInner_w = tolerance + 82.3 + tolerance + 0.5;
buttonsIncludedInner_h = + 3.0 + tolerance;
buttonsIncludedInner_r = tolerance ;
sleeveOuter_w = sleeveSideThickness + sleeveInner_w + sleeveSideThickness;
sleeveOuter_h = sleeveBottomThickness + sleeveInner_h + sleeveTopThickness;
sleeveOuter_r = 3.2;
iphoneDisplay_w = 68.8;
iphoneScreenBezel_w = 3.5;
iphoneScreenOpening_w = iphoneScreenBezel_w + iphoneDisplay_w + iphoneScreenBezel_w;
caseNonViewable = (1/2) * (sleeveOuter_w - iphoneScreenOpening_w );
sleeveInner_l = l;
volumeButtonsHeightFromBottom = 105.0;
volumeButtonsCutoutHeight = 25.3;
volumeButtonsCutoutDepth = 7.7 + 2.3;
volumeButtonsCutoutRadius = 2;
erase_sleeveInner_l_left = volumeButtonsHeightFromBottom;
powerButtonHeightFromBottom = 117.7 - 1.0;
powerButtonCutoutHeight = 12.2 + 2.0 + 1.0;
powerButtonCutoutDepth = 7.7 + 2.3;
powerButtonCutoutRadius = 2;
erase_sleeveInner_l_right = powerButtonHeightFromBottom;
muteSwitchHeightFromBottom = 132.7;
muteSwitchCutoutHeight = 12.2 + 3.0;
muteSwitchCutoutDepth = 7.7 + 2.3;
muteSwitchCutoutRadius = 2;
cameraHeightFromBottom = 144.8;
cameraCutoutHeight = 0.5 + 28.2 + 0.5;
cameraCutoutDepth = 12.1;
cameraCutoutRadius = cameraCutoutDepth/2-1;
cameraHoleOffcenter = 5.5 - 0.5;
speakerCutoutHeight = 22;
speakerCutoutDepth = 5;
speakerCutoutRadius = speakerCutoutDepth/2;
speakerHoleOffcenter = 10.8 ;
lightningCutoutHeight = 14.4;
lightningCutoutDepth = lightningCutoutHeight/2;
lightningCutoutRadius = lightningCutoutDepth/2;
lightningHoleOffcenter = 0;
headphoneMicCutoutHeight = 15 - 2;
headphoneMicCutoutDepth = 7.2;
headphoneMicCutoutRadius = lightningCutoutDepth/2;
headphoneMicHoleOffcenter = 28.5 + 3.9 - 2;
headphoneJackDiameter = 3.5;
headphoneMicBoreDiameter = 8.0 + 0.2;
headphoneMicBoreOffcenter = 28.5 + 2.6 + headphoneMicCutoutDepth -
headphoneMicBoreDiameter;
// Use some trig: http://mathworld.wolfram.com/CircularSegment.html
bottomLipHeight = 18.0 - 3;
bottomLipFingerprintDiameter = 17;
bottomLipCutoutMaxWidth = 1.6 * bottomLipFingerprintDiameter;
bottomLipCutoutArcRadius = 2.6*bottomLipCutoutMaxWidth; // pick a multiple
bottomLipCutoutArcDegrees = 2*asin(bottomLipCutoutMaxWidth/(2*bottomLipCutoutArcRadius)); // figure out how many degrees of arc this is
// calculate the width of cutout at junction with base
bottomLipCutout_r2 = bottomLipCutoutArcRadius - bottomLipHeight;
bottomLipCutout_MinWidth = 2 * bottomLipCutout_r2 * tan((1/2) *bottomLipCutoutArcDegrees);
// calculate how far we need to translate below to cut out enough
bottomLipCutout_h = bottomLipCutoutArcRadius * cos((1/2)*bottomLipCutoutArcDegrees);
intersection() {
union() {
union () {
// fill in groove for part of sleeve below buttons
if (!CONTROL_RENDER_experiment3) {
difference() {
union () {
erase_sleeveInner_left = CONTROL_RENDER_experiment5 ? l : erase_sleeveInner_l_left;
erase_sleeveInner_right = CONTROL_RENDER_experiment5 ? l : erase_sleeveInner_l_right;
linear_extrude(height = erase_sleeveInner_left, center = false, convexity = 10)
translate([-(1/2)*buttonsIncludedInner_w, -(1/2)*buttonsIncludedInner_h, 0])
difference () {
complexRoundSquare([buttonsIncludedInner_w/2, buttonsIncludedInner_h],
[0, 0], [0, 0], [0, 0], [0, 0],
center = false);
// cut out size of iphone in case (plus tolerance)
translate([(buttonsIncludedInner_w-sleeveInner_w)/2, 0, 0])
complexRoundSquare([(1/2)*sleeveInner_w, sleeveInner_h/2],
[0, 0],
[0, 0],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
center = false);
}
linear_extrude(height = erase_sleeveInner_right, center = false, convexity = 10)
translate([0, -(1/2)*buttonsIncludedInner_h, 0])
difference () {
complexRoundSquare([buttonsIncludedInner_w/2, buttonsIncludedInner_h],
[0, 0], [0, 0], [0, 0], [0, 0],
center = false);
// cut out size of iphone in case (plus tolerance)
translate([0, 0, 0])
complexRoundSquare([(1/2)*sleeveInner_w, sleeveInner_h/2],
[0, 0],
[0, 0],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
center = false);
}
}
// fill in groove in cap
translate([0,0,l - 10.0])
rotate([180,0,0])
linear_extrude(height = 40.0, center = false, convexity = 10)
complexRoundSquare([sleeveOuter_w, sleeveOuter_h],
[0, 0],
[0, 0],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
center = true);
}
}
// need a difference here to be able to punch out button and camera access holes
difference () {
// 2D view for length of case
linear_extrude(height = sleeveInner_l, center = false, convexity = 10)
difference () {
complexRoundSquare([sleeveOuter_w, sleeveOuter_h],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
center = true);
// cut out size of iphone in case (includes tolerance)
complexRoundSquare([sleeveInner_w, sleeveInner_h],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
center = true);
// include groove for buttons (covered back in above)
complexRoundSquare([buttonsIncludedInner_w, buttonsIncludedInner_h],
[buttonsIncludedInner_r, buttonsIncludedInner_r],
[buttonsIncludedInner_r, buttonsIncludedInner_r],
[buttonsIncludedInner_r, buttonsIncludedInner_r],
[buttonsIncludedInner_r, buttonsIncludedInner_r],
center = true);
bevel_angle = 50;
// cut for screen and add bevel
translate ([-iphoneScreenOpening_w/2, -sleeveInner_h ])
square([iphoneScreenOpening_w, sleeveInner_h], center = false);
translate ([-(1/2)*(sleeveInner_w + 2*tolerance), -(sleeveInner_h + tolerance) + sleeveTopThickness/2])
rotate((360 - bevel_angle) * [0, 0, 1])
square([caseNonViewable, sleeveInner_h], center = false);
translate ([1/2*(sleeveInner_w + 2*tolerance), -(sleeveInner_h + tolerance) + sleeveTopThickness/2])
rotate((90 + bevel_angle) * [0, 0, 1])
square([caseNonViewable, sleeveInner_h], center = false);
}
// volume buttons cutout
translate([-1 * ((1/2) * sleeveOuter_w + e), -(1/2) * (volumeButtonsCutoutDepth), volumeButtonsHeightFromBottom])
mirror([1,0,0])
rotate([0, 180 + 90, 0])
linear_extrude(height = sleeveSideThickness + 2*e, center = false, scale = 0.9, convexity = 10)
complexRoundSquare( [volumeButtonsCutoutHeight, volumeButtonsCutoutDepth],
[volumeButtonsCutoutRadius, volumeButtonsCutoutRadius],
[volumeButtonsCutoutRadius, volumeButtonsCutoutRadius],
[volumeButtonsCutoutRadius, volumeButtonsCutoutRadius],
[volumeButtonsCutoutRadius, volumeButtonsCutoutRadius],
center = false);
// power button cutout
translate([+1 * ((1/2) * sleeveOuter_w + e), -(1/2) * (powerButtonCutoutDepth), powerButtonHeightFromBottom])
rotate([0, 180 + 90, 0])
linear_extrude(height = sleeveSideThickness + 2*e, center = false, scale = 0.9, convexity = 10)
complexRoundSquare( [powerButtonCutoutHeight, powerButtonCutoutDepth],
[powerButtonCutoutRadius, powerButtonCutoutRadius],
[powerButtonCutoutRadius, powerButtonCutoutRadius],
[powerButtonCutoutRadius, powerButtonCutoutRadius],
[powerButtonCutoutRadius, powerButtonCutoutRadius],
center = false);
// mute switch cutout
/// echo(muteSwitchCutoutHeight, muteSwitchCutoutDepth, muteSwitchHeightFromBottom);
translate([-1 * ((1/2) * sleeveOuter_w + e), -(1/2) * (muteSwitchCutoutDepth), muteSwitchHeightFromBottom])
mirror([1,0,0])
rotate([0, 180 + 90, 0])
linear_extrude(height = sleeveSideThickness + 2*e, center = false, scale = 0.9, convexity = 10)
complexRoundSquare( [muteSwitchCutoutHeight, muteSwitchCutoutDepth ],
[muteSwitchCutoutRadius, muteSwitchCutoutRadius],
[muteSwitchCutoutRadius, muteSwitchCutoutRadius],
[muteSwitchCutoutRadius, muteSwitchCutoutRadius],
[muteSwitchCutoutRadius, muteSwitchCutoutRadius],
center = false);
// camera cutout
translate([cameraHoleOffcenter, (1/2) * sleeveInner_h - tolerance - e, cameraHeightFromBottom])
rotate([90, 0, 0])
mirror([0,0,1])
linear_extrude(height = sleeveBottomThickness + 2*tolerance +2*e, center = false, convexity = 10)
complexRoundSquare( [cameraCutoutHeight, cameraCutoutDepth + 1.2],
[cameraCutoutRadius, cameraCutoutRadius],
[cameraCutoutRadius, cameraCutoutRadius],
[cameraCutoutRadius, cameraCutoutRadius],
[cameraCutoutRadius, cameraCutoutRadius],
center = false);
if (CONTROL_RENDER_cutoff_top) {
cutHeight = CONTROL_RENDER_experiment3 ? 5 : l - 10.0 ;
extrHeight = CONTROL_RENDER_experiment3 ? 200 : 26 ;
echo("cutHeight:", cutHeight);
translate([0,0, cutHeight])
linear_extrude(height = extrHeight, center = false, convexity = 10)
complexRoundSquare([sleeveOuter_w+e, sleeveOuter_h+e],
[0,0], [0,0], [0,0], [0,0],
center = true);
} else {
if (CONTROL_RENDER_experiment5) {
cutHeight = l - 10.0 ;
extrHeight = l;
echo("cutHeight:", cutHeight);
translate([0,0, cutHeight])
rotate([180,0,0])
linear_extrude(height = extrHeight, center = false, convexity = 10)
complexRoundSquare([sleeveOuter_w+e, sleeveOuter_h+e],
[0,0], [0,0], [0,0], [0,0],
center = true);
}
}
}
}
// cap
if (with_cap) {
capArmThickness = 4;
capCapThickness = 3.5;
capDepth = sleeveOuter_h;
caseHeight = sleeveInner_l;
capCaseWidth = sleeveOuter_w + 2*tolerance + tolerance; // tolerance
// shouldn't
// here be
// higher-quality
// prints
powerSideCut = powerButtonHeightFromBottom;
powerSideHeight = powerButtonCutoutHeight;
powerButtonCapClip_z = caseHeight - powerSideCut - powerSideHeight;
muteSideCut = muteSwitchHeightFromBottom;
muteSideHeight = muteSwitchCutoutHeight;
muteSwitchCapClip_z = caseHeight - muteSideCut - muteSideHeight;
echo("capDepth:", capDepth );
echo("caseHeight:", caseHeight);
echo("capCaseWidth:", capCaseWidth);
echo("powerButtonCapClip_z:", powerButtonCapClip_z);
echo("muteSwitchCapClip_z:", muteSwitchCapClip_z);
if (CONTROL_RENDER_experiment5) {
translate([0, 0, caseHeight])
generateCap(capArmThickness, capCapThickness, capDepth, capCaseWidth,
powerButtonCapClip_z, muteSwitchCapClip_z);
} else {
translate([0, 0, caseHeight])
generateCap(capArmThickness, capCapThickness, capDepth, capCaseWidth,
powerButtonCapClip_z, muteSwitchCapClip_z);
}
}
// base
difference() {
translate([0,0, -base_l])
linear_extrude(height = base_l, center = false, convexity = 10)
// 2D view for base of sleeve
complexRoundSquare([sleeveOuter_w, sleeveOuter_h],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
center = true);
// handle speaker hole, lightning, headphone
// speaker hole
rotate([180,0,0])
translate([-tolerance + speakerHoleOffcenter, -(1/2) * speakerCutoutDepth, -e])
linear_extrude(height = base_l + 2*e, center = false, convexity = 10)
complexRoundSquare( [speakerCutoutHeight, speakerCutoutDepth],
[speakerCutoutRadius/2, speakerCutoutRadius/2],
[speakerCutoutRadius, speakerCutoutRadius],
[speakerCutoutRadius, speakerCutoutRadius],
[speakerCutoutRadius/2, speakerCutoutRadius/2],
center = false);
// lightning hole
rotate([180,0,0])
translate([-tolerance, 0, -e])
linear_extrude(height = base_l + 2*e, center = false, convexity = 10)
complexRoundSquare( [lightningCutoutHeight, lightningCutoutDepth],
[lightningCutoutRadius, lightningCutoutRadius],
[lightningCutoutRadius, lightningCutoutRadius],
[lightningCutoutRadius, lightningCutoutRadius],
[lightningCutoutRadius, lightningCutoutRadius],
center = true);
// widen lightning hole
rotate([180,0,0])
translate([-tolerance, 0, -e])
linear_extrude(height = base_l + 2*e, center = false, convexity = 10)
complexRoundSquare( [lightningCutoutHeight - 5, lightningCutoutDepth + 2],
[lightningCutoutRadius/2, lightningCutoutRadius/2],
[lightningCutoutRadius/2, lightningCutoutRadius/2],
[lightningCutoutRadius/2, lightningCutoutRadius/2],
[lightningCutoutRadius/2, lightningCutoutRadius/2],
center = true);
// headphone and Mic hole
rotate([180,0,0]) {
translate([-headphoneMicHoleOffcenter, -(1/2) * headphoneMicCutoutDepth, -e])
linear_extrude(height = base_l + 2*e, center = false, convexity = 10)
complexRoundSquare( [headphoneMicCutoutHeight, headphoneMicCutoutDepth],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
center = false);
translate([-headphoneMicBoreOffcenter, -(1/2) * headphoneMicBoreDiameter, -e])
linear_extrude(height = base_l + 2*e, center = false, convexity = 10)
complexRoundSquare( [headphoneMicBoreDiameter, headphoneMicBoreDiameter],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
[headphoneMicCutoutRadius, headphoneMicCutoutRadius],
center = false);
}
}
// Bottom lip with cutout for Home button / thumbprint sensor
difference() {
// 2D view for height of lip
linear_extrude(height = bottomLipHeight, center = false, convexity = 10)
difference () {
complexRoundSquare([sleeveOuter_w, sleeveOuter_h],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
[sleeveOuter_r, sleeveOuter_r],
center = true);
// cut out size of iphone plus some additional
scale ([1,1.22,1])
complexRoundSquare([sleeveInner_w, sleeveInner_h],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
[sleeveInner_r, sleeveInner_r],
center = true);
}
if (CONTROL_RENDER_cutoff_top) {
cutHeight = CONTROL_RENDER_experiment3 ? 5 : l - 10.0 ;
extrHeight = CONTROL_RENDER_experiment3 ? 200 : 26 ;
echo("cutHeight:", cutHeight);
translate([0,0, cutHeight])
linear_extrude(height = extrHeight, center = false, convexity = 10)
complexRoundSquare([sleeveOuter_w+e, sleeveOuter_h+e],
[0,0],
[0,0],
[0,0],
[0,0],
center = true);
}
// cutout for fingerprint
//// wedge(height, radius, degrees);
echo ("Width of fingerprint cutout at base: ", bottomLipCutout_MinWidth);
translate([0, 0, bottomLipHeight-bottomLipCutout_h+e])
rotate([90, 360-(90-bottomLipCutoutArcDegrees/2), 0])
wedge (10, bottomLipCutoutArcRadius, bottomLipCutoutArcDegrees);
}
if (!CONTROL_RENDER_experiment3) {
mountInsertWidth = 22;
mountInsertThickness = 3;
mountInsertHeight = 42;
mountInsert_yTranslation = (1/2)*( tolerance + h + tolerance) + sleeveBottomThickness - e;
translate([-mountInsertWidth/2, mountInsert_yTranslation, (0.58) * l - mountInsertHeight + base_l])
difference() {
sleeveMountInsert(mountInsertWidth, mountInsertThickness, mountInsertHeight, tweak_mount_surface);
// chop off top 1.5 mm
translate([-e, -e, mountInsertHeight - 1.5])
cube([mountInsertWidth + 2*e, mountInsertThickness*2 + 2*e, 6]);
}
}
}
if ((CONTROL_RENDER_cutoff_top && CONTROL_RENDER_experiment4) || CONTROL_RENDER_experiment5) {
keepHeight = 45 + 10;
cutHeight = l + 10 ;
extrHeight = keepHeight ;
translate([0,0, cutHeight - keepHeight])
linear_extrude(height = extrHeight, center = false, convexity = 10)
complexRoundSquare([sleeveOuter_w+10+e, sleeveOuter_h+10+e],
[0,0],
[0,0],
[0,0],
[0,0],
center = true);
}
}
}
module generateCap(cap_arm_thickness, cap_thickness, cap_depth, cap_case_width,
power_button_z, mute_switch_z) {
tolerance = 0.5;
capCaseWidth = cap_case_width;
capCapThickness = cap_thickness;
capArmThickness = cap_arm_thickness;
capDepth = cap_depth;
fudge = true;
//fudge = false;
powerButtonCapClip_z = fudge ? power_button_z + 1 : power_button_z;
muteSwitchCapClip_z = fudge ? mute_switch_z + 1 : mute_switch_z;
tabInsertDepth = 2.5 + 1;
powerButtonCap_tabHeight = 15;
powerButtonCap_tabWidth = 10 - tolerance;
muteSwitchCap_tabHeight = 15.2;
muteSwitchCap_tabWidth = 10 - tolerance;
capSideDistance = (capCaseWidth + capArmThickness)/2;
caseOverlap = 10.0;
linear_extrude(height = capCapThickness, center = false, convexity = 10)
// 2D view for cap
complexRoundSquare([capCaseWidth + 2*capArmThickness, capDepth],
[0,0], [0,0], [0,0], [0,0],
center = true);
// power button side
translate([capSideDistance, 0, - powerButtonCapClip_z])
linear_extrude(height = powerButtonCapClip_z, center = false, convexity = 10)
complexRoundSquare([capArmThickness, capDepth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([capSideDistance - (capArmThickness - 1), 0, - caseOverlap + e])
linear_extrude(height = caseOverlap, center = false, convexity = 10)
complexRoundSquare([capArmThickness, capDepth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([capSideDistance, 0, - powerButtonCapClip_z - powerButtonCap_tabHeight])
rotate([0,0,180])
generateCapTab(capArmThickness, capDepth,
powerButtonCap_tabHeight, powerButtonCap_tabWidth, tabInsertDepth);
// mute switch side
translate([-(capSideDistance), 0, - muteSwitchCapClip_z])
linear_extrude(height = muteSwitchCapClip_z, center = false, convexity = 10)
complexRoundSquare([capArmThickness, capDepth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([-(capSideDistance - (capArmThickness - 1)), 0, - caseOverlap + e])
linear_extrude(height = caseOverlap, center = false, convexity = 10)
complexRoundSquare([capArmThickness, capDepth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([-(capSideDistance), 0, - muteSwitchCapClip_z - muteSwitchCap_tabHeight])
rotate([0,0,0])
generateCapTab(capArmThickness, capDepth,
muteSwitchCap_tabHeight, muteSwitchCap_tabWidth, tabInsertDepth);
}
module generateCapTab(cap_arm_thickness, cap_case_width, tab_height, tab_width, tab_insert_depth) {
capCaseWidth = cap_case_width;
capArmThickness = cap_arm_thickness;
tabHeight = tab_height;
tabWidth = tab_width;
tabInsertDepth = tab_insert_depth;
if (true) {
echo("=== generateCapTab ===");
echo("capCaseWidth:", capCaseWidth);
echo("capArmThickness:", capArmThickness);
echo("tabHeight:", tabHeight);
echo("tabWidth:", tabWidth);
echo("tabInsertDepth:", tabInsertDepth);
}
translate([0,0,0])
linear_extrude(height = tabHeight, center = false, convexity = 10)
complexRoundSquare([capArmThickness, tabWidth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([(1/2)*capArmThickness,0,(1/2)*tabHeight])
rotate([0,90,0])
linear_extrude(height = tabInsertDepth, scale = 0.7, center = false, convexity = 10)
complexRoundSquare([tabHeight, tabWidth],
[0,0], [0,0], [0,0], [0,0],
center = true);
translate([0,0,tabHeight])
rotate([0,180,0])
linear_extrude(height = tabHeight/2, center = false, scale = 0.7, convexity = 10)
//linear_extrude(height = tabHeight/2, center = false, scale = 0.7, convexity = 10)
complexRoundSquare([capArmThickness, capCaseWidth],
[0,0], [0,0], [0,0], [0,0],
center = true);
}
module sleeveMountInsert (width, thickness, height, shouldTweak) {
insertTailWidth = width;
insertThickness = 2*thickness;
insertChopThickness = thickness;
insertFullHeight = height;
insertPartialHeight = 30;
insertSlantedHeight = insertFullHeight - insertPartialHeight;
insertSlantAngle = 60;
tolerance = 0.5;
insertChopThickness_x = shouldTweak ? insertChopThickness + tolerance : insertChopThickness;
insertChopThickness_y = shouldTweak ? insertChopThickness + tolerance : insertChopThickness;
rotateAngle = 15;
echo("insertChopThickness_x:", insertChopThickness_x);
echo("insertChopThickness_y:", insertChopThickness_y);
difference() {
intersection () {
linear_extrude(height = insertFullHeight, center = false, convexity = 10)
difference() {
complexRoundSquare([insertTailWidth, insertThickness],
[0,0], [0,0], [0,0], [0,0],
center = false);
translate([-e, -e, 0])
complexRoundSquare([insertChopThickness_x, insertChopThickness_y],
[0,0], [0,0], [0,0], [0,0],
center = false);
translate([insertTailWidth - insertChopThickness_x + e, -e, 0])
complexRoundSquare([insertChopThickness_x, insertChopThickness_y],
[0,0], [0,0], [0,0], [0,0],
center = false);
if (shouldTweak) {
translate([insertChopThickness_x, insertChopThickness_y*(1),0])
rotate([0,0,180-rotateAngle])
complexRoundSquare([insertChopThickness_x+1, insertChopThickness_y],
[0,0], [0,0], [0,0], [0,0],
center = false);
translate([insertTailWidth - insertChopThickness_x + e, -e, 0])
translate([0, insertChopThickness_y*(1),0])
rotate([0,0,270+rotateAngle])
complexRoundSquare([insertChopThickness_x, insertChopThickness_y+1],
[0,0], [0,0], [0,0], [0,0],
center = false);
}
}
rotate([insertSlantAngle,0,0])
cube(insertFullHeight);
}
translate([insertChopThickness,
insertChopThickness - 2*e,
(1/2) * insertSlantedHeight * sin (insertSlantAngle) - e])
rotate([360-(90-insertSlantAngle),0,90])
cube(7);
translate([insertTailWidth - insertChopThickness,
insertChopThickness - 2*e,
(1/2) * insertSlantedHeight * sin (insertSlantAngle) - e])
rotate([0, (90 - insertSlantAngle) ,0])
cube(7);
}
}
module bicycleMount(mount_insert_w, mount_insert_thickness, mount_insert_h, fitBetter) {
// there are four basic design features of the bike mount:
//
// 1. curvature for bike frame
//
// 2. through hole around this curvature for a metal screw-band (for
// attaching to bike frame)
//
// 3. mount insert piece for inserting phone carrier
//
// 4. clip latch to "lock" iphone carrier into the mount unless released
//
// 5. catch, to "lock" carrier into the mount
//
block_x = 30.5;
block_y = 24.0;
block_z = 39.0;
mountInsert_w = mount_insert_w;
mountInsert_h = 2*mount_insert_thickness;
enlargePunchScale = 1.08;
// http://mathworld.wolfram.com/CircularSegment.html
/* heightOfArcedPortion = 7.8; // Original setting */
heightOfArcedPortion = 5.8; // for my bicycle's handlebar column
chordLength = block_x;
// R = (1/2) (a^2/4h + h)
radiusOfCurvature = (1/2) * (pow(chordLength,2)/(4*heightOfArcedPortion) + heightOfArcedPortion);
// r = R - h
circleCenterDistanceFromCut = radiusOfCurvature - heightOfArcedPortion;
thicknessOfBandSupport = 3.5;
bandCutoutDistanceFromBlock = 10.7;
bandCutoutStartOfNegative = (3/10)*block_z;
bandCutoutStopOfNegative = (7/10)*block_z;
lockClip_square = 10.0;
lockClip_x = lockClip_square;
lockClip_y = lockClip_square;
lockClip_z = 6.6;
lockClip_r = lockClip_square/2;
lockClip_fr = lockClip_square/3;
lockClipScrewDiameter = 2.0;
difference() {
linear_extrude(height = block_z, center = false, convexity = 10)
difference () {
complexRoundSquare([block_x, block_y],
[0,0], [0,0], [0,0], [0,0],
center = false);
// 1. curvature for bike frame
translate([block_x/2, block_y + circleCenterDistanceFromCut,0])
circle(r= radiusOfCurvature);
}
// 2. through hole around this curvature for a metal screw-band
translate([0,0,bandCutoutStartOfNegative])
linear_extrude(height = bandCutoutStopOfNegative - bandCutoutStartOfNegative, center = false, convexity = 10)
difference() {
translate([-e, bandCutoutDistanceFromBlock,0])
square([block_x+2*e, block_y]);
translate([block_x/2, block_y + circleCenterDistanceFromCut,0])
circle(r= radiusOfCurvature + thicknessOfBandSupport);
}
// 3. mount insert piece for inserting phone carrier
scale([enlargePunchScale, enlargePunchScale, 1], center = false)
translate([-50 + (1/2) * (block_x - (mountInsert_w * enlargePunchScale)) ,
(mountInsert_h - enlargePunchScale*mountInsert_h), block_z - mount_insert_h + e])
test_sleeveMountInsert(fitBetter, 50);
}
// 4. clip latch to "lock" iphone carrier into the mount unless released
// (attach point)
translate ([block_x , 0, block_z - lockClip_z]) {
linear_extrude(height = lockClip_z, center = false, convexity = 10)
union() {
difference () {
complexRoundSquare([lockClip_x, lockClip_y],
[0,0],
[0,0],
[lockClip_r, lockClip_r],
[0,0],
center = false);
translate([lockClip_x/2, lockClip_y/2,0])
circle(r=lockClipScrewDiameter/2);
}
// upper curve
translate([0, lockClip_y, 0]) {
difference() {
complexRoundSquare([lockClip_x, lockClip_y],
[0,0],
[0,0],
[0,0],
[0,0],
center = false);
translate([-e, -e, 0])
complexRoundSquare([lockClip_x + 2*e, lockClip_y + 2*e],
[lockClip_fr, lockClip_fr],
[0,0],
[0,0],
[0,0],
center = false);
}
}
}
}
// 5. catch, to "lock" carrier into the mount
//
printable = !true;
align = 3;
spread = 5;
if (printable) {
translate([-align, -spread, block_z])
rotate([180, 0, 0])
import ("files/mount_v6-catch.stl");
} else {
translate([-align, 0.5, block_z])
rotate([0, 0, 0])
%import ("files/mount_v6-catch.stl");
}
}
module generateCup () {
cupRegionHeightAboveHolderBottom = 40.5 + 10;
cupRegionHeightBelowHolderBottom = 20;
holderBottomSectionSplitDiameter = 70.4;
cupBaseThickness = 4.5;
cupSideThickness = 3.5;
cupSideSlope = 10/1;
// two parts of side of cup (cones sections)
// top section
sideIncreaseTop = cupRegionHeightAboveHolderBottom * (1/cupSideSlope);
top_t = cupRegionHeightBelowHolderBottom + (1/2)*cupRegionHeightAboveHolderBottom;
top_h = cupRegionHeightAboveHolderBottom;
top_r1 = holderBottomSectionSplitDiameter/2;
top_r2 = holderBottomSectionSplitDiameter/2 + sideIncreaseTop;
top_thickness = cupSideThickness;
translate([0,0,top_t])
difference () {
cylinder(h = top_h,
r1 = top_r1, r2 = top_r2, center=true);
translate([0,0,e/2])
cylinder(h = top_h + 2*e,
r1 = top_r1 - top_thickness, r2 = top_r2 - top_thickness, center=true);
}
// bottom section
sideDecreaseBottom = cupRegionHeightBelowHolderBottom * (1/cupSideSlope);
bottom_t = cupRegionHeightBelowHolderBottom/2;
bottom_h = cupRegionHeightBelowHolderBottom;
bottom_r1 = holderBottomSectionSplitDiameter/2 - sideDecreaseBottom;
bottom_r2 = top_r1;
bottom_thickness = cupSideThickness;
translate([0,0,bottom_t])
difference () {
cylinder(h = bottom_h, r1 = bottom_r1, r2 = bottom_r2, center=true);
translate([0,0,e/2])
cylinder(h = bottom_h + 2*e,
r1 = bottom_r1 - bottom_thickness, r2 = bottom_r2 - top_thickness, center=true);
}
// base
base_thickness = cupBaseThickness;
base_t = base_thickness/2;
translate([0,0,-base_t])
linear_extrude(height = base_thickness, center = false, convexity = 10)
circle(r = bottom_r1, center = true);
echo("sideIncreaseTop:", sideIncreaseTop);
echo("Top of cup Diameter:", 2*top_r2);
echo("sideDecreaseBottom:", sideDecreaseBottom);
echo("Base Diameter:", 2*bottom_r1);
totalCupHeight = base_t + bottom_h + top_h;
echo("totalCupHeight:", totalCupHeight);
}
module generateCup2 () {
cupRegionHeightAboveHolderBottom = 27.667 * 2;
cupRegionHeightBelowHolderBottom = 27.667;
holderBottomSectionSplitDiameter = 68.667;
cupBaseThickness = 4.5 - 0.5;
cupSideThickness = 3.5 - 0.5;
cupSideSlope = 30/1;
// two parts of side of cup (cones sections)
// top section
sideIncreaseTop = cupRegionHeightAboveHolderBottom * (1/cupSideSlope);
top_t = cupRegionHeightBelowHolderBottom + (1/2)*cupRegionHeightAboveHolderBottom;
top_h = cupRegionHeightAboveHolderBottom;
top_r1 = holderBottomSectionSplitDiameter/2;
top_r2 = holderBottomSectionSplitDiameter/2 + sideIncreaseTop;
top_thickness = cupSideThickness;
translate([0,0,top_t])
difference () {
cylinder(h = top_h,
r1 = top_r1, r2 = top_r2, center=true);
translate([0,0,e/2])
cylinder(h = top_h + 2*e,
r1 = top_r1 - top_thickness, r2 = top_r2 - top_thickness, center=true);
}
// bottom section
sideDecreaseBottom = cupRegionHeightBelowHolderBottom * (1/cupSideSlope);
bottom_t = cupRegionHeightBelowHolderBottom/2;
bottom_h = cupRegionHeightBelowHolderBottom;
bottom_r1 = holderBottomSectionSplitDiameter/2 - sideDecreaseBottom;
bottom_r2 = top_r1;
bottom_thickness = cupSideThickness;
translate([0,0,bottom_t])
difference () {
cylinder(h = bottom_h, r1 = bottom_r1, r2 = bottom_r2, center=true);
translate([0,0,e/2])
cylinder(h = bottom_h + 2*e,
r1 = bottom_r1 - bottom_thickness, r2 = bottom_r2 - top_thickness, center=true);
}
// base
base_thickness = cupBaseThickness;
base_t = base_thickness/2;
translate([0,0,-base_t])