build.gradle

plugins {
    id 'java'
    id 'jacoco'
    id 'application'
    id 'com.github.johnrengelman.shadow' version '6.0.0'
    id 'pl.allegro.tech.build.axion-release' version '1.8.3'
}

scmVersion {
    tag {
        prefix = ''
    }
}

sourceCompatibility = 1.8
targetCompatibility = 1.8
group = 'se.gustavkarlsson.rocketchat'
version = scmVersion.version
mainClassName = 'se.gustavkarlsson.rocketchat.jira_trigger.App'

repositories {
    mavenCentral()
    maven { url 'https://maven.atlassian.com/repository/public' }
    maven { url 'https://jitpack.io' }
}

dependencies {
    // Hack to handle dependencies with 'atlassian-plugin' extension
    compile module('com.atlassian.jira:jira-rest-java-client-core:4.0.0') {
        dependency 'com.atlassian.httpclient:atlassian-httpclient-plugin:0.23.4@jar'
        dependency 'com.atlassian.sal:sal-api:3.1.0@jar'
        dependency 'com.atlassian.jira:jira-rest-java-client-api:4.0.0'
        dependency 'com.atlassian.event:atlassian-event:2.3.5'
        dependency 'com.atlassian.util.concurrent:atlassian-util-concurrent:2.6.3'
        dependency 'org.springframework:spring-beans:2.5.6'
        dependency 'com.sun.jersey:jersey-client:1.19.4'
        dependency 'com.sun.jersey:jersey-json:1.19.4'
        dependency 'joda-time:joda-time:1.6.2'
        dependency 'org.apache.httpcomponents:httpmime:4.5.3'
    }
    compile 'com.github.gustavkarlsson:rocketchat-outgoing-webhook-server:3.3.0'
    compile 'com.atlassian.fugue:fugue:2.6.1'
    compile 'ch.qos.logback:logback-classic:1.2.3'
    compile 'org.apache.commons:commons-lang3:3.6'
    compile 'com.moandjiezana.toml:toml4j:0.7.1'
    compile 'com.google.inject:guice:4.1.0'
    compile 'com.google.code.findbugs:jsr305:3.0.2'
    compileOnly 'com.google.code.findbugs:jsr305:1.3.9'
    testCompile 'junit:junit:4.12'
    testCompile 'org.assertj:assertj-core:3.8.0'
    testCompile 'org.mockito:mockito-core:3.5.7'
    testCompile 'nl.jqno.equalsverifier:equalsverifier:2.3.3'
    testCompile 'org.glassfish.jersey.core:jersey-client:2.25.1'
    testCompile 'org.skyscreamer:jsonassert:1.5.0'
}

jacocoTestReport {
    reports {
        xml.enabled = true
        html.enabled = true
    }
}

jar {
    manifest {
        attributes 'Main-Class': mainClassName
    }
}

shadowJar {
    mergeServiceFiles {
        exclude 'META-INF/*.SF'
        exclude 'META-INF/*.DSA'
        exclude 'META-INF/*.RSA'
    }
}

check.dependsOn jacocoTestReport