build.gradle

buildscript {
    repositories {
        maven { url "https://repo.grails.org/grails/core" }
        maven { url "https://plugins.gradle.org/m2/" }
    }
    dependencies {
        classpath "org.grails:grails-gradle-plugin:$grailsGradlePluginVersion"
        classpath "org.asciidoctor:asciidoctor-gradle-jvm:4.0.0"
        classpath "com.github.erdi:webdriver-binaries-gradle-plugin:3.2"
        classpath "io.github.gradle-nexus:publish-plugin:1.3.0"
    }
}

logger.lifecycle "GORM VERSION = ${project.datastoreVersion}"

group "org.grails"
version project.projectVersion

ext {
    hibernatePluginVersion = project.hibernatePluginVersion
    isCiBuild = project.hasProperty("isCiBuild") || System.getenv().get("CI") as Boolean
    isBuildSnapshot = project.version.endsWith("-SNAPSHOT")
    isReleaseVersion = !isBuildSnapshot
    servletApiVersion = "4.0.1"
    nexusUsername = System.getenv("SONATYPE_USERNAME") ?: project.hasProperty("sonatypeOssUsername") ? project.sonatypeOssUsername : ''
    nexusPassword = System.getenv("SONATYPE_PASSWORD") ?: project.hasProperty("sonatypeOssPassword") ? project.sonatypeOssPassword : ''
    isSnapshot = project.projectVersion.endsWith("-SNAPSHOT")
    groovyVersion = System.getenv('CI_GROOVY_VERSION') ?: project.groovyVersion
}

ext."signing.keyId" = project.hasProperty("signing.keyId") ? project.getProperty('signing.keyId') : System.getenv('SIGNING_KEY')
ext."signing.password" = project.hasProperty("signing.password") ? project.getProperty('signing.password') : System.getenv('SIGNING_PASSPHRASE')
ext."signing.secretKeyRingFile" = project.hasProperty("signing.secretKeyRingFile") ? project.getProperty('signing.secretKeyRingFile') : "${System.properties['user.home']}${File.separator}.gnupg${File.separator}secring.gpg"

if (isReleaseVersion) {
    apply plugin: 'maven-publish'
    apply plugin: "io.github.gradle-nexus.publish-plugin"

    nexusPublishing {
        repositories {
            sonatype {
                def ossUser = System.getenv("SONATYPE_USERNAME") ?: project.hasProperty("sonatypeOssUsername") ? project.sonatypeOssUsername : ''
                def ossPass = System.getenv("SONATYPE_PASSWORD") ?: project.hasProperty("sonatypeOssPassword") ? project.sonatypeOssPassword : ''
                def ossStagingProfileId = System.getenv("SONATYPE_STAGING_PROFILE_ID") ?: project.hasProperty("sonatypeOssStagingProfileId") ? project.sonatypeOssStagingProfileId : ''
                nexusUrl = uri("https://s01.oss.sonatype.org/service/local/")
                username = ossUser
                password = ossPass
                stagingProfileId = ossStagingProfileId
            }
        }
    }
}


allprojects {

    ext.groovyVersion = System.getenv('CI_GROOVY_VERSION') ?: project.groovyVersion

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url = 'https://repo.grails.org/grails/core' }
        maven { url = 'https://oss.sonatype.org/content/repositories/snapshots' }
        if(isSnapshot) {
            maven { url = 'https://repo.grails.org/grails/libs-snapshots-local' }
        }
        if(groovyVersion && groovyVersion.endsWith('-SNAPSHOT')) {
            maven {
                name = 'ASF Snapshot repo'
                url = 'https://repository.apache.org/content/repositories/snapshots'
            }
        }
    }

    configurations.configureEach {
        resolutionStrategy.eachDependency { DependencyResolveDetails details ->
            if ((details.requested.group == 'org.codehaus.groovy' || details.requested.group == 'org.apache.groovy') && details.requested.name != 'groovy-bom') {
                details.useTarget(group: 'org.apache.groovy', name: details.requested.name, version: groovyVersion)
                details.because "The dependency coordinates are changed in Apache Groovy 4, plus ensure version"
            }

            if (details.requested.group == "io.micronaut" && details.requested.name == "micronaut-inject-groovy") {
                details.useVersion(micronautVersion)
            }
        }

        resolutionStrategy.dependencySubstitution {

            //update fields plugin used by scaffolding
            substitute(module("org.grails.plugins:fields:3.0.0.RC1")).using(module("io.github.gpc:fields:5.0.3"))
        }
    }


}

subprojects { Project subproject ->

    ext['h2.version'] = h2Version
    ext['gorm.version'] = datastoreVersion
    ext['gorm.hibernate5.version'] = hibernatePluginVersion
    ext['junit-jupiter.version'] = junitJupiterVersion
    ext['spock.version'] = spockVersion
    ext['mongodb.version'] = mongodbDriverVersion

    if (project.name.startsWith("examples")) {

        apply plugin: 'groovy'

        if(project.name.contains('grails3')) {

            apply plugin:"org.grails.grails-web"
            apply plugin:"org.grails.grails-gsp"
        }

        boolean usesGeb = project.name.contains('grails3-hibernate5-mongodb') || project.name.contains('grails3-mongodb') || project.name.contains('grails3-mongodb-database-per-tenant')|| project.name.contains('grails3-rxmongodb')

        if (usesGeb) {
            apply plugin:"com.github.erdi.webdriver-binaries"
        }

        if (project.name == "examples-test-data-service") {
            apply plugin:"org.grails.grails-web"
        }

        configurations.configureEach {
            resolutionStrategy.eachDependency { DependencyResolveDetails details ->
                if(details.requested.group == 'org.apache.groovy' && details.requested.name.startsWith('groovy')) {
                    details.useVersion(groovyVersion)
                } else if (details.requested.group == 'org.mongodb' && details.requested.module.name != 'mongodb-driver-rx') {
                    details.useVersion(mongodbDriverVersion)
                } else if (details.requested.group == 'org.springframework') {
                    details.useVersion(springVersion)
                } else if (details.requested.group == "org.springframework.boot") {
                    details.useVersion(springBootVersion)
                }
            }
        }

        dependencies {
            testImplementation "jakarta.annotation:jakarta.annotation-api:$jakartaAnnotationApiVersion"
            testImplementation "io.micrometer:micrometer-core:latest.integration"
            testImplementation "org.hibernate:hibernate-validator:$hibernateValidatorVersion"
            testImplementation "org.apache.groovy:groovy-test-junit5:$groovyVersion"
            testImplementation "org.spockframework:spock-core:$spockVersion", { transitive = false }
            testImplementation "org.junit.jupiter:junit-jupiter-api:$junitJupiterVersion"
            testImplementation "org.junit.platform:junit-platform-runner:$junitJupiterPlatformVersion"
            testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitJupiterVersion"
        }

        tasks.withType(Test) {
            useJUnitPlatform()
            testLogging {
                showStandardStreams = true
                exceptionFormat = 'full'
            }
        }

        tasks.withType(Jar).configureEach {
            duplicatesStrategy = DuplicatesStrategy.INCLUDE
        }

        return
    }

    boolean isPluginProject = project.name.endsWith("-plugin") && (project.name.startsWith("grails") || project.name.startsWith("rx-"))
    boolean isGrails3PluginProject = project.name.endsWith("-plugin")

    ext {
        projectInfo = new PublishingConvention(project)
        pomInfo = {
            delegate.name projectInfo.projectName
            delegate.description projectInfo.projectDescription
            delegate.url projectInfo.projectURL

            delegate.licenses {
                delegate.license {
                    delegate.name 'The Apache Software License, Version 2.0'
                    delegate.url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                    delegate.distribution 'repo'
                }
            }

            delegate.scm {
                delegate.url projectInfo.projectVcsUrl
                delegate.connection projectInfo.projectVcsUrl
                delegate.developerConnection projectInfo.projectVcsUrl
            }


            delegate.developers {
                delegate.developer {
                    delegate.id 'graemerocher'
                    delegate.name 'Graeme Rocher'
                }
                delegate.developer {
                    delegate.id 'jeffscottbrown'
                    delegate.name 'Jeff Brown'
                }
                delegate.developer {
                    delegate.id 'burtbeckwith'
                    delegate.name 'Burt Beckwith'
                }
            }

        }
    }

    apply plugin: 'groovy'

    if (isPluginProject) {
        group "org.grails.plugins"
        version(rootProject.version)
    } else {
        group "org.grails"
        version rootProject.version
    }

    if (project.name == 'docs') {
        return
    }

    if (isGrails3PluginProject) {
        apply plugin: "org.grails.grails-plugin"
    } else {
        apply plugin: "groovy"
    }

    apply plugin: "java-library"
    apply plugin: 'maven-publish'
    apply plugin: 'signing'

    if (project.name == "examples-test-data-service") {
        apply plugin:"org.grails.plugins.views-json"
    }

    java {
        toolchain {
            languageVersion = JavaLanguageVersion.of(17)
        }
        withJavadocJar()
        withSourcesJar()
    }

    configurations {
        all {
            resolutionStrategy {
                force "org.apache.groovy:groovy:$groovyVersion"
                force "org.apache.groovy:groovy-dateutil:$groovyVersion"
                force "org.apache.groovy:groovy-xml:$groovyVersion"
                force "org.apache.groovy:groovy-templates:$groovyVersion"
            }
        }
    }

    configurations.all {
        resolutionStrategy.eachDependency { DependencyResolveDetails details ->
            def dependencyName = details.requested.name
            if (dependencyName.startsWith('mongodb-driver') &&  !dependencyName.contains('-rx')) {
                details.useVersion(mongodbDriverVersion)
            } else if( details.requested.group == 'org.grails' &&
                    details.requested.name in ['grails-datastore-core',
                                               'grails-datastore-async',
                                               'grails-datastore-gorm',
                                               'grails-datastore-gorm-async',
                                               'grails-datastore-gorm-rx',
                                               'grails-datastore-gorm-support',
                                               'grails-datastore-gorm-tck',
                                               'grails-datastore-gorm-test',
                                               'grails-datastore-gorm-validation',
                                               'grails-datastore-web']
            ) {
                details.useVersion(datastoreVersion)
            } else if (details.requested.group == 'org.mongodb' && details.requested.module.name != 'mongodb-driver-rx') {
                details.useVersion(mongodbDriverVersion)
            } else if(details.requested.group == 'org.springframework') {
                details.useVersion(springVersion)
            } else if (details.requested.group == 'org.springframework.boot') {
                details.useVersion(springBootVersion)
            }
        }
    }

    dependencies {
        api "org.apache.groovy:groovy:$groovyVersion"
        api "org.apache.groovy:groovy-templates:$groovyVersion"

        testImplementation "org.apache.groovy:groovy-json:$groovyVersion"
        testImplementation "org.apache.groovy:groovy-templates:$groovyVersion"
        testImplementation "org.apache.groovy:groovy-test-junit5:$groovyVersion"
        testImplementation "org.spockframework:spock-core:$spockVersion", { transitive = false }
        testImplementation "org.junit.jupiter:junit-jupiter-api:$junitJupiterVersion"
        testImplementation "org.junit.platform:junit-platform-runner:$junitJupiterPlatformVersion"
        testRuntimeOnly "org.junit.jupiter:junit-jupiter-engine:$junitJupiterVersion"
    }

    publishing {

        if (isBuildSnapshot) {
            repositories {
                maven {
                    credentials {
                        def u = System.getenv("ARTIFACTORY_USERNAME") ?: project.hasProperty("artifactoryPublishUsername") ? project.artifactoryPublishUsername : ''
                        def p = System.getenv("ARTIFACTORY_PASSWORD") ?: project.hasProperty("artifactoryPublishPassword") ? project.artifactoryPublishPassword : ''
                        username = u
                        password = p
                    }
                    if (isGrails3PluginProject) {
                        url "https://repo.grails.org/grails/plugins3-snapshots-local"
                    } else {
                        url "https://repo.grails.org/grails/libs-snapshots-local"
                    }
                }
            }
        }

        publications {
            maven(MavenPublication) {

                pom {
                    name = projectInfo.projectName
                    description = projectInfo.projectDescription
                    url = projectInfo.projectURL

                    licenses {
                        license {
                            name = 'The Apache Software License, Version 2.0'
                            url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                            distribution = 'repo'
                        }
                    }

                    scm {
                        url = 'scm:git@github.com:grails/gorm-mongodb.git'
                        connection = 'scm:git@github.com:grails/gorm-mongodb.git'
                        developerConnection = 'scm:git@github.com:grails/gorm-mongodb.git'
                    }

                    developers {
                        developer {
                            id = 'puneetbehl'
                            name = 'Puneet Behl'
                            email = 'behlp@objectcomputing.com'
                        }
                    }
                }

                artifactId projectInfo.projectArtifactId
                from components.java

                afterEvaluate {
                    if (isGrails3PluginProject) {
                        artifact source:"${sourceSets.main.groovy.getClassesDirectory().get().getAsFile()}/META-INF/grails-plugin.xml",
                                classifier:"plugin",
                                extension:'xml'
                    }
                }

                pom.withXml {
                    def xml = asNode()
                    def dependency = xml.dependencies.find { dep -> dep.artifactId == 'slf4j-simple' }
                    dependency?.optional = true
                }
            }
        }
    }

    afterEvaluate {
        signing {
            required { isReleaseVersion }
            sign publishing.publications.maven
        }
    }

    tasks.withType(Sign) {
        onlyIf { isReleaseVersion }
    }

    //do not generate extra load on Nexus with new staging repository if signing fails
    tasks.withType(io.github.gradlenexus.publishplugin.InitializeNexusStagingRepository).configureEach {
        shouldRunAfter(tasks.withType(Sign))
    }
}

class PublishingConvention {
    Project project

    String projectArtifactId
    String projectName = 'GORM for MongoDB'
    String projectDescription = 'Provides a GORM Object Mapping implementations for the MongodB Document Database'
    String projectURL = 'https://gorm.grails.org/latest/mongodb'
    String projectIssueTrackerUrl = 'https://github.com/grails/gorm-mongodb/issues'
    String projectVcsUrl = 'https://github.com/grails/gorm-mongodb'

    PublishingConvention(Project project) {
        this.project = project

        def name = project.name
        if(name.startsWith('grails') && name.endsWith('-plugin')) {
            name = 'mongodb'
        }
        if(name.startsWith('rx') && name.endsWith('-plugin')) {
            name = 'rx-mongodb'
            projectName = 'RxGORM for MongoDB'
        }        
        projectArtifactId = name
    }
}