80mA PWM, perfect to drive Mosfets

[dbuezas]

The 80mAh drive is spectacular to drive logic level Mosfets w/o a driver at high speed. Unfortunately the only timer that has "convenient" 80mAh pins (in the QFP32) as output is timer0 (D5 and D6), which is the 8 bit timer with less modes and one looses millis() and delay().

Timer 3 can also be used (by enabling the alternate outputs to F1 and F2), but F1 and F2 are exposed as D1 and D2 which are the standard serial pins.

void setup() {
  noInterrupts();
  TIMSK0 = 0;  // disable interrupts on timer0. millis() and delay() don't work
               // anymore
  TCCR0A = 0b10 << COM0A0 |  // set D6 on compare match, so it can get to true 0
           0b10 << COM0B0 |  // set D5 on compare match
           0b11 << WGM00;    // FPWM, top is 255
  TCCR0B = 0b0 << WGM02 |    //
           0b01 << CS00;     //  prescaler=1. Frequency is 125kHz (32000000/256)
  // TCKSCR = 1 << F2XEN | 1 << TC2XS1;  // double timer 1 clock speed to 64MHz
  OCR0A = 0;        // D6 off
  OCR0B = 0;        // D5 off
  HDR = 0b11 << 0;  // Enable 80mA high current in D5 and D6

  // check the datasheet to understand what all of this is

  pinMode(D5, OUTPUT);
  pinMode(D6, OUTPUT);
  interrupts();
}

// The normal delay() can't be used because we are using timer0 ourselves.
void myDelay(uint32_t ms) {
  for (; ms > 0; ms--) delayMicroseconds(1000);
}

void loop() {
  OCR0A = 128;  // D6 pin. From 0 to 255. 128=50% duty;
  for (int duty = 0; duty < 256; duty++) {
    OCR0B = duty;  // D5 from 0% to 100% (actually from 0.4%)
    myDelay(100);
  }
}

[dbuezas]

There are also dead time settings and high power options for timers 1 and 3, see here
https://dbuezas.github.io/arduino-web-timers/#mcu=LGT8F328P&timer=1&CompareOutputModeA=set-on-match%2C+clear-at-max&OCnA_OutputCurrent=80mA&OCnB_OutputCurrent=80mA&DeadTime=on&DTR1H=23&OCR1A=171&DTR1L=21&OCR1B=115&CompareOutputModeB=clear-on-match%2C+set-at-max

[dbuezas]

[jokokiswan]

Awesome!