build.gradle

buildscript {
  ext {
    lombokVersion = '1.16.20'
    logbackVersion = '1.2.3'
    slf4jVersion = '1.7.25'
  }
  repositories {
    maven {
      url "https://plugins.gradle.org/m2/"
    }
  }
  dependencies {
    classpath "io.franzbecker:gradle-lombok:1.14"
    classpath "gradle.plugin.com.github.spotbugs:spotbugs-gradle-plugin:1.6.2"
  }
}

apply plugin: "java"
apply plugin: "com.github.spotbugs"
apply plugin: "io.franzbecker.gradle-lombok"

repositories {
  mavenCentral()
  jcenter()
}

defaultTasks 'clean', 'check'

lombok {
  version = project.lombokVersion
}

spotbugs {
  toolVersion = '3.1.3'
  ignoreFailures = true
  effort = 'max'
  showProgress = true
}

sourceSets {
  // we define `main` sourceSet here, so SpotBugs Gradle Plugin generates `spotbugsMain` task
  main {
    java.srcDirs = ['src/main/java']
  }
}

// To generate an HTML report instead of XML
tasks.withType(com.github.spotbugs.SpotBugsTask) {
  reports {
    xml.enabled = false
    html.enabled = true
  }
}

dependencies {
  compile "org.slf4j:slf4j-api:$slf4jVersion"
  compile "org.slf4j:jul-to-slf4j:$slf4jVersion"
  compile "org.slf4j:log4j-over-slf4j:$slf4jVersion"
  compile "ch.qos.logback:logback-classic:$logbackVersion"

  testCompile 'junit:junit:4.12'

  spotbugsPlugins 'com.h3xstream.findsecbugs:findsecbugs-plugin:1.7.1'
}