build.gradle

buildscript {
  ext.versions = [
      minSdk                   : 21,
      compileSdk               : 30,
      kotlin                   : '1.4.30',
      supportLib               : '1.0.0',
      recyclerView             : '1.0.0',
      material                 : '1.3.0',
      cardview                 : '1.0.0',
      room                     : '2.2.6',
      androidXTestExt          : '1.1.1',
      androidXTest             : '1.2.0',
      timber                   : '4.7.0',
      dagger                   : '2.32',
      butterKnife              : '8.8.1',
      coreTesting              : '2.0.0',
      moshi                    : '1.9.2',
      retrofit                 : '2.9.0',
      sentry                   : '1.7.22',
      sentryGradlePlugin       : '1.7.36',
      slf4j                    : '1.7.25',
      flow                     : '1.0.0-alpha3',
      rxJava                   : '2.2.16',
      rxAndroid                : '2.1.1',
      rxBinding                : '2.1.1',
      rxBinding3               : '3.1.0',
      rxKotlin                 : '2.4.0',
      rxPreference             : '2.0.0',
      okLoggingInterceptor     : '3.10.0',
      traceur                  : '2.2.12',
      maskedEditText           : '1.0.5',
      itemAnimators            : '1.0.2',
      jbcrypt                  : '0.3m',
      workManager              : '2.5.0',
      faker                    : '1.2.8',
      truth                    : '1.1.2',
      junit                    : '4.12',
      mockitoKotlin            : '2.2.0',
      junitParams              : '1.1.1',
      sqliteAndroid            : '3.32.2',
      playServicesAuth         : '16.0.1',
      playServicesVision       : '16.2.0',
      viewPump                 : '2.0.3',
      pinEntryEditText         : '2.0.6',
      javaStringSimilarity     : '1.1.0',
      leakCanary               : '2.1',
      constraintLayout         : '2.0.4',
      playServicesLocation     : '16.0.0',
      firebaseConfig           : '19.2.0',
      firebasePerformance      : '19.0.8',
      firebasePerformancePlugin: '1.3.1',
      googleServices           : '4.3.3',
      playCore                 : '1.6.1',
      fastScroll               : '2.0.0',
      mixpanel                 : '5.6.4',
      mobius                   : '1.3.0',
      guava                    : '28.1-jre', // Used by the 'mobius-migration' library ONLY in tests
      uuidGenerator            : '3.2.0',
      flipper                  : '0.37.0',
      soloader                 : '0.5.1',
      asm                      : '7.2',
      ktlint                   : '0.36.0',
      quarantine               : '0.3.0',
      jackson                  : '2.10.2',
      logback                  : '1.2.3',
      camerax                  : '1.0.0-rc01',
      cameraView               : '1.0.0-alpha20',
      cameraLifecycle          : '1.0.0-rc01',
      zxing                    : '3.3.3',
      paging                   : '2.1.2',

      // When bumping this dependency, verify whether `org.simple.clinic.feature.Feature.ChangeLanguage`
      // can be enabled again.
      appcompat                : '1.2.0',

      navigation               : '2.3.0',
      lottie                   : '3.4.0',
      desugarJdk               : '1.0.9',
      signaturePad             : '1.3.1',
      viewpager2               : '1.0.0',
      lint                     : '27.1.1',
      rootbeer                 : '5fef9f62f9',
      mlKitBarcode             : '16.1.2',
      fragment                 : '1.2.5'
  ]

  repositories {
    google()
    mavenCentral()
    maven { url 'https://jitpack.io' }
  }

  dependencies {
    classpath 'com.android.tools.build:gradle:4.2.1'
    classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlin"
    classpath "io.sentry:sentry-android-gradle-plugin:$versions.sentryGradlePlugin"
    classpath "com.google.gms:google-services:$versions.googleServices"
    classpath 'com.google.firebase:firebase-crashlytics-gradle:2.4.1'
    classpath "com.google.firebase:perf-plugin:$versions.firebasePerformancePlugin"
  }
}

plugins {
  id "com.diffplug.spotless" version "5.6.1"
}

allprojects {
  repositories {
    google()
    mavenCentral()

    // Left to support migration away from JCenter, do not add any new dependency inclusions here.
    // See: https://jeroenmols.com/blog/2021/02/04/migratingjcenter/
    jcenter() {
      content {
        // :app
        includeModule("com.facebook.flipper", "flipper")
        includeModule("com.facebook.flipper", "flipper-network-plugin")
        includeModule("io.requery", "sqlite-android")
        includeModule("ru.egslava", "MaskedEditText")

        // :lint
        includeModule("org.jetbrains.trove4j", "trove4j")
      }
    }
  }
}

subprojects {
  apply plugin: 'com.diffplug.spotless'

  // https://github.com/diffplug/spotless/tree/master/plugin-gradle
  spotless {
    lineEndings 'UNIX'

    kotlin {
      ktlint(versions.ktlint).userData([
          'indent_style'            : 'space',
          'indent_size'             : '2',
          'continuation_indent_size': '4'
      ])

      trimTrailingWhitespace()
      endWithNewline()
    }
  }
}

task cleanRoot(type: Delete) {
  delete rootProject.buildDir
}