-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathSerialOSCClient.sc
2186 lines (1787 loc) · 52.7 KB
/
SerialOSCClient.sc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
SerialOSCClient {
classvar prefix='/monome';
classvar defaultLegacyModeListenPort=8080;
classvar devicesListSemaphore;
classvar autoconnect;
classvar <>verbose;
classvar recvSerialOSCFunc, oscRecvFunc, legacyModeOscRecvFunc;
classvar deviceAddedHandler, deviceRemovedHandler;
classvar <devices, <connectedDevices;
classvar <all;
classvar <initialized=false;
classvar <runningLegacyMode=false;
var gridKeyResponder, tiltResponder;
var encDeltaResponder, encKeyResponder;
var <name;
var <autoroute;
var <>permanent;
var <gridSpec, <encSpec;
var <grid, <enc;
var <>willFree;
var <>onFree;
var <active;
var <>onGridRouted, <>onGridUnrouted, <>gridRefreshAction;
var <>onEncRouted, <>onEncUnrouted, <>encRefreshAction;
var <>gridKeyAction, <>encDeltaAction, <>encKeyAction, <>tiltAction;
*initClass {
all = [];
devices = [];
connectedDevices = [];
devicesListSemaphore = Semaphore.new;
CmdPeriod.add(this);
oscRecvFunc = { |msg, time, addr, recvPort|
if (addr.ip == "127.0.0.1") {
this.prLookupDeviceByPort(addr.port) !? { |device|
if (connectedDevices.includes(device)) {
if (#['/monome/grid/key', '/monome/tilt', '/monome/enc/delta', '/monome/enc/key'].includes(msg[0])) { // note: no pattern matching is performed on OSC address
var type = msg[0].asString[7..].asSymbol;
recvSerialOSCFunc.value(type, msg[1..], time, device);
};
};
};
};
};
legacyModeOscRecvFunc = { |msg, time, addr, recvPort|
if (addr.ip == "127.0.0.1") {
this.prLookupDeviceByPort(addr.port) !? { |device|
if (connectedDevices.includes(device)) {
if ('/monome/press' == msg[0]) { // note: no pattern matching is performed on OSC address
recvSerialOSCFunc.value('/grid/key', msg[1..], time, device);
};
};
};
};
};
deviceAddedHandler = { |id|
fork {
devicesListSemaphore.wait;
if (this.prLookupDeviceById(id).isNil) {
this.prUpdateDevicesListAsync {
this.prLookupDeviceById(id) !? { |device|
this.prSyncAfterDeviceListChanges([device], []);
SerialOSCClientNotification.postDeviceAttached(device);
};
devicesListSemaphore.signal;
};
} {
devicesListSemaphore.signal;
};
};
};
deviceRemovedHandler = { |id|
fork {
devicesListSemaphore.wait;
this.prLookupDeviceById(id) !? { |device|
this.prSyncAfterDeviceListChanges([], [device]);
SerialOSCClientNotification.postDeviceDetached(device);
};
devicesListSemaphore.signal;
};
};
}
*init { |completionFunc, autoconnect=true, autodiscover=true, verbose=false|
this.prInit(autoconnect, verbose);
if (autodiscover) {
SerialOSC.startTrackingConnectedDevicesChanges(deviceAddedHandler, deviceRemovedHandler);
};
thisProcess.addOSCRecvFunc(oscRecvFunc);
initialized = true;
runningLegacyMode = false;
this.prUpdateDevicesListAsync { |devicesAddedToDevicesList, devicesRemovedFromDevicesList|
this.postDevices;
this.prSyncAfterDeviceListChanges(devicesAddedToDevicesList, devicesRemovedFromDevicesList);
completionFunc.value;
};
}
*legacy40h { |autoconnect=true, verbose=false|
this.prLegacyMode(autoconnect, verbose, LegacySerialOSCGrid('monome 40h', nil, defaultLegacyModeListenPort, 0));
}
*legacy64 { |autoconnect=true, verbose=false|
this.prLegacyMode(autoconnect, verbose, LegacySerialOSCGrid('monome 64', nil, defaultLegacyModeListenPort, 0));
}
*legacy128 { |autoconnect=true, verbose=false|
this.prLegacyMode(autoconnect, verbose, LegacySerialOSCGrid('monome 128', nil, defaultLegacyModeListenPort, 0));
}
*legacy256 { |autoconnect=true, verbose=false|
this.prLegacyMode(autoconnect, verbose, LegacySerialOSCGrid('monome 256', nil, defaultLegacyModeListenPort, 0));
}
*prLegacyMode { |autoconnect=true, verbose=false, legacyGrid|
var devicesRemovedFromDevicesList;
this.prInit(autoconnect, verbose);
thisProcess.addOSCRecvFunc(legacyModeOscRecvFunc);
initialized = true;
runningLegacyMode = true;
devicesRemovedFromDevicesList = devices;
devices = [legacyGrid];
this.postDevices;
this.prSyncAfterDeviceListChanges(devices, devicesRemovedFromDevicesList);
"SerialOSCClient is running in legacy mode. For an attached grid to work MonomeSerial has to run and be configured with Host Port %, Address Prefix /monome and Listen Port %.".format(NetAddr.langPort, legacyGrid.port).postln;
}
*prInit { |argAutoconnect, argVerbose|
autoconnect = argAutoconnect;
verbose = argVerbose;
this.prRemoveRegisteredOSCRecvFuncsIfAny;
if (SerialOSC.isTrackingConnectedDevicesChanges) {
SerialOSC.stopTrackingConnectedDevicesChanges
};
}
*prSyncAfterDeviceListChanges { |devicesAddedToDevicesList, devicesRemovedFromDevicesList|
devicesRemovedFromDevicesList do: _.remove;
devicesAddedToDevicesList do: { |device|
SerialOSCClientNotification.deviceAttached(device);
};
if (autoconnect) { devicesAddedToDevicesList do: _.connect };
this.prUpdateDefaultDevices(devicesAddedToDevicesList, devicesRemovedFromDevicesList);
}
*prRemoveRegisteredOSCRecvFuncsIfAny {
thisProcess.removeOSCRecvFunc(oscRecvFunc);
thisProcess.removeOSCRecvFunc(legacyModeOscRecvFunc);
}
*addSerialOSCRecvFunc { |func| recvSerialOSCFunc = recvSerialOSCFunc.addFunc(func) }
*removeSerialOSCRecvFunc { |func| recvSerialOSCFunc = recvSerialOSCFunc.removeFunc(func) }
*freeAll {
all.copy do: _.free;
}
*cmdPeriod {
all.reject { |client| client.permanent }.copy.do(_.free);
}
*prGetPrefixedAddress { |address|
^(prefix.asString++address.asString).asSymbol
}
*prUpdateDefaultDevices { |devicesAddedToDevicesList, devicesRemovedFromDevicesList|
this.prUpdateDefaultGrid(devicesAddedToDevicesList, devicesRemovedFromDevicesList);
this.prUpdateDefaultEnc(devicesAddedToDevicesList, devicesRemovedFromDevicesList);
}
*prUpdateDefaultGrid { |devicesAddedToDevicesList, devicesRemovedFromDevicesList|
var addedAndConnected, connectedNotRoutedToAClient;
addedAndConnected = devicesAddedToDevicesList.reject(this.prDeviceIsEncByType(_)).select(_.isConnected);
connectedNotRoutedToAClient = SerialOSCGrid.connected.reject { |device| device.client.notNil };
case
{ SerialOSCGrid.default.isNil and: addedAndConnected.notEmpty } {
SerialOSCGrid.default = addedAndConnected.first
}
{ devices.includes(SerialOSCGrid.default).not } {
SerialOSCGrid.default = case
{ addedAndConnected.notEmpty } { addedAndConnected.first }
{ connectedNotRoutedToAClient.notEmpty } { connectedNotRoutedToAClient.first }
}
}
*prUpdateDefaultEnc { |devicesAddedToDevicesList, devicesRemovedFromDevicesList|
var addedAndConnected, connectedNotRoutedToAClient;
addedAndConnected = devicesAddedToDevicesList.select(this.prDeviceIsEncByType(_)).select(_.isConnected);
connectedNotRoutedToAClient = SerialOSCEnc.connected.reject { |device| device.client.notNil };
case
{ SerialOSCEnc.default.isNil and: addedAndConnected.notEmpty } {
SerialOSCEnc.default = addedAndConnected.first
}
{ devices.includes(SerialOSCEnc.default).not } {
SerialOSCEnc.default = case
{ addedAndConnected.notEmpty } { addedAndConnected.first }
{ connectedNotRoutedToAClient.notEmpty } { connectedNotRoutedToAClient.first }
}
}
*connectAll {
devices do: { |device| this.connect(device) }
}
*connect { |device|
this.prEnsureInitialized;
if (connectedDevices.includes(device).not) {
runningLegacyMode.not.if {
SerialOSC.changeDeviceMessagePrefix(
device.port,
prefix
);
SerialOSC.changeDeviceDestinationPort(
device.port,
NetAddr.langPort
);
};
connectedDevices = connectedDevices.add(device);
SerialOSCClientNotification.deviceConnected(device);
this.prAutorouteDeviceToClients;
};
}
*prAutorouteDeviceToClients {
var clients;
clients = SerialOSCClient.all.select(_.autoroute);
clients.do { |client| client.findAndRouteUnusedDevicesToClient(true) };
clients.do { |client| client.findAndRouteUnusedDevicesToClient(false) };
}
*doGridKeyAction { |x, y, state, device|
this.prDispatchEvent('/grid/key', [x.asInteger, y.asInteger, state.asInteger], device);
}
*doEncDeltaAction { |n, delta, device|
this.prDispatchEvent('/enc/delta', [n.asInteger, delta.asInteger], device);
}
*doTiltAction { |n, x, y, z, device|
this.prDispatchEvent('/tilt', [n.asInteger, x.asInteger, y.asInteger, z.asInteger], device);
}
*doEncKeyAction { |n, state, device|
this.prDispatchEvent('/enc/key', [n.asInteger, state.asInteger], device);
}
*prDispatchEvent { |type, args, device|
this.prEnsureInitialized;
recvSerialOSCFunc.value(type, args, SystemClock.seconds, device);
}
*disconnectAll {
devices do: { |device| this.disconnect(device) }
}
*disconnect { |device|
this.prEnsureInitialized;
if (connectedDevices.includes(device)) {
device.unroute;
connectedDevices.remove(device);
SerialOSCClientNotification.deviceDisconnected(device);
};
}
*postDevices {
if (devices.notEmpty) {
"SerialOSC Devices:".postln;
devices.do { |device| (Char.tab ++ device).postln };
} {
"No SerialOSC Devices are attached".postln;
};
}
*prDeviceIsEncByType { |device|
^this.prIsEncType(device.type)
}
*prListEntryIsEncByType { |device|
^this.prIsEncType(device[\type])
}
*prIsEncType { |type|
^type.asString.contains("arc")
}
*prUpdateDevicesListAsync { |completionFunc|
SerialOSC.requestListOfDevices { |list|
var currentDevices, foundDevices, devicesToRemove, devicesToAdd;
currentDevices = devices.as(IdentitySet);
foundDevices = list.collect { |entry|
devices.detect { |serialOSCDevice| serialOSCDevice.id == entry[\id] } ?? {
if (this.prListEntryIsEncByType(entry)) {
SerialOSCEnc(entry[\type], entry[\id], entry[\receivePort]);
} {
SerialOSCGrid(entry[\type], entry[\id], entry[\receivePort], 0);
};
};
}.as(IdentitySet);
devicesToRemove = currentDevices - foundDevices;
devicesToAdd = foundDevices - currentDevices;
devices.removeAll(devicesToRemove);
devices = devices.addAll(devicesToAdd);
completionFunc.(devicesToAdd.as(Array), devicesToRemove.as(Array));
};
}
*prLookupDeviceById { |id|
^devices.detect { |device| device.id == id.asSymbol }
}
*prLookupDeviceByPort { |receivePort|
^devices.detect { |device| device.port == receivePort }
}
*prEnsureInitialized {
initialized.not.if { Error("SerialOSCClient has not been initialized").throw };
}
*grid { |name, func, gridSpec=\any, autoroute=true|
^this.new(name, gridSpec, \none, func, autoroute);
}
*enc { |name, func, encSpec=\any, autoroute=true|
^this.new(name, \none, encSpec, func, autoroute);
}
*gridEnc { |name, func, gridSpec, encSpec, autoroute=true|
^this.new(name, gridSpec, encSpec, func, autoroute);
}
*new { |name, gridSpec=\any, encSpec=\any, func, autoroute=true|
^super.new.initSerialOSCClient(name, gridSpec, encSpec, func, autoroute)
}
*doWhenInitialized { |func|
if (initialized, func, {
this.init(func);
});
}
initSerialOSCClient { |argName, argGridSpec, argEncSpec, func, argAutoroute|
name = argName;
gridSpec = argGridSpec;
encSpec = argEncSpec;
autoroute = argAutoroute;
permanent = false;
func.value(this);
active = true;
SerialOSCClient.doWhenInitialized {
if (argAutoroute) { this.findAndRouteUnusedDevicesToClient(false) };
};
all = all.add(this);
}
printOn { arg stream;
stream << this.class.name << "(" <<<*
[name, gridSpec, encSpec] <<")"
}
usesGrid {
^gridSpec != \none
}
usesEnc {
^encSpec != \none
}
*prFindGrid { |gridSpec, strict|
var strictMatch = this.prDefaultGridIfFreeAndMatching(gridSpec) ? this.prFirstFreeGridMatching(gridSpec);
^if (strict) {
strictMatch
} {
strictMatch ? this.prDefaultGridIfFree ? SerialOSCGrid.unrouted.first;
}
}
*prDefaultGridIfFreeAndMatching { |gridSpec|
var freeDefaultGrid = this.prDefaultGridIfFree;
^if (freeDefaultGrid.notNil) {
if (this.gridMatchesSpec(freeDefaultGrid, gridSpec)) {
freeDefaultGrid;
}
};
}
*prDefaultGridIfFree {
var defaultGrid = SerialOSCGrid.default;
^if (defaultGrid.notNil) {
if (defaultGrid.client.isNil) {
defaultGrid;
}
};
}
*prFirstFreeGridMatching { |gridSpec|
^SerialOSCGrid.unrouted.select {|grid|this.gridMatchesSpec(grid, gridSpec)}.first;
}
*prFindEnc { |encSpec, strict|
var strictMatch = this.prDefaultEncIfFreeAndMatching(encSpec) ? this.prFirstFreeEncMatching(encSpec);
^if (strict) {
strictMatch
} {
strictMatch ? this.prDefaultEncIfFree ? SerialOSCEnc.unrouted.first;
}
}
*prDefaultEncIfFreeAndMatching { |encSpec|
var freeDefaultEnc = this.prDefaultEncIfFree;
^if (freeDefaultEnc.notNil) {
if (this.encMatchesSpec(freeDefaultEnc, encSpec)) {
freeDefaultEnc;
}
};
}
*prDefaultEncIfFree {
var defaultEnc = SerialOSCEnc.default;
^if (defaultEnc.notNil) {
if (defaultEnc.client.isNil) {
defaultEnc;
}
};
}
*prFirstFreeEncMatching { |encSpec|
^SerialOSCEnc.unrouted.select {|enc|this.encMatchesSpec(enc, encSpec)}.first;
}
findAndRouteUnusedDevicesToClient { |strict|
this.findAndRouteAnyUnusedGridToClient(strict);
this.findAndRouteAnyUnusedEncToClient(strict);
}
findAndRouteAnyUnusedGridToClient { |strict|
if (this.usesGrid and: grid.isNil) {
SerialOSCClient.prFindGrid(gridSpec, strict) !? { |foundGrid| this.prRouteGridToClient(foundGrid) }
};
}
findAndRouteAnyUnusedEncToClient { |strict|
if (this.usesEnc and: enc.isNil) {
SerialOSCClient.prFindEnc(encSpec, strict) !? { |foundEnc| this.prRouteEncToClient(foundEnc) }
};
}
prRouteGridToClient { |argGrid|
grid = argGrid;
gridKeyResponder = GridKeyFunc.new(
{ |x, y, state, time, device|
gridKeyAction.value(this, x, y, state);
},
device: \client -> this
);
gridKeyResponder.permanent = true;
tiltResponder = TiltFunc.new(
{ |n, x, y, z, time, device|
tiltAction.value(this, n, x, y, z);
},
device: \client -> this
);
tiltResponder.permanent = true;
grid.client = this;
onGridRouted.value(this, grid);
SerialOSCClientNotification.deviceRouted(grid, this);
this.warnIfGridDoesNotMatchSpec;
this.clearAndRefreshGrid;
}
prRouteEncToClient { |argEnc|
enc = argEnc;
encDeltaResponder = EncDeltaFunc.new(
{ |n, delta, time, device|
encDeltaAction.value(this, n, delta);
},
device: \client -> this
);
encDeltaResponder.permanent = true;
encKeyResponder = EncKeyFunc.new(
{ |n, state, time, device|
encKeyAction.value(this, n, state);
},
device: \client -> this
);
encKeyResponder.permanent = true;
enc.client = this;
onEncRouted.value(this, enc);
SerialOSCClientNotification.deviceRouted(enc, this);
this.warnIfEncDoesNotMatchSpec;
this.clearAndRefreshEnc;
}
asSerialOSCClient { ^this }
grabDevices {
this.grabGrid;
this.grabEnc;
}
grabGrid {
if (this.usesGrid and: SerialOSCGrid.all.notEmpty) {
SerialOSCClient.route(SerialOSCGrid.all.first, this);
};
}
grabEnc {
if (this.usesEnc and: SerialOSCEnc.all.notEmpty) {
SerialOSCClient.route(SerialOSCEnc.all.first, this);
};
}
*route { |device, client|
this.prRoute(device, client.asSerialOSCClient);
}
*prRoute { |device, client|
if (device.respondsTo(\ledSet)) { this.prRouteGrid(device, client) };
if (device.respondsTo(\ringSet)) { this.prRouteEnc(device, client) };
}
*prRouteGrid { |grid, client|
client.usesGrid.not.if {
"Client % does not use a grid".format(client).postln;
} {
client.grid.notNil.if { client.unrouteGrid };
grid.client.notNil.if { grid.unroute };
client.prRouteGridToClient(grid);
};
}
*prRouteEnc { |enc, client|
client.usesEnc.not.if {
"Client % does not use an enc".format(client).postln;
} {
client.enc.notNil.if { client.unrouteEnc };
enc.client.notNil.if { enc.unroute };
client.prRouteEncToClient(enc);
};
}
*postRoutings {
all.do { |client|
client.postln;
if (client.usesGrid) {
if (client.grid.notNil) {
"\trouted to %".format(client.grid)
} {
"\tno grid routed"
}.postln
};
if (client.usesEnc) {
if (client.enc.notNil) {
"\trouted to %".format(client.enc)
} {
"\tno enc routed"
}.postln
};
}
}
warnIfGridDoesNotMatchSpec {
SerialOSCClient.gridMatchesSpec(grid, gridSpec).not.if {
"Note: Grid % does not match client % spec: %".format(grid, this, gridSpec).postln
}
}
warnIfEncDoesNotMatchSpec {
SerialOSCClient.encMatchesSpec(enc, encSpec).not.if {
"Note: Enc % does not match client % spec: %".format(enc, this, encSpec).postln
}
}
*gridMatchesSpec { |grid, gridSpec|
var numCols, numRows;
numCols = grid.numCols;
numRows = grid.numRows;
^case
{gridSpec == \any} { true }
{gridSpec.respondsTo(\key) and: gridSpec.respondsTo(\value)} {
((gridSpec.key == \numCols) and: (gridSpec.value == numCols))
or:
((gridSpec.key == \numRows) and: (gridSpec.value == numRows))
}
{gridSpec.respondsTo(\keys)} {
(gridSpec[\numCols] == numCols) and: (gridSpec[\numRows] == numRows)
}
}
*encMatchesSpec { |enc, encSpec|
^(encSpec == \any) or: (encSpec == enc.numEncs)
}
clearAndRefreshGrid {
grid !? {
this.clearLeds;
this.refreshGrid;
};
}
refreshGrid {
grid !? {
gridRefreshAction.value(this);
}
}
clearAndRefreshEnc {
enc !? {
this.clearRings;
this.refreshEnc;
};
}
refreshEnc {
enc !? {
encRefreshAction.value(this);
}
}
unrouteGrid {
grid !? {
var gridToUnroute;
gridToUnroute = grid;
grid.client = nil;
grid.clearLeds;
grid = nil;
gridKeyResponder.free;
tiltResponder.free;
onGridUnrouted.value(this, gridToUnroute);
SerialOSCClientNotification.deviceUnrouted(gridToUnroute, this);
};
}
unrouteEnc {
enc !? {
var encToUnroute;
encToUnroute = enc;
enc.client = nil;
enc.clearRings;
enc = nil;
encDeltaResponder.free;
encKeyResponder.free;
onEncUnrouted.value(this, encToUnroute);
SerialOSCClientNotification.deviceUnrouted(encToUnroute, this);
};
}
free {
if (all.includes(this)) {
willFree.value(this);
if (this.usesGrid) { this.unrouteGrid };
if (this.usesEnc) { this.unrouteEnc };
all.remove(this);
active = false;
onFree.value(this);
};
}
clearLeds {
grid !? { |grid| grid.clearLeds };
}
activateTilt { |n|
grid !? { |grid| grid.activateTilt(n) };
}
deactivateTilt { |n|
grid !? { |grid| grid.deactivateTilt(n) };
}
ledSet { |x, y, state|
grid !? { |grid| grid.ledSet(x, y, state) };
}
ledAll { |state|
grid !? { |grid| grid.ledAll(state) };
}
ledMap { |xOffset, yOffset, bitmasks|
grid !? { |grid| grid.ledMap(xOffset, yOffset, bitmasks) };
}
ledRow { |xOffset, y, bitmasks|
grid !? { |grid| grid.ledRow(xOffset, y, bitmasks) };
}
ledCol { |x, yOffset, bitmasks|
grid !? { |grid| grid.ledCol(x, yOffset, bitmasks) };
}
ledIntensity { |i|
grid !? { |grid| grid.ledIntensity(i) };
}
ledLevelSet { |x, y, l|
grid !? { |grid| grid.ledLevelSet(x, y, l) };
}
ledLevelAll { |l|
grid !? { |grid| grid.ledLevelAll(l) };
}
ledLevelMap { |xOffset, yOffset, levels|
grid !? { |grid| grid.ledLevelMap(xOffset, yOffset, levels) };
}
ledLevelRow { |xOffset, y, levels|
grid !? { |grid| grid.ledLevelRow(xOffset, y, levels) };
}
ledLevelCol { |x, yOffset, levels|
grid !? { |grid| grid.ledLevelCol(x, yOffset, levels) };
}
tiltSet { |n, state|
grid !? { |grid| grid.tiltSet(n, state) };
}
clearRings {
enc !? { |enc| enc.clearRings };
}
ringSet { |n, x, level|
enc !? { |enc| enc.ringSet(n, x, level) };
}
ringAll { |n, level|
enc !? { |enc| enc.ringAll(n, level) };
}
ringMap { |n, levels|
enc !? { |enc| enc.ringMap(n, levels) };
}
ringRange { |n, x1, x2, level|
enc !? { |enc| enc.ringRange(n, x1, x2, level) };
}
}
SerialOSCClientNotification {
*deviceAttached { |device|
this.changed(\attached, device);
this.verbosePost("% was attached".format(device));
}
*deviceDetached { |device|
this.changed(\detached, device);
this.verbosePost("% was detached".format(device));
}
*deviceConnected { |device|
this.changed(\connected, device);
device.changed(\connected);
this.verbosePost("% was connected".format(device));
}
*deviceDisconnected { |device|
this.changed(\disconnected, device);
device.changed(\disconnected);
this.verbosePost("% was disconnected".format(device));
}
*deviceRouted { |device, client|
SerialOSCClient.changed(\routed, device, client);
device.changed(\routed, client);
this.verbosePost("% was routed to client %".format(device, client));
}
*deviceUnrouted { |device, client|
SerialOSCClient.changed(\unrouted, device, client);
device.changed(\unrouted, client);
this.verbosePost("% was unrouted from client %".format(device, client));
}
*postDeviceAttached { |device|
"A SerialOSC Device was attached to the computer:".postln;
(Char.tab ++ device).postln;
}
*postDeviceDetached { |device|
"A SerialOSC Device was detached from the computer:".postln;
(Char.tab ++ device).postln;
}
*verbosePost { |message|
SerialOSCClient.verbose.if { message.postln };
}
}
LegacySerialOSCGrid : SerialOSCGrid {
ledSet { |x, y, state|
this.prSendMsg('/led', x.asInteger, y.asInteger, state.asInteger);
}
ledAll { |state|
16.do { |x|
16.do { |y|
this.ledSet(x, y, state);
}
};
}
ledMap { |xOffset, yOffset, bitmasks|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledRow { |xOffset, y, bitmasks|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledCol { |x, yOffset, bitmasks|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledIntensity { |i|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledLevelSet { |x, y, l|
this.ledSet(x.asInteger, y.asInteger, if (l == 15, 1, 0));
}
ledLevelAll { |l|
this.ledAll(if (l == 15, 1, 0));
}
ledLevelMap { |xOffset, yOffset, levels|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledLevelRow { |xOffset, y, levels|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
ledLevelCol { |x, yOffset, levels|
NotYetImplementedError("Method not yet supported in Legacy Mode", thisMethod).throw;
}
}
SerialOSCGrid : SerialOSCDevice {
classvar <default;
var <rotation;
*all {
^SerialOSCClient.devices.reject { |device|
SerialOSCClient.prIsEncType(device.type)
}
}
*default_ { |grid|
var prevDefault;
prevDefault = default;
if (grid.isNil) {
default = nil;
} {
if (SerialOSCClient.devices.includes(grid)) {
if (grid.respondsTo(\ledSet)) {
default = grid;
} {
Error("Not a grid: %".format(grid)).throw
}
} {
Error("% is not in SerialOSCClient devices list".format(grid)).throw
};
};
if (default != prevDefault) {
this.changed(\default, default);
}
}
*unrouted {
^this.all.select {|grid|grid.client.isNil}
}
*connected {
^this.all.select(_.isConnected)
}
*new { |type, id, port, rotation|
^super.new(type, id, port).initSerialOSCGrid(rotation);
}
initSerialOSCGrid { |argRotation|
rotation = argRotation;
}
*doWithDefaultWhenInitialized { |func, defaultNotAvailableFunc|
var fallback = { ("No default grid available").postln };
SerialOSCClient.doWhenInitialized {
if (default.notNil) {
func.value(default);
} {
(defaultNotAvailableFunc ? fallback).value;
};
};
}
*testLeds {
this.doWithDefaultWhenInitialized(
_.testLeds,
{ ("Unable to run test, no default grid available").postln }
);
}
*ledDemo {
this.doWithDefaultWhenInitialized(
_.ledDemo,
{ ("Unable to run demo, no default grid available").postln }
);
}
*clearLeds {
this.doWithDefaultWhenInitialized(_.clearLeds);
}
*activateTilt { |n|
this.doWithDefaultWhenInitialized { |grid| grid.activateTilt(n) };
}
*deactivateTilt { |n|
this.doWithDefaultWhenInitialized { |grid| grid.deactivateTilt(n) };
}
*ledSet { |x, y, state|
this.doWithDefaultWhenInitialized { |grid| grid.ledSet(x, y, state) };
}
*ledAll { |state|
this.doWithDefaultWhenInitialized { |grid| grid.ledAll(state) };
}
*ledMap { |xOffset, yOffset, bitmasks|
this.doWithDefaultWhenInitialized { |grid| grid.ledMap(xOffset, yOffset, bitmasks) };
}
*ledRow { |xOffset, y, bitmasks|
this.doWithDefaultWhenInitialized { |grid| grid.ledRow(xOffset, y, bitmasks) };
}
*ledCol { |x, yOffset, bitmasks|
this.doWithDefaultWhenInitialized { |grid| grid.ledCol(x, yOffset, bitmasks) };
}
*ledIntensity { |i|
this.doWithDefaultWhenInitialized { |grid| grid.ledIntensity(i) };
}
*ledLevelSet { |x, y, l|
this.doWithDefaultWhenInitialized { |grid| grid.ledLevelSet(x, y, l) };
}
*ledLevelAll { |l|
this.doWithDefaultWhenInitialized { |grid| grid.ledLevelAll(l) };
}