publishing.gradle

apply plugin: 'maven-publish'
apply plugin: 'signing'

tasks.register("sourceJar", Jar) {
    from android.sourceSets.main.java.srcDirs
    archiveClassifier.set('sources')
}

Properties localProps = new Properties()
File localProperties = new File(rootProject.rootDir, "local.properties")
if (localProperties.exists() && localProperties.isFile()) {
    localProperties.withInputStream { localProps.load(it) }
}

project.ext["signing.keyId"] = localProps.getProperty("signing.keyId")
project.ext["signing.secretKeyRingFile"] = localProps.getProperty("signing.secretKeyRingFile")
project.ext["signing.password"] = localProps.getProperty("signing.password")

afterEvaluate {
    publishing {
        publications {
            releaseAar(MavenPublication) {
                from components.release
                artifact sourceJar

                groupId = project.ext.groupId
                artifactId = project.ext.artifactId
                version = project.ext.versionName

                pom {
                    name = 'Mockcept'
                    description = 'Library for mocking HTTP/HTTPS requests'
                    url = 'https://github.com/alexkamanin/Mockcept'

                    licenses {
                        license {
                            name = 'The Apache License, Version 2.0'
                            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        }
                    }

                    developers {
                        developer {
                            id = 'alexkamanin'
                            name = 'Alex Kamanin'
                            email = 'alexkamanin@mail.ru'
                        }
                    }

                    scm {
                        url = 'https://github.com/alexkamanin/Mockcept'
                        connection = 'scm:https://github.com/alexkamanin/Mockcept.git'
                        developerConnection = 'scm:https://github.com/alexkamanin/Mockcept.git'
                    }
                }
            }
        }

        repositories {
            maven {
                name = "sonatypeStaging"
                url = uri("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
                credentials {
                    username = localProps.getProperty("ossrhUsername")
                    password = localProps.getProperty("ossrhPassword")
                }
            }

            maven {
                name = "githubPackages"
                url = uri("https://maven.pkg.github.com/alexkamanin/Mockcept")
                credentials {
                    username = localProps.getProperty("githubUsername")
                    password = localProps.getProperty("githubToken")
                }
            }
        }
    }

    signing {
        sign(publishing.publications)
    }
}