build.gradle

// For those who want the bleeding edge
buildscript {
    repositories {
        jcenter()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            // for cursegradle
            url = "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT'
        // for cursegradle
        classpath "gradle.plugin.com.matthewprenger:CurseGradle:1.0.7"
    }
}

apply plugin: 'com.matthewprenger.cursegradle'
apply plugin: 'scala'

apply plugin: 'net.minecraftforge.gradle.forge'

repositories {
    mavenCentral()
    jcenter()
    maven {
        name "ddd"
        url "http://doubledoordev.net:8082/artifactory/mods"//http://box1.dmodoomsirius.me:8081/artifactory/libs-release/"
    }
    maven {
        name "dsiriusArt"
        url "http://box1.dmodoomsirius.me:8081/artifactory/libs-release/"
    }
}

dependencies {
    deobfCompile "temportalist.origin:Origin:${version_origin_dep}"
    deobfCompile "mezz.jei:jei_${version_minecraft}:${version_jei}"
}

ext.getBuildNumber = {
    if (System.getenv("BUILD_NUMBER") != null) return "${System.getenv("BUILD_NUMBER")}"
    else if (project.hasProperty("bambooBuildNumber")) return project.bambooBuildNumber
    else return getDate()
}

def getDate() {
    def date = new Date()
    def formattedDate = date.format('MM-dd-yyyy_HH-mm-ss')
    return formattedDate
}

group = "${org}.${groupName}"

// java version
sourceCompatibility = 1.7
targetCompatibility = 1.7

minecraft {
    version = "${version_minecraft}-${version_forge}${version_forge_b}"
    runDir = "run"
    mappings = "${version_mcp}"

    replace "required-after:Forge", "required-after:Forge@[${version_forge},)"
    replace "required-after:Origin", "required-after:origin@[${version_origin},)"
    replace "@MOD_VERSION@", "${version_major}.${version_minor}.${version_patch}"
}

def createVersion() {
    def branch = ""
    def proc = "git rev-parse --abbrev-ref HEAD".execute()
    proc.in.eachLine { line -> branch = line }
    proc.err.eachLine { line -> println line }
    proc.waitFor()
    println("Building on branch " + branch)
    def version = "${version_major}.${version_minor}.${version_patch}"
    if (project.hasProperty("build_type")) {
		if (build_type == "dev") version += "." + getBuildNumber()
    } else if (!branch.startsWith("master"))
        version += "." + getBuildNumber()
    println("Bulding with version " + version)
    return version
}

archivesBaseName = "${archiveName}-${project.minecraft.version}"
version = createVersion()

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version': project.version, 'mcversion': project.minecraft.version
    }

    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }

}

sourceSets {
	main.compileClasspath += api.compileClasspath;
	main.compileClasspath += api.output;
}

task sourcesJar(type: Jar) {
	from sourceSets.api.scala;
	from sourceSets.main.scala;
	classifier = 'sources'
}

tasks.build.dependsOn sourcesJar

apply plugin: 'maven'
apply plugin: 'maven-publish'

uploadArchives {
    repositories {
        // official DDD maven stuffs
        if (project.hasProperty("dddUser") && project.hasProperty("dddUrl") && project.hasProperty("dddPass")) {
            mavenDeployer {
                repository(url: dddUrl) {
                    authentication(userName: dddUser, password: dddPass)
                }
                pom {
                    groupId = project.group
                    version = project.version
                    artifactId = "${archiveName}"
                    project {
                        name project.archivesBaseName
                        packaging 'jar'
                        description '${gitConfig.gitName}'
                        url 'https://github.com/TheTemportalist/${gitConfig.gitName}'

                        scm {
                            url 'https://github.com/TheTemportalist/${gitConfig.gitName}'
                            connection 'scm:git:git://github.com/TheTemportalist/${gitConfig.gitName}.git'
                            developerConnection 'scm:git:git@github.com:TheTemportalist/${gitConfig.gitName}.git'
                        }

                        issueManagement {
                            system 'github'
                            url 'https://github.com/TheTemportalist/${gitConfig.gitName}/issues'
                        }

                        licenses {
                            license {
                                name '${gitConfig.license}'
                                url 'https://github.com/TheTemportalist/${gitConfig.gitName}/blob/master/LICENSE'
                                distribution 'repo'
                            }
                        }

                        developers {
                            developer {
                                id 'TheTemportalist'
                                name 'TheTemportalist'
                                roles { role 'developer' }
                            }
                        }
                    }
                }
            }
        }
    }
}

idea.module.inheritOutputDirs = true

curseforge {
    if (project.hasProperty("tempCurseAPI"))
        apiKey = tempCurseAPI
    project {
        id = curseID
        releaseType = curseBuildType
        changelog = "Update recipe filter for compatibility with JEI"
        addGameVersion version_minecraft
        addArtifact sourcesJar
		relations {
			requiredLibrary 'origin'
		}
    }
}