build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.1'
    id 'io.spring.dependency-management' version '1.1.4'
    id 'org.asciidoctor.jvm.convert' version '3.3.2'
    id 'jacoco'
    id "org.sonarqube" version "4.4.1.3373"
}

group = 'com.apps'
version = '0.0.1-SNAPSHOT'

java {
    sourceCompatibility = '17'
}

configurations {
    asciidoctorExt
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    testImplementation("org.springframework.boot:spring-boot-starter-test") {
        exclude group: "com.vaadin.external.google", module: "android-json"
    }

    // jasypt encryption
    implementation "com.github.ulisesbocchio:jasypt-spring-boot-starter:3.0.5"

    // S3
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

    // OpenFeign
    implementation 'org.springframework.cloud:spring-cloud-starter-openfeign:4.1.3'

    // security
    implementation 'org.springframework.boot:spring-boot-starter-security'
    testImplementation 'org.springframework.security:spring-security-test'

    implementation group: 'org.bouncycastle', name: 'bcpkix-jdk18on', version: '1.72'
    implementation group: 'com.nimbusds', name: 'nimbus-jose-jwt', version: '9.30.1'

    // jwt
    implementation 'javax.xml.bind:jaxb-api:2.3.1'
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    implementation 'io.jsonwebtoken:jjwt-impl:0.11.5'
    implementation 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    // lombok
    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    annotationProcessor 'org.projectlombok:lombok'
    testCompileOnly 'org.projectlombok:lombok:1.18.34'
    testAnnotationProcessor 'org.projectlombok:lombok:1.18.34'

    // h2
    implementation 'com.h2database:h2'
    runtimeOnly 'com.h2database:h2'

    // restdocs
    asciidoctorExt 'org.springframework.restdocs:spring-restdocs-asciidoctor'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'

    // FCM
    implementation group: 'org.json', name: 'json', version: '20090211'
    implementation 'com.google.firebase:firebase-admin:9.2.0'

    // Querydsl
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // GCS
    implementation group: 'org.springframework.cloud', name: 'spring-cloud-gcp-starter', version: '1.2.8.RELEASE'
    implementation group: 'org.springframework.cloud', name: 'spring-cloud-gcp-storage', version: '1.2.8.RELEASE'
}

ext {
    snippetsDir = file('build/generated-snippets')
    set('springCloudVersion', "2023.0.3")
}

dependencyManagement {
    imports {
        mavenBom "org.springframework.cloud:spring-cloud-dependencies:${springCloudVersion}"
    }
}

test {
    exclude '**/PostImageDeletionSchedulerTest.class'
    useJUnitPlatform()
    outputs.dir snippetsDir
}

asciidoctor {
    inputs.dir snippetsDir
    configurations 'asciidoctorExt'
    baseDirFollowsSourceFile()
    dependsOn test
}

tasks.resolveMainClassName {
    dependsOn 'copyDocument'
}

tasks.register('copyDocument', Copy) {
    dependsOn asciidoctor

    from file("build/docs/asciidoc/")
    into file("build/resources/main/static/docs")
}
bootJar {
    dependsOn copyDocument
}

// -plain.jar 제거
jar {
    enabled = false
}

build {
    dependsOn copyDocument
}

def generated = 'src/main/generated'

clean {
    delete file(generated)
}

tasks.withType(JavaCompile) {
    options.generatedSourceOutputDirectory = file(generated)
}

sourceSets {
    main.java.srcDirs += "$projectDir/build/generated"
}

jacoco {
    toolVersion = "0.8.9"
}

test {
    finalizedBy jacocoTestReport
}

def Qdomains = []
for (qPattern in "**/QA".."**/QZ") {
    Qdomains.add(qPattern + "*")
}

Qdomains.add("com/apps/pochak/**/dto/**")

jacocoTestReport {
    dependsOn test
    dependsOn copyDocument

    reports {
        xml.required.set(true)
        html.required.set(true)

        afterEvaluate {
            classDirectories.setFrom(files(classDirectories.files.collect {
                fileTree(dir: it,
                        exclude: [] + Qdomains)
            }))
        }

        xml.destination file("${buildDir}/jacoco/index.xml")
        html.destination file("${buildDir}/jacoco/index.html")
    }
}

sonarqube {
    properties {
        property "sonar.projectKey", "SMWU-POCHAK_POCHAK-Server"
        property "sonar.organization", "pochak-server"
        property "sonar.host.url", "https://sonarcloud.io"
        property "sonar.login", "${System.getenv('SONAR_TOKEN')}"
    }
}