CreateModelCatalog.bat.in

@ECHO off 
ECHO Build PlusModelCatalog...

rem IS_MAKE_PROGRAM_MSBUILD?
if ${IS_MAKE_PROGRAM_MSBUILD}==TRUE goto MakeUsingMsBuild

rem ---------------- msdev -----------------------
:msdev

ECHO   Clear old files to force rebuild of model catalog
"${CMAKE_MAKE_PROGRAM}" PlusModelCatalog.sln /clean Release /project ALL_BUILD 1> CreateModelCatalog.log 2>&1 
IF ERRORLEVEL 1 GOTO fail

ECHO   Generating model catalog
"${CMAKE_MAKE_PROGRAM}" PlusModelCatalog.sln /build Release /project ALL_BUILD 1>> CreateModelCatalog.log 2>&1 
IF ERRORLEVEL 1 GOTO fail

goto success

rem ---------------- msbuild -----------------------
:MakeUsingMsBuild

ECHO   Clear old files to force rebuild of model catalog
"${CMAKE_MAKE_PROGRAM}" ALL_BUILD.vcxproj /p:Configuration=Release /target:clean 1> CreateModelCatalog.log 2>&1 
IF ERRORLEVEL 1 GOTO fail

ECHO   Generating model catalog
"${CMAKE_MAKE_PROGRAM}" ALL_BUILD.vcxproj /p:Configuration=Release /target:rebuild 1>> CreateModelCatalog.log 2>&1
IF ERRORLEVEL 1 GOTO fail

goto success

rem ---------------------------------------

:success
ECHO PlusModelCatalog is available at: ${CMAKE_CURRENT_BINARY_DIR}/html
exit /b 0

:fail
ECHO Failed to generate PlusModelCatalog:
type CreateModelCatalog.log 
exit /b 1