-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathexec_op.S
3507 lines (2972 loc) · 96.6 KB
/
exec_op.S
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; ****************************************************************************
;
; Execute Op
;
; ****************************************************************************
#include "include.inc"
.text
#define OP_MAX 0x8B // max. Op number (HEX)
; bridges
.global _DispC
_DispC: jmp DispC
.global __Calc
__Calc: jmp Calc
.global __CalcGetMem
__CalcGetMem: jmp CalcGetMem
LoadTxt:
.asciz " Load? (1=YES) "
.balign 2
; ----- predefined numeric texts
NumTextTab:
.ascii " OK" ; 0
.ascii " ERROR" ; 1
.ascii "Diagnose" ; 2
.ascii " Result" ; 3
.ascii " Input" ; 4
.ascii " Enter" ; 5
.ascii " Index" ; 6
.ascii " Row" ; 7
.ascii " Column" ; 8
.ascii "Continue" ; 9
.ascii " STOP" ; 10
.ascii " Matrix" ; 11
.ascii " Complex" ; 12
.ascii " Number" ; 13
.ascii " Element" ; 14
.ascii " Item" ; 15
.ascii " Print" ; 16
.ascii " from" ; 17
.ascii " to" ; 18
.ascii " Display" ; 19
.ascii " Program" ; 20
.ascii " Load" ; 21
.ascii " Save" ; 22
.ascii " YES" ; 23
.ascii " NO" ; 24
.ascii " Add" ; 25
.ascii "Subtract" ; 26
.ascii "Multiply" ; 27
.ascii " Divide" ; 28
.ascii " Power" ; 29
.ascii " Root" ; 30
.ascii " Square" ; 31
.ascii " Key" ; 32
.ascii " Button" ; 33
.ascii " (1=YES)" ; 34
.ascii " Vector" ; 35
.ascii " Library" ; 36
.ascii " First" ; 37
.ascii " Second" ; 38
.ascii " Third" ; 39
.ascii " Fourth" ; 40
.ascii " Param." ; 41
.ascii " Entry" ; 42
.ascii " Output" ; 43
.ascii " Rows" ; 44
.ascii " Columns" ; 45
.ascii " Size" ; 46
.ascii " Ready" ; 47
.ascii " Lambda" ; 48
.ascii " Polynom" ; 49
.ascii " Angle" ; 50
.ascii " Side" ; 51
.ascii "Triangle" ; 52
.ascii " Area" ; 53
.ascii " Perimet" ; 54
.ascii " Radius" ; 55
.ascii " ArcLen" ; 56
.ascii " Chord" ; 57
.ascii " S-Area" ; 58
.ascii " Low" ; 59
.ascii " High" ; 60
.ascii " Too Low" ; 61
.ascii " Correct" ; 62
.ascii "Too High" ; 63
.ascii " Game" ; 64
.ascii " Time" ; 65
.ascii " Working" ; 66
.ascii " ..." ; 67
.ascii " Win" ; 68
.ascii " Loss" ; 69
.ascii "Bankroll" ; 70
.ascii " Success" ; 71
.ascii " Crash" ; 72
.ascii " Fail" ; 73
.ascii " Speed" ; 74
.ascii " Check" ; 75
.ascii " Landing" ; 76
.ascii " Mission" ; 77
.ascii "Complete" ; 78
.ascii " Failure" ; 79
.ascii " Smooth" ; 80
.ascii " Turn" ; 81
.ascii " Turns" ; 82
.ascii "Computer" ; 83
.ascii " Your" ; 84
.ascii " You" ; 85
.ascii " My" ; 86
.ascii " Lost" ; 87
.ascii " Count" ; 88
.ascii " Counter" ; 89
.ascii " Calc" ; 90
.ascii " Calcul" ; 91
.ascii "Calculer" ; 92
.ascii " Won" ; 93
.ascii " Wait" ; 94
.ascii " Press" ; 95
.ascii " a Key" ; 96
.ascii "Reaction" ; 97
.ascii "Response" ; 98
.ascii " Alien" ; 99
.ascii " Running" ; 100
.ascii " Test" ; 101
.ascii " Help" ; 102
.ascii " Hello" ; 103
.ascii " World" ; 104
.ascii " ET-58" ; 105
.ascii "Progress" ; 106
.ascii " Graph" ; 107
.ascii " Black" ; 108
.ascii " White" ; 109
.ascii " Height" ; 110
.ascii " Width" ; 111
.ascii " CRC" ; 112
#define NUMTEXT_MAX 112 // max. text index
.balign 2
; ----------------------------------------------------------------------------
; Op Ind (0x84)
; ----------------------------------------------------------------------------
; INPUT: R24 = key HEX code 0x00..0xFF
; R23 = INV flag (1=set)
; Z = clear if INV flag was set (=brne)
; ----------------------------------------------------------------------------
.global ExecOpInd
ExecOpInd:
; ----- load parameter indirect
; OUTPUT: R24 = memory index
; C = set if error
; DESTROYS: R31, R30, R27, R26, R25, R20
rcall ExecMemNum ; get memory index, with indirect from keyboard
brcs GetTB9 ; error
; INPUT: R24 = index of the number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
rcall __CalcGetMem ; load number into stack
; OUTPUT: R24 = unsigned integer
; C flag is set = overflow valid range
; Z flag is set = number is positive or 0 (breq), NZ = number is negative (brne)
; DESTROYS: R31, R30, R25, R_M1..R_M10
; CALCULATOR STACK: -1
call CalcUnstackB ; load byte from the stack
brcs GetTB9 ; overflow
brne GetTB9 ; negative
rjmp ExecOp2
; ----------------------------------------------------------------------------
; Load byte from X register
; ----------------------------------------------------------------------------
; OUTPUT: R24 = unsigned integer
; C flag is set = overflow valid range
; Z flag is set = number is positive or 0 (breq), NZ = number is negative (brne)
; DESTROYS: R31, R30, R25, R_M1..R_M10
; ----------------------------------------------------------------------------
.global GetXB
GetXB:
; stop edit mode
call __EditStop ; stop edit mode
; load register X
ldi r24,REG_X
; INPUT: R24 = index of the number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
rcall __CalcGetMem ; load register X
; OUTPUT: R24 = unsigned integer
; C flag is set = overflow valid range
; Z flag is set = number is positive or 0 (breq), NZ = number is negative (brne)
; DESTROYS: R31, R30, R25, R_M1..R_M10
; CALCULATOR STACK: -1
jmp CalcUnstackB ; unstack byte
; ----------------------------------------------------------------------------
; Load byte from T register
; ----------------------------------------------------------------------------
; OUTPUT: R25 = unsigned integer
; C flag is set = overflow valid range
; Z flag is set = number is positive or 0 (breq), NZ = number is negative (brne)
; DESTROYS: R31, R30, R_M1..R_M10, saves register R24 (with X value)
; ----------------------------------------------------------------------------
.global GetTB
GetTB:
push r24
ldi r24,REG_T
rcall __CalcGetMem ; load register T
call CalcUnstackB ; unstack key code
mov r25,r24 ; T value
pop r24
GetTB9:
ret
; ----------------------------------------------------------------------------
; Output characters to print buffer
; ----------------------------------------------------------------------------
; INPUT: R27:R26 (X) = number
; R31:R30 (Z) = destination print buffer
; OUTPUT: R31:R30 (Z) = new pointer in buffer
; DESTROYS: many
; ----------------------------------------------------------------------------
AddPrintChar_1B:
ldi r30,lo8(PrintBuf3)
ldi r31,hi8(PrintBuf3)
rjmp AddPrintChar_11
AddPrintChar_3:
ldi r30,lo8(PrintBuf2)
ldi r31,hi8(PrintBuf2)
ldi r26,lo8(PrintReg+2*NUM_BYTES)
ldi r27,hi8(PrintReg+2*NUM_BYTES)
rjmp AddPrintChar
AddPrintChar_1:
ldi r30,lo8(PrintBuf1)
ldi r31,hi8(PrintBuf1)
AddPrintChar_11:
ldi r26,lo8(PrintReg+0*NUM_BYTES)
ldi r27,hi8(PrintReg+0*NUM_BYTES)
; AddPrintChar must follow
.global AddPrintChar
AddPrintChar:
push r30
push r31
; ----- load number into stack
; OUTPUT: R31:R30 (Z) = new number
; DESTROYS: -
; CALCULATOR STACK: +1
call CalcNew ; create new number -> Z
; INPUT and OUTPUT: R31:R30 (Z), R27:R26 (X) = registers to exchange
; DESTROYS: -
call ExcXZ ; exchange pointers X and Z
; INPUT: R31:R30 (Z) = source address in RAM
; R27:R26 (X) = destination address in RAM
; OUTPUT: R31:R30 (Z) = next source address in RAM
; R27:R26 (X) = next destination address in RAM
; DESTROYS: R25, R24
call CalcCopyNum ; copy number from Z to X
call CalcAbs ; absolute value
call CalcRound
call CalcPreCor ; rounding pre-correction
; ----- divide by 10^16 (shift by 16 digits = 8 characters)
; INPUT: R31:R30 = constant in ROM
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
ldi r30,lo8(ExpTab+9*NUM_BYTES)
ldi r31,hi8(ExpTab+9*NUM_BYTES)
call CalcConstROM
call CalcMul
; ----- decode digits
ldi r23,8
; DESTROYS: R31, R30, R27..R24
; CALCULATOR STACK: +1
2: push r23
ldi r24,CONST_100
call CalcConst
call CalcMul ; multiply number by 100
call CalcDup ; duplicate
; OUTPUT: R24 = unsigned integer
; C flag is set = overflow valid range
; Z flag is set = number is positive or 0 (breq), NZ = number is negative (brne)
; DESTROYS: R31, R30, R25, R_M1..R_M10
; CALCULATOR STACK: -1
call CalcUnstackB ; get byte
; INPUT: (R25:)R24 = unsigned integer
; DESTROYS: R31, R30, R25, R24, R_M1..R_M10, R0
; CALCULATOR STACK: +1
push r24
call CalcStackB
call CalcNeg
call CalcAdd ; subtract integer part
pop r24
pop r23
pop r31
pop r30
cpi r24,100
brcs 3f
ldi r24,0
3: subi r24,-32
st Z+,r24
push r30
push r31
dec r23
brne 2b ; next digit
call CalcDel
pop r31
pop r30
ret
; ----------------------------------------------------------------------------
; Calculate regresion
; ----------------------------------------------------------------------------
; y = m*x + b, RegT = m, RegX = b
; mem 1: sum y
; mem 2: sum y^2
; mem 3: N
; mem 4: sum x
; mem 5: sum x^2
; mem 6: sum x*y
Regr:
rcall __Calc
; sum(x*y) - sum(x)*sum(y)/N
.byte C_GETMEM(MEM_6) ; load mem 6 = sum x*y (m6)
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (m6,m4)
.byte C_GETMEM(MEM_1) ; load mem 1 = sum y (m6,m4,m1)
.byte C_MUL ; multiply (m6,m4*m1)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (m6,m4*m1,N)
.byte C_DIV ; divide (m6,m4*m1/N)
.byte C_SUB ; subtract (m6-m4*m1/N = sum(x*y)-sum(x)*sum(y)/N = z)
; sum(x^2) - sum(x)^2/N
.byte C_GETMEM(MEM_5) ; load mem 5 = sum x^2 (z,m5)
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (z,m5,m4)
.byte C_SQR ; square (z,m5,m4^2)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (z,m5,m4^2,N)
.byte C_DIV ; divide (z,m5,m4^2/N)
.byte C_SUB ; subtract (z,m5-m4^2/N = sum(x^2) - sum(x)^2/N = w)
; m = sum(x*y) - sum(x)*sum(y)/N) / (sum(x^2) - sum(x)^2/N) -> RegT
.byte C_DIV ; divide (z/w)
.byte C_SETMEM(REG_T) ; set register T (m)
; b = (sum(y) - m*sum(x))/N -> RegX
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (m,m4)
.byte C_MUL ; multiply (m*m4)
.byte C_GETMEM(MEM_1) ; load mem 1 = sum y (m*m4,m1)
.byte C_SUB ; subtract (m*m4-m1)
.byte C_NEG ; negate (m1-m*m4)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (m1-m*m4,N)
.byte C_DIV ; divide ((m1-m*m4)/N)
.byte C_SETMEMDEL(REG_X) ; set register X
.byte C_END
.balign 2
ret
; ----- decode register X into edit buffer (length R24)
ExecOpPrepX:
std Y+DATA_EDITMAX,r24
rcall __EditStop ; stop edit mode
ldi r24,REG_X
rcall __CalcGetMem ; load number X
jmp DecNum
; ----------------------------------------------------------------------------
; Delete top complex number (C_CPXDEL)
; ----------------------------------------------------------------------------
.global CpxDel
CpxDel:
lds r24,CpxInx ; current index
tst r24 ; check
brne CpxDel2 ; ok
CpxDel9:
jmp Fatal ; fatal error
CpxDel2:
dec r24 ; decrement index
CpxDel3:
sts CpxInx,r24
ret
; ----------------------------------------------------------------------------
; Create new complex number
; ----------------------------------------------------------------------------
CpxNew:
lds r24,CpxInx ; current index
lds r25,CpxNum ; max. number
cp r24,r25 ; check number
brcc CpxDel9 ; error
inc r24 ; increase number
rjmp CpxDel3
; ----------------------------------------------------------------------------
; Get pre-top complex number into calculator stack (pre-top=real, top=imaginary) (C_CPXGETPRETOP)
; ----------------------------------------------------------------------------
.global CpxGetPreTop
CpxGetPreTop:
; get memory index of top complex number
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
rcall CpxPreTopInx
rjmp CpxGetTop2
; ----------------------------------------------------------------------------
; Get top complex number into calculator stack (pre-top=real, top=imaginary) (C_CPXGETTOP)
; ----------------------------------------------------------------------------
.global CpxGetTop
CpxGetTop:
; get memory index of top complex number
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
rcall CpxTopInx
CpxGetTop2:
; Get number from memory into stack (C_GETMEM)
; INPUT: R24 = index of the number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
push r24
rcall __CalcGetMem
pop r24
; Get number from memory into stack (C_GETMEM)
; INPUT: R24 = index of the number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
inc r24
rjmp __CalcGetMem
; ----------------------------------------------------------------------------
; Set pre-top complex number from calculator stack (pre-top=real, top=imaginary) (C_CPXSETPRETOP)
; ----------------------------------------------------------------------------
.global CpxSetPreTop
CpxSetPreTop:
; get memory index of top complex number
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
rcall CpxPreTopInx
rjmp CpxSetTop2
; ----------------------------------------------------------------------------
; Set top complex number from calculator stack (pre-top=real, top=imaginary) (C_CPXSETTOP)
; ----------------------------------------------------------------------------
.global CpxSetTop
CpxSetTop:
; get memory index of top complex number
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
rcall CpxTopInx
CpxSetTop2:
; set number from stack (C_GETMEM)
; INPUT: R24 = index of a number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
push r24
inc r24
call CalcSetMem
call CalcExc
pop r24
; set number from stack (C_GETMEM)
; INPUT: R24 = index of a number
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
call CalcSetMem
jmp CalcExc
; ----------------------------------------------------------------------------
; Get memory index of pre-top complex number
; ----------------------------------------------------------------------------
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
; ----------------------------------------------------------------------------
CpxPreTopInx:
lds r24,CpxInx ; current index
subi r24,2
rjmp CpxToInx
; ----------------------------------------------------------------------------
; Get memory index of top complex number
; ----------------------------------------------------------------------------
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
; ----------------------------------------------------------------------------
CpxTopInx:
lds r24,CpxInx ; current index
dec r24
; CpxToInx must follow
; ----------------------------------------------------------------------------
; Convert index of complex number to memory index
; ----------------------------------------------------------------------------
; INPUT: R24 = index of complex number
; OUTPUT: R24 = index of memory number
; DESTROYS: R25
; ----------------------------------------------------------------------------
CpxToInx:
; check index
lds r25,CpxNum ; max. number
cp r24,r25 ; check number
brcc CpxDel9 ; error
lds r25,CpxBeg ; first register
add r25,r24
brcs CpxDel9
add r25,r24
brcs CpxDel9
cpi r25,USER_NUM-1 ; check start index
brcc CpxDel9 ; invalid start index
; INPUT: R24 = index of variable 0..MEM_NUM-1
; OUTPUT: R31:R30 = address of variable
; R1 = 0
; DESTROYS: R0
subi r25,-USER_FIRST
mov r24,r25
ret
; ----------------------------------------------------------------------------
; Op (0x69)
; ----------------------------------------------------------------------------
; INPUT: R24 = key HEX code 0x00..0xFF
; R23 = INV flag (1=set)
; Z = clear if INV flag was set (=brne)
; ----------------------------------------------------------------------------
.global ExecOp
ExecOp:
; ----- load parameter (2 HEX digits)
; OUTPUT: R24 = byte
; DESTROYS: R25
call Load2Hex
ExecOp2:
cpi r24,OP_MAX+1 ; check max. opcode
brcc ExecOp_00_9 ; invalid opcode
; ----- jump to operation
ldi r30,lo8(ExecOpTab) ; Z <- jump table
ldi r31,hi8(ExecOpTab)
add r30,r24
adc r31,R_ZERO
add r30,r24 ; Z <- offset in jump table
adc r31,R_ZERO
lpm r0,Z+ ; R0 <- load jump address LOW
lpm r31,Z ; R31 <- load jump address HIGH
mov r30,r0 ; Z <- jump address (byte offset)
lsr r31
ror r30 ; convert address to word index
ijmp ; jump to function (R24=opcode)
; ----- 0: clear print registers 1..4
ExecOp_00:
ldi r30,lo8(PrintReg)
ldi r31,hi8(PrintReg)
ldi r24,4
; INPUT: R31:R30 = float number
; DESTROYS: R_M1,...R_M10
5: call CalcZ0
adiw r30,NUM_BYTES
dec r24
brne 5b
ExecOp_00_9:
ret
; ----- 1..4: set print register 1..4
ExecOp_01:
ExecOp_02:
ExecOp_03:
ExecOp_04:
push r24 ; register index 1..4
; DESTROYS: R27, R26, R25, R24, R20
rcall __EditStop ; stop edit mode
pop r24
ldi r25,NUM_BYTES
mul r25,r24 ; offet of register
movw r26,r0 ; offset
clr r1 ; restore R1 (R_ZERO)
subi r26,lo8(-(PrintReg-NUM_BYTES))
sbci r27,hi8(-(PrintReg-NUM_BYTES))
ldi r30,lo8(MemReg + REG_X*NUM_BYTES)
ldi r31,hi8(MemReg + REG_X*NUM_BYTES)
; INPUT: R31:R30 (Z) = source address in RAM
; R27:R26 (X) = destination address in RAM
; OUTPUT: R31:R30 (Z) = next source address in RAM
; R27:R26 (X) = next destination address in RAM
; DESTROYS: R25, R24
call CalcCopyNum
rjmp _Disp
; ----- 5: output print registers 1..4 to printer
ExecOp_05:
rcall __EditStop ; stop edit mode and set X valid
ret
; ----- 6: output print register 1 with X to printer
ExecOp_06:
rcall __EditStop ; stop edit mode and set X valid
ret
; ----- 7: print asterisk to X position 0..19 of the printer
ExecOp_07:
rcall __EditStop ; stop edit mode and set X valid
ret
; ----- 8: print labels to the printer
ExecOp_08:
rcall __EditStop ; stop edit mode and set X valid
ret
; ----- 9: load selected program into main memory
ExecOp_09:
IF_RUNNING ; running?
9: ret ; running program, no function
ldd r24,Y+DATA_PROGINX ; current program index
tst r24 ; main program?
breq 9b ; main program
rcall __EditStop ; stop edit mode and set X valid
; diplay prompt to confirm operation
call DispSetRow1 ; set cursor to ROW1
ldi r30,lo8(LoadTxt)
ldi r31,hi8(LoadTxt)
call DispTextRom ; display text
ldi r24,NOKEY
call ReturnKey ; flush old key
call WaitKey ; wait for a key
cpi r24,KEY_1 ; check key '1'
brne 8f
rcall _DispC ; display C
ldd r30,Y+DATA_PROGBEG ; begin of program
ldd r31,Y+DATA_PROGBEG+1
clr r26 ; destination address
clr r27
1: call ExcXZ ; exchange X and Z
; INPUT: R27:R26 (X) = address (can be out of range)
; OUTPUT: R24 = byte (0 if invalid)
; R27:R26 (X+1) = new address, increased by 1 (not changed on error)
; CY = invalid address (R27:R26 not changed)
; DESTROYS: -
call LoadByte ; load byte
brcc 2f ; address is OK
ldi r24,CLEARKEY ; clear key
2: mov r25,r24
call ExcXZ ; exchange X and Z
; INPUT: R27:R26 = destination address
; R25 = data
; OUTPUT: R24 = old byte
call EEWrite ; clear byte
; increase destination address
adiw r26,1 ; shift destination address
cpi r26,lo8(PROG_NUM)
brne 1b
cpi r27,hi8(PROG_NUM)
brne 1b
clr r24
; INPUT: R24 = program index (0=main)
; DESTROYS: R31, R30, R24, R0
call OpenProg ; open main program
; reset current address
std Y+DATA_ADDR,R_ZERO
std Y+DATA_ADDR+1,R_ZERO
; DESTROYS: R0
8: rjmp _Disp ; display all
; ----- 0x0A: print registers 1 and 2 on 1st row while running (cleared on stop) - full row
ExecOp_0A:
rcall AddPrintChar_1
ldi r26,lo8(PrintReg+1*NUM_BYTES)
ldi r27,hi8(PrintReg+1*NUM_BYTES)
; INPUT: R27:R26 (X) = number
; R31:R30 (Z) = destination print buffer
; OUTPUT: R31:R30 (Z) = new pointer in buffer
; DESTROYS: many
rcall AddPrintChar
rjmp ExecOp_0B_4
; ----- 0x0B: print register 1 on 1st row while running (cleared on stop) - half row + number
ExecOp_0B:
ldi r24,8
rcall ExecOpPrepX
rcall AddPrintChar_1
ExecOp_0B_2:
ldi r25,8
ExecOp_0B_3:
ldi r26,lo8(EditBuf)
ldi r27,hi8(EditBuf)
2: ld r24,X+
st Z+,r24
dec r25
brne 2b
ExecOp_0B_4:
IF_RUNNING
rcall _DispC
rcall _Disp
ret
; ----- 0x0C: print register 1 on 1st row while running (cleared on stop) - quart row + number
ExecOp_0C:
ldi r24,12
rcall ExecOpPrepX
rcall AddPrintChar_1
ExecOp_0C_2:
sbiw r30,4
ldi r25,12
rjmp ExecOp_0B_3
; ----- 0x0D: print registers 3 and 4 on 2nd row while running (set to 'C' on stop) - full row
ExecOp_0D:
rcall AddPrintChar_3
ldi r26,lo8(PrintReg+3*NUM_BYTES)
ldi r27,hi8(PrintReg+3*NUM_BYTES)
; INPUT: R27:R26 (X) = number
; R31:R30 (Z) = destination print buffer
; OUTPUT: R31:R30 (Z) = new pointer in buffer
; DESTROYS: many
rcall AddPrintChar
rjmp ExecOp_0B_4
; ----- 0x0E: print register 3 on 2nd row while running (set to 'C' on stop) - half row + number
ExecOp_0E:
ldi r24,8
rcall ExecOpPrepX
rcall AddPrintChar_3
rjmp ExecOp_0B_2
; ----- 0x0F: print register 3 on 2nd row while running (set to 'C' on stop) - quart row + number
ExecOp_0F:
ldi r24,12
rcall ExecOpPrepX
rcall AddPrintChar_3
rjmp ExecOp_0C_2
; ----- 0x10: sign function of X
ExecOp_10:
jmp ExecSign ; sign of X
; ----- 0x11: variation
; mem 1: sum y
; mem 2: sum y^2
; mem 3: N
; mem 4: sum x
; mem 5: sum x^2
; mem 6: sum x*y
ExecOp_11:
rcall __EditStop ; stop edit mode and set X valid
rcall __Calc
; sum(x^2)/N
.byte C_GETMEM(MEM_5) ; load mem 5 = sum x^2 (m5)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (m5,N)
.byte C_DIV ; divide (m5/N = xx)
; (sum(x)/N)^2
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (xx,m4)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (xx,m4,N)
.byte C_DIV ; divide (xx,m4/N)
.byte C_SQR ; square (xx,(m4/N)^2)
; reg T = sum(x^2)/N - (sum(x)/N)^2)
.byte C_SUB ; subtract (xx-(m4/N)^2 = sum(x^2)/N - (sum(x)/N)^2)
.byte C_SETMEMDEL(REG_T) ; set register T
; sum(y^2)/N
.byte C_GETMEM(MEM_2) ; load mem 2 = sum y^2 (m2)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (m2,N)
.byte C_DIV ; divide (m2/N = yy)
; (sum(y)/N)^2
.byte C_GETMEM(MEM_1) ; load mem 1 = sum y (yy,m1)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (yy,m1,N)
.byte C_DIV ; divide (yy,m1/N)
.byte C_SQR ; square (yy,(m1/N)^2)
; reg X = sum(y^2)/N - (sum(y)/N)^2)
.byte C_SUB ; subtract (yy-(m1/N)^2 = sum(y^2)/N - (sum(y)/N)^2)
.byte C_SETMEMDEL(REG_X) ; set register X
.byte C_END
.balign 2
rjmp _Disp
; ----- 0x12: coefficients of linear regression
; linear regression, y = m*x + b
; RegT = m = (sum(x*y) - sum(x)*sum(y)/N) / (sum(x^2) - sum(x)^2/N)
; RegX = b = (sum(y) - m*sum(x))/N
; mem 1: sum y
; mem 2: sum y^2
; mem 3: N
; mem 4: sum x
; mem 5: sum x^2
; mem 6: sum x*y
ExecOp_12:
rcall __EditStop ; stop edit mode and set X valid
rcall Regr ; calculate regression
rjmp _Disp ; display
; ----- 0x13: correlation coefficient
; correlation coefficient R = m * devx / devy
; rise coefficient m = (sum(x*y) - sum(x)*sum(y)/N) / (sum(x^2) - sum(x)^2/N))
; standard deviation devx = sqrt((sum(x^2) - sum(x)^2/N)/(N-1))
; standard deviation devy = sqrt((sum(y^2) - sum(y)^2/N)/(N-1))
; R = (sum(x*y) - sum(x)*sum(y)/N) / sqrt((sum(x^2) - sum(x)^2/N)*(sum(y^2) - sum(y)^2/N))
; mem 1: sum y
; mem 2: sum y^2
; mem 3: N
; mem 4: sum x
; mem 5: sum x^2
; mem 6: sum x*y
ExecOp_13:
rcall __EditStop ; stop edit mode and set X valid
rcall __Calc
; z = sum(x*y) - sum(x)*sum(y)/N
.byte C_GETMEM(MEM_6) ; load mem 6 = sum x*y (m6)
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (m6,m4)
.byte C_GETMEM(MEM_1) ; load mem 1 = sum y (m6,m4,m1)
.byte C_MUL ; multiply (m6,m4*m1)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (m6,m4*m1,N)
.byte C_DIV ; divide (m6,m4*m1/N)
.byte C_SUB ; subtract (m6-m4*m1/N = sum(x*y) - sum(x)*sum(y)/N = z)
; w = sum(x^2) - sum(x)^2/N
.byte C_GETMEM(MEM_5) ; load mem 5 = sum x^2 (z,m5)
.byte C_GETMEM(MEM_4) ; load mem 4 = sum x (z,m5,m4)
.byte C_SQR ; square (z,m5,m4^2)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (z,m5,m4^2,N)
.byte C_DIV ; divide (z,m5,m4^2/N)
.byte C_SUB ; subtract (z,m5-m4^2/N = sum(x^2) - sum(x)^2/N = w)
; s = sum(y^2) - sum(y)^2/N
.byte C_GETMEM(MEM_2) ; load mem 2 = sum y^2 (z,w,m2)
.byte C_GETMEM(MEM_1) ; load mem 1 = sum y (z,w,m2,m1)
.byte C_SQR ; square (z,w,m2,m1^2)
.byte C_GETMEM(MEM_3) ; load mem 3 = N (z,w,m2,m1^2,N)
.byte C_DIV ; divide (z,w,m2,m1^2/N)
.byte C_SUB ; subtract (z,w,m2-m1^2/N = sum(y^2) - sum(y)^2/N = s)
; q = sqrt((sum(x^2) - sum(x)^2/N) * (sum(y^2) - sum(y)^2/N)) = sqrt(w*s)
.byte C_MUL ; multiply (z,w*s)
; R = z/q
.byte C_DIV ; divide (z/(w*s))
.byte C_SETMEMDEL(REG_X) ; set register X
.byte C_END
.balign 2
rjmp _Disp ; display
; ----- 0x14: calculate linear regression Y from X
; linear regression: y = m*x + b, RegT = m, RegX = b
ExecOp_14:
rcall __EditStop ; stop edit mode and set X valid
ldi r24,REG_T
rcall __CalcGetMem ; load register T into stack
ldi r24,REG_X
rcall __CalcGetMem ; load register X into stack
rcall Regr ; calculate regression
rcall __Calc
.byte C_GETMEM(REG_T) ; load register T = coefficient m (x,m)
.byte C_MUL ; multiply (x*m)
.byte C_GETMEM(REG_X) ; load register X = coefficient b (x*m,b)
.byte C_ADD ; add (x*m+b)
.byte C_SETMEMDEL(REG_X) ; save result into X
.byte C_SETMEMDEL(REG_T) ; save original value T
.byte C_END
.balign 2
rjmp _Disp ; display
; ----- 0x15: calculate linear regression X from Y
; linear regression: y = m*x + b, RegT = m, RegX = b ... x = (y - b)/m
ExecOp_15:
call EditStop ; stop edit mode and set X valid
ldi r24,REG_T
rcall __CalcGetMem ; load register T into stack
ldi r24,REG_X
rcall __CalcGetMem ; load register X into stack
rcall Regr ; calculate regression
rcall __Calc
.byte C_GETMEM(REG_X) ; load register X = coefficient b (y,b)
.byte C_SUB ; subtract (y-b)
.byte C_GETMEM(REG_T) ; load register T = coefficient m (y-b,m)
.byte C_DIV ; divide ((y-b)/m)
.byte C_SETMEMDEL(REG_X) ; save result into X
.byte C_SETMEMDEL(REG_T) ; save original value T
.byte C_END
.balign 2
rjmp _Disp ; display
; ----- 0x16,0x17: set/get memory organization 999.99
ExecOp_16:
ExecOp_17:
call EditStop
ldi r24,CONST_99999
; INPUT: R24 = index of the constant in ConstTab
; OUTPUT: R1 = 0
; DESTROYS: R31, R30, R27..R24, R0
; CALCULATOR STACK: +1
call CalcConst
call _CalcSetMemDelX