build.gradle

// Top-level build file where you can add configuration options common to all sub-projects/modules.

buildscript {
    repositories {
        jcenter()
        maven { url 'https://maven.fabric.io/public' }
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.0.0-beta6'
        classpath 'com.google.gms:google-services:2.0.0-beta6'

        classpath 'io.fabric.tools:gradle:1.21.5'
        classpath 'com.github.triplet.gradle:play-publisher:1.1.4'
        classpath 'com.github.ben-manes:gradle-versions-plugin:0.12.0'
        classpath 'org.ajoberstar:grgit:1.4.1'
    }
}

apply plugin: 'com.github.ben-manes.versions'

allprojects {
    repositories {
        jcenter()
        maven { url 'https://maven.fabric.io/public' }
    }

    task checkstyle(type: Checkstyle) {
        showViolations = true
        configFile file("../settings/checkstyle.xml")

        source 'src/main/java'
        include '**/*.java'
        exclude '**/gen/**'
        classpath = files()
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}

// Define versions in a single place
ext {
    ci = "true".equals(System.getenv("CI"))
    preDexEnabled = "true".equals(System.getProperty("pre-dex", "true"))

    // Manifest version information!
    versionMajor = 2
    versionMinor = 3
    versionPatch = 0
    versionBuild = 9 // bump for dogfood builds, public betas, etc.

    versionCode = versionMajor * 10000 + versionMinor * 1000 + versionPatch * 100 + versionBuild
    versionName = "${versionMajor}.${versionMinor}.${versionPatch}"

    // Sdk and tools
    minSdkVersion = project.hasProperty("minSdk") ? minSdk : 16
    targetSdkVersion = 21
    compileSdkVersion = 23
    buildToolsVersion = '23.0.2'

    // App dependencies
    supportLibraryVersion = '23.2.1'
    playServicesVersion = '8.4.0'
    jodaTimeVersion = '2.9.2'
    leakCanaryVersion = '1.3.1'
    okHttpVersion = '3.2.0'
    retrofitVersion = '2.0.0'

    //test dependencies
    junitVersion = '4.12'
    mockitoVersion = '1.10.19'
    hamcrestVersion = '1.3'
    robolectricVersion = '3.0'
    runnerVersion = '0.5'
    rulesVersion = '0.5'
    espressoVersion = '2.2.2'
}