build.gradle

plugins {
    id 'dev.architectury.loom' version '1.9-SNAPSHOT' apply false
    id 'architectury-plugin' version '3.4-SNAPSHOT'
    id 'com.github.johnrengelman.shadow' version '8.1.1' apply false
    id "io.github.pacifistmc.forgix" version "1.2.9-local.7"
    id "org.moddedmc.wiki.toolkit" version "0.2.4"
}

architectury {
    minecraft = minecraft_version
}

allprojects {
    group = maven_group
    version = "$mod_version+$minecraft_version"
    if (tbversion != "0") version = version + "-tb$tbversion"
}

forgix {
    group = "net.lerariemann.infinity"
    mergedJarName = "infinite-dimensions-${version}.jar"

    neoforge {
        projectName = "neoforge"
        jarLocation = "build/libs/infinity-neoforge-${version}.jar"
    }

    fabric {
        projectName = "fabric"
        jarLocation = "build/libs/infinity-fabric-${version}.jar"
    }

}

wiki {
    docs {
        // The name of the object (examplemod) should match the registered wiki project ID (if it exists).
        "infinite-dimensions" {
            // The path to the folder containing the documentation metadata file (sinytra-wiki.json)
            root = file('docs')
        }
    }
}

subprojects {
    apply plugin: 'dev.architectury.loom'
    apply plugin: 'architectury-plugin'
    apply plugin: 'maven-publish'

    base {
        // Set up a suffixed format for the mod jar names, e.g. `example-fabric`.
        archivesName = "$rootProject.archives_name-$project.name"
    }

    repositories {
        // Add repositories to retrieve artifacts from in here.
        // You should only use this when depending on other mods because
        // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
        // See https://docs.gradle.org/current/userguide/declaring_repositories.html
        // for more information about repositories.
        exclusiveContent {
            forRepository {
                maven {
                    name = "Modrinth"
                    url = "https://api.modrinth.com/maven"
                }
            }
            filter {
                includeGroup "maven.modrinth"
            }
        }
    }

    dependencies {
        minecraft "net.minecraft:minecraft:$rootProject.minecraft_version"
        mappings loom.layered {
            it.mappings("net.fabricmc:yarn:$minecraft_version+build.$rootProject.yarn_mappings:v2")
            it.mappings("dev.architectury:yarn-mappings-patch-neoforge:$rootProject.yarn_mappings_patch_neoforge_version")
        }
    }

    java {
        // Loom will automatically attach sourcesJar to a RemapSourcesJar task and to the "build" task
        // if it is present.
        // If you remove this line, sources will not be generated.
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 21
    }

    // Configure Maven publishing.
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifactId = base.archivesName.get()
                from components.java
            }
        }

        // See https://docs.gradle.org/current/userguide/publishing_maven.html for information on how to set up publishing.
        repositories {
            // Add repositories to publish to here.
            // Notice: This block does NOT have the same function as the block in the top level.
            // The repositories here will be used for publishing your artifact, not for
            // retrieving dependencies.
        }
    }
    build.finalizedBy(mergeJars)
    assemble.finalizedBy(mergeJars)
}