build.gradle

buildscript {
    ext.kotlin_version = '1.4.21'
}

plugins {
    id "org.jetbrains.dokka" version "1.4.10.2"
    id 'org.jetbrains.kotlin.jvm' version '1.4.21'
}

apply plugin: 'maven'
apply plugin: 'org.jetbrains.dokka'
apply plugin: 'signing'

sourceCompatibility = '1.8'
targetCompatibility = '1.8'

repositories {
    mavenCentral()
    jcenter()
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"

    testCompile "org.jetbrains.kotlin:kotlin-test:$kotlin_version"
    testCompile 'junit:junit:4.13.1'
}

dokkaJavadoc {
    outputDirectory = javadoc.destinationDir
    inputs.dir 'src/main/kotlin'
}

jar {
    archivesBaseName = 'npy'
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: dokkaJavadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives sourcesJar, javadocJar
}

signing {
    // multiline environment variables are not fun.
    def signingKey = findProperty("signingKey")?.replace("\\n", "\n")
    def signingPassword = findProperty("signingPassword")
    useInMemoryPgpKeys(signingKey, signingPassword)
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            def ossrhUsername = findProperty("ossrhUsername")
            def ossrhPassword = findProperty("ossrhPassword")

            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: ossrhUsername, password: ossrhPassword)
            }

            pom.groupId = 'org.jetbrains.bio'

            pom.project {
                name 'npy'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'NPY and NPZ support for the JVM'
                url 'https://github.com/JetBrains-Research/npy'

                scm {
                    connection 'scm:git:git@github.com:JetBrains-Research/npy.git'
                    developerConnection 'scm:git:git@github.com:JetBrains-Research/npy.git'
                    url 'https://github.com/JetBrains-Research/npy'
                }

                licenses {
                    license {
                        name 'MIT License'
                        url 'https://github.com/JetBrains-Research/npy/blob/master/LICENSE'
                    }
                }

                developers {
                    developer {
                        id 'dievsky'
                        name 'Aleksei Dievskii'
                        email 'alexey.dievsky@jetbrains.com'
                    }
                    developer {
                        id 'slebedev'
                        name 'Sergei Lebedev'
                        email 'sergei.a.lebedev@gmail.com'
                    }
                }
            }
        }
    }
}

wrapper {
    gradleVersion = '6.5'
}