-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathDungeons.bms
323 lines (293 loc) · 8.54 KB
/
Dungeons.bms
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
# Unreal Engine 4 - Unreal Tournament 4 (*WindowsNoEditor.pak) (script 0.4.23)
# script for QuickBMS http://quickbms.aluigi.org
math NO_TAIL_INFO = 0 # set it to 1 for archives with corrupt/missing tail information
quickbmsver "0.8.4"
math TOC_FILE = 0
# Dungeons Beta AES Key
# set AES_KEY binary "0x478762BAEC53557F2BB59292B1341F1ADA335163D1335CE338A3A02B78F14271"
# Dungeons 1.2.0.0 - 1.7.3.0 AES Key
#set AES_KEY binary "0x90F270A4EA6DE0E3BABDC4C8BDC04F46FA5B9087BE8FE76AA859C93C17D04661"
# Dungeons 1.8.0.0 AES Key
#set AES_KEY binary "0x0634AF9A409BA6D24FC17B6872124A91F3DBC4C3986F639A5E29C1BB10B2A099"
# Dungeons 1.8.6.0 AES Key
#set AES_KEY binary "0xA031D8DC72D498FF3856CF3B6E7FCA0DF09D59E6C75DCA8A9FBE152C7982C4A2"
# Dungeons 1.8.8.0 AES Key
# set AES_KEY binary "0x8F80D8A467F135AC43BB1324861EF5D91316AD954A09D4B3499A8CCA8AE70AB7"
# Dungeons 1.9.1.0 AES Key
set AES_KEY binary "0x0A01138AC7553ECEA7E9E257B5A45FA6665679D360B270278AE5D5367B172E40"
string AES_KEY << 2
string AES_KEY h AES_KEY
math AES_KEY_IS_SET = 1
math ALTERNATIVE_MODE = 0
get ARCHIVE_NAME basename
get ARCHIVE_PATH FILEPATH
math VERSION = 0
math CHUNK_OFFSET_ABSOLUTE = -1 # default, enabled
# 1 = HIT
math WORKAROUND = 0
if NO_TAIL_INFO != 0
get OFFSET asize
math ALTERNATIVE_MODE = 1
else
goto -0xac # for version 8
savepos MAGIC_OFF
get MAGIC long #idstring "\xe1\x12\x6f\x5a" # 0x5a6f12e1
if MAGIC != 0x5a6f12e1
goto -0x2c # previous versions 3-6
savepos MAGIC_OFF
get MAGIC long
else
math WORKAROUND = 4
endif
if MAGIC == 0
goto -0xcc # Fortnite iOS
savepos MAGIC_OFF
get MAGIC long
math WORKAROUND = 3
endif
endian guess MAGIC # 0x5a6f12e1:le, 0xe1126f5a:be
if MAGIC == 0x1233a # HIT game
math WORKAROUND = 1
elif MAGIC == 0x1066a # OverHit
math WORKAROUND = 1
elif MAGIC == 0x13aed # OverHit
math WORKAROUND = 1
elif ARCHIVE_NAME & "OverHit"
math WORKAROUND = 1
elif ARCHIVE_NAME == "0" # HIT
math WORKAROUND = 1
elif ARCHIVE_PATH & "Gears of War 4"
math WORKAROUND = 2
endif
get VERSION long
endian guess VERSION
get OFFSET longlong
get SIZE longlong
getdstring HASH 20
if WORKAROUND == 1
math VERSION = 3
endif
if VERSION >= 3
goto MAGIC_OFF
goto -1 0 SEEK_CUR
get ENCRYPTED byte
if ENCRYPTED != 0
callfunction SET_AES_KEY 1
log MEMORY_FILE10 OFFSET SIZE
encryption "" ""
math TOC_FILE = -10 # MEMORY_FILE10 is -10
endif
endif
goto OFFSET # don't use TOC_FILE
callfunction GET_NAME 1
endif
if ALTERNATIVE_MODE == 0
get FILES long TOC_FILE
else
math FILES = 0x7fffffff
math MAX_OFF = OFFSET
goto 0
set NAME string ""
endif
math CHUNK_SIZE = 0x10000 # just in case...
for i = 0 < FILES
if ALTERNATIVE_MODE == 0
callfunction GET_NAME 1
if NAMESZ == 0 # lame work-around for Conan Exiles
callfunction GET_NAME 1
endif
endif
savepos TMP_OFF TOC_FILE
get OFFSET longlong TOC_FILE
if WORKAROUND == 2
get ZSIZE long TOC_FILE
get SIZE long TOC_FILE
get ZIP byte TOC_FILE
elif WORKAROUND == 4
get ZSIZE longlong TOC_FILE
get SIZE longlong TOC_FILE
get ZIP byte TOC_FILE
else
get ZSIZE longlong TOC_FILE
get SIZE longlong TOC_FILE
get ZIP long TOC_FILE
endif
if WORKAROUND == 1
getdstring HASH 20 TOC_FILE
elif VERSION <= 1
get TSTAMP longlong TOC_FILE
endif
if WORKAROUND == 2
else
getdstring HASH 20 TOC_FILE
endif
math CHUNKS = 0
math ENCRYPTED = 0
if VERSION >= 3
if ZIP != 0
get CHUNKS long TOC_FILE
for x = 0 < CHUNKS
get CHUNK_OFFSET longlong TOC_FILE
get CHUNK_END_OFFSET longlong TOC_FILE
putarray 0 x CHUNK_OFFSET
putarray 1 x CHUNK_END_OFFSET
next x
endif
if WORKAROUND == 2
else
get ENCRYPTED byte TOC_FILE
endif
get CHUNK_SIZE long TOC_FILE
endif
if WORKAROUND == 1
if ARCHIVE_NAME == "0" # HIT game only!
math ENCRYPTED = 0
endif
endif
if ALTERNATIVE_MODE != 0
savepos TMP_OFF TOC_FILE
math OFFSET + TMP_OFF
endif
#comtype copy # for AES, do not enable or quickbms 0.9.2 will fail
if ZIP == 3 # JoyfunRPG / Faith of Danschant
comtype oodle
elif ZIP & 1
comtype zlib
elif ZIP & 2
comtype gzip
elif ZIP & 4
comtype snappy
if VERSION >= 6
comtype oodle
endif
if WORKAROUND == 2
comtype lz4
endif
elif ZIP & 0x10
comtype oodle
else
math ZIP = 0
endif
if CHUNKS > 0
log NAME 0 0
append
math TMP_SIZE = SIZE
if CHUNK_OFFSET_ABSOLUTE < 0 && OFFSET != 0
getarray CHUNK_OFFSET 0 0
if CHUNK_OFFSET u< OFFSET || VERSION >= 5
math CHUNK_OFFSET_ABSOLUTE = 0
else
math CHUNK_OFFSET_ABSOLUTE = 1
endif
endif
for x = 0 < CHUNKS
getarray CHUNK_OFFSET 0 x
getarray CHUNK_END_OFFSET 1 x
math CHUNK_ZSIZE = CHUNK_END_OFFSET
math CHUNK_ZSIZE - CHUNK_OFFSET
math CHUNK_XSIZE = CHUNK_ZSIZE
if ENCRYPTED != 0
callfunction SET_AES_KEY 1
math CHUNK_XSIZE x 16
endif
if TMP_SIZE u< CHUNK_SIZE
math CHUNK_SIZE = TMP_SIZE
endif
if CHUNK_OFFSET_ABSOLUTE == 0
math CHUNK_OFFSET + OFFSET
endif
if ZIP == 0
log NAME CHUNK_OFFSET CHUNK_SIZE 0 CHUNK_XSIZE
else
clog NAME CHUNK_OFFSET CHUNK_ZSIZE CHUNK_SIZE 0 CHUNK_XSIZE
endif
math TMP_SIZE - CHUNK_SIZE
next x
append
else
# the file offset points to an entry containing
# the "same" OFFSET ZSIZE SIZE ZIP HASH ZERO fields,
# just an additional backup... so let's skip them
savepos BASE_OFF TOC_FILE
math BASE_OFF - TMP_OFF
math OFFSET + BASE_OFF
math XSIZE = ZSIZE
if ENCRYPTED != 0
callfunction SET_AES_KEY 1
math XSIZE x 16
endif
if ZIP == 0
log NAME OFFSET SIZE 0 XSIZE
else
clog NAME OFFSET ZSIZE SIZE 0 XSIZE
endif
endif
encryption "" ""
if ALTERNATIVE_MODE != 0
math OFFSET + ZSIZE
goto OFFSET
if OFFSET == MAX_OFF
break
endif
if VERSION >= 4
padding 0x800 # necessary for WitchIt
endif
endif
next i
startfunction SET_AES_KEY_ASK
math AES_KEY_IS_SET = 1
print "The archive is encrypted, select the number of the key to use or type yours:"
for z = 0
getarray KEY 10 z
if KEY == ""
break
endif
print "%z%: %KEY%"
next z
print "%z%: press RETURN for no encryption (Lineage 2 Revolution)"
set KEY unknown "???"
strlen TMP KEY
if KEY == ""
math AES_KEY_IS_SET = -1
set AES_KEY string "no key, encryption disabled"
elif TMP <= 2
getarray AES_KEY 10 KEY
if AES_KEY strncmp "0x"
string AES_KEY << 2
string AES_KEY h AES_KEY
endif
elif KEY strncmp "0x"
string KEY << 2
string AES_KEY h KEY
else
set AES_KEY binary KEY
endif
print "KEY: %AES_KEY%"
endfunction
startfunction SET_AES_KEY
if AES_KEY_IS_SET == 0
callfunction SET_AES_KEY_ASK 1
endif
if AES_KEY_IS_SET > 0
encryption aes AES_KEY "" 0 32
endif
endfunction
startfunction GET_NAME
get NAMESZ signed_long TOC_FILE
if NAMESZ >= 0
if NAMESZ > 0x200
math ALTERNATIVE_MODE = 1
else
getdstring NAME NAMESZ TOC_FILE
endif
else
math NAMESZ n NAMESZ
if NAMESZ > 0x200
math ALTERNATIVE_MODE = 1
else
math NAMESZ * 2
getdstring NAME NAMESZ TOC_FILE
set NAME unicode NAME
endif
endif
endfunction