I just cannot print a simple IP address with the TFT_eSPI library

[Rollmops67]

Hello !
I'm new to the TFT_eSPI library, and because of a serious lack of documentation I struggle to even print a simple IP address...
I'm using a Lilygo T-Display board with an integrated LCD screen and an ESP32-S3 processor.

For example, if I write this simple code (with output to the serial monitor) to connect to my WiFi :

#include <WiFi.h>

const char* ssid     = "mySSID";
const char* password = "myPASSWORD";

void setup() {
  Serial.begin(115200);
  Serial.print("Connecting to WiFi ..");
  
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
    {
      Serial.print(".");
      delay(250);
    }
  Serial.println();
  Serial.println(WiFi.localIP());
  Serial.println(WiFi.macAddress());
  Serial.println(WiFi.gatewayIP());
  Serial.println(WiFi.subnetMask());
  }

void loop() {}

Then on the serial monitor I have this result :

Connecting to WiFi ............
192.168.1.131
34:85:18:8B:B2:48
192.168.1.1
255.255.255.0

Nothing but normal...

Now I try to adapt this code so it prints on the LCD screen of the Lilygo T-display, and it looks like that :

#include <TFT_eSPI.h> 
#include <WiFi.h>

TFT_eSPI tft = TFT_eSPI(); 

const char* ssid     = "mySSID";
const char* password = "myPASSWORD";

void setup() {
  
  tft.init();
  tft.setRotation(3);
  tft.fillScreen(TFT_BLACK);
  tft.drawString("Connecting to WiFi ..",10,10,2);
  
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
    {
      delay(250);
    }
tft.drawString(String(WiFi.localIP()),10,46,2);
tft.drawString(String(WiFi.macAddress()),10,62,2);
tft.drawString(String(WiFi.gatewayIP()),10,78,2);
tft.drawString(String(WiFi.subnetMask()),10,94,2);
  }

void loop() {}

And this is the result I get on my LCD screen :

Connecting to WiFi ..

2197924032
34:85:18:8B:B2:48
16885952
16777215

IP address, gateway address aud subnet mask look just weird...
I think the solution is very simple, it's surely in the syntax, but as I said, without serious documentation, in regard to the huge list of keywords, I'm lost...

Thank you in advance for any help !

Roland

[Bodmer]

This is not something I would cover in any TFT_eSPI documentation because it comes down to understanding variable typedef handling.

The Arduino print class has probably been extended by the WiFi library so that it understands how to print a "typedef IPAddress" number in the IP address format. The String class has no such understanding, so simply converts the IP address to a number and the TFT library then correctly prints what it is given.

You have a couple of options depending on the processor you are using and its associated support library functions.

For an ESP32 this should work:

tft.drawString( WiFi.localIP().toString(), 10, 46, 2 );

Alternatively the TFT_eSPI library has commented examples which show how to use the print class (which in this case understands how to format the IP address). The above could be replaced by:

tft.setTextFont(2);
tft.setCursor(10, 46);
tft.print(WiFi.localIP());  // println would move cursor to next line.

Essentially just replace Serial.print with tft.print

The TFT_eSPI library is compatible with the basic capability of the Adafruit_GFX library so this may help you get off the ground:
https://learn.adafruit.com/adafruit-gfx-graphics-library/coordinate-system-and-units

[Rollmops67]

Thank you Bodmer for the fast reply !
I new for the the possibility with "tft.print(WiFi.localIP())", the problem is that with "tft.print" the font size is very little and when I set it to "tft.setTextSize(2)" it's allready too big ! (and not very nice to the eyes)
But at least I understand that the problem comes from String class.
"tft.drawString( WiFi.localIP().toString(), 10, 46, 2 );" works perfectly.

If you allow another dumb question :
When using "tft.print" without writing a "tft.setCursor" between 2 print commands, the second prints just after the first on the screen (what is normal and very convenient)
With "tft.drawString", I have to put x and y coordinates in the command line.
To achieve the same behaviour as with 2 following "tft.print" commands, I tried to let the x and y coordinates empty in the second "tft.drawString" command, but I end with an error when compiling.
Is there a simple way to print a second "tft.drawString" command directly after the previous "tft.drawString" ?

Roland

[Bodmer]

With tft.print.. you can set the font to use. That is why I included tft.setTextFont(2); in the example code above.

The coordinates need to be defined for each string, except for when using println, which moves the cursor automatically to the start of the next line.

If I understand your question.... The tft.drawString function returns the x coordinate distance to the end of the drawn string. So this can be used to position the next string at the end of the previous one:

uint16_t dx = tft.drawString( "Hello ", 10, 46, 2 );
tft.drawString( "World!", 10 + dx, 46, 2 );

[Rollmops67]

Wow, you are a genius (and I still have a lot to learn)
I tried it with "getCursorX" but it allways returns 0.

Many thanks again, I just learn to appreciate your TFT_eSPI library.

Regards from France, Roland

[Bodmer]

drawString does not use or change the cursor position, that is only relevant to tft.print to position the text.

Enjoy using the library, there are lots of examples to run which demostrate the capabilites and functions.

[Rollmops67]

I am now at the moment where I ask myself what is the difference between "tft.drawString" and "tft.print" (apart of the different syntax) and when to use either "drawString" or "print".
Is there a gain in speed with the displaying of text on the screen ?
Or other differences I'm not aware of ?

Roland