[Bug] SuggestionEditor- cannot stop editing with Enter

[hyyan]

By Rick van Baalen

After searching for a title and picking a title from the SuggestionEditor dropdown, you can’t press enter to stop the Full Row Editing. The only way to leave this column is with TAB or click in a different column.

Sample Program

use ::BBjGridExWidget/BBjGridExWidget.bbj::BBjGridExWidget
use ::BBjGridExWidget/GxCellEditors.bbj::GxCellEditorSuggestionResolver
use ::BBjGridExWidget/GxCellEditors.bbj::GxCellEditorSuggestion
use com.basiscomponents.db.ResultSet
use com.basiscomponents.bc.SqlQueryBC
use java.util.UUID

class public CustomResolver extends GxCellEditorSuggestionResolver
    
    method public void doResolve(BBjString term!)
      declare SqlQueryBC sbc!
      declare ResultSet rs!
      query! = ""
      query! = query! + "    SELECT"
      query! = query! + "        TITLE,"
      query! = query! + "        MUSICTYPE "
      query! = query! + "    FROM"
      query! = query! + "        CDINVENTORY "
      query! = query! + "    WHERE"
      query! = query! + "        CVS(TITLE,8) LIKE CVS('%s%%',8) "
      query! = query! + "    ORDER BY"
      query! = query! + "        MUSICTYPE"
      
      sbc! = new SqlQueryBC(BBjAPI().getJDBCConnection("CDStore"))
      
      rs! = sbc!.retrieve(String.format(query!, term!))
      if(rs! <> null() and rs!.count() > 0)
        it! = rs!.iterator()
        while it!.hasNext()
            next! = it!.next()
            label! = String.format("%s", next!.getFieldAsString("TITLE"))
            value! = next!.getFieldAsString("TITLE")

            rem add suggestion
            #addItem(label!, value!)
        wend
      fi
    methodend
    
classend

wnd! = BBjAPI().openSysGui("X0").addWindow(20, 20, 1000, 600, "SuggestionEditor")
wnd!.setCallback(BBjAPI.ON_CLOSE,"byebye")
wnd!.setCallback(BBjAPI.ON_RESIZE,"resize")

gosub main

process_events

main:
    declare SqlQueryBC sbc!
    declare ResultSet rs!
    declare BBjGridExWidget grid!
    
    sbc! = new SqlQueryBC(BBjAPI().getJDBCConnection("CDStore"))
    rs! = sbc!.retrieve("SELECT TOP 10 CDNUMBER, TITLE, PLAYINGTIME, PLAYINGTIME as PLAYINGTIMEINHOURS, ARTIST FROM CDINVENTORY")
    
    grid! = new BBjGridExWidget(wnd!, 100, 0, 0, 1000, 600)
    grid!.getOptions().setEditable(1)
    grid!.getOptions().setEditType(grid!.GRID_EDITTYPE_ROW())
    grid!.setFitToGrid()
    
    grid!.addColumn("CDNUMBER", "CDNUMBER")
    grid!.addColumn("TITLE", "TITLE")
    grid!.addColumn("PLAYINGTIMEINHOURS", "Time in hours")
    
    column! = grid!.addColumn("PLAYINGTIME", "Time in minutes")
    exp! = "data.PLAYINGTIME = newValue; data.PLAYINGTIMEINHOURS = (newValue / 60).toFixed(2); return true;"
    column!.setValueSetterExpression(exp!)
    
    grid!.addColumn("ARTIST", "ARTIST")
    
    grid!.setData(rs!)
    
    editor! = new GxCellEditorSuggestion(UUID.randomUUID().toString(), new CustomResolver())
    editor!.setEmptyMessage("No data to display")
    editor!.setMinLength(1)
    editor!.setShowOnFocus(1)
    editor!.setWidth(300)
    
    column! = grid!.getColumn("TITLE")
    column!.setCellEditor(editor!)
return

resize:
    ev! = BBjAPI().getLastEvent()
    w = ev!.getWidth()
    h = ev!.getHeight()
    grid!.setSize(w,h)
return

byebye:
    bye