#version 150
//OVE shader_name: Door way
//OVE shader_description: by gre (Licence MIT)


//OVE name: Reflection
//OVE type: FLOAT
//OVE flag: NOT_CONNECTABLE
//OVE min: 0.0
//OVE max: 1.0
//OVE default: 0.3
//OVE description:
uniform float reflection;

//OVE name: Perspective
//OVE type: FLOAT
//OVE flag: NOT_CONNECTABLE
//OVE min: 0.0
//OVE max: 1.0
//OVE default: 0.4
//OVE description:
uniform float perspective;

//OVE name: Depth
//OVE type: FLOAT
//OVE flag: NOT_CONNECTABLE
//OVE min: 0
//OVE default: 3
//OVE description:
uniform float depth;


//OVE end

#define LINEAR_CURVE 0
#define EXPONENTIAL_CURVE 1
#define LOGARITHMIC_CURVE 2

uniform sampler2D out_block_in;
uniform sampler2D in_block_in;
uniform bool out_block_in_enabled;
uniform bool in_block_in_enabled;
uniform int curve_in;

/* animated from 0 to 1 */
uniform float ove_tprog_all;

in vec2 ove_texcoord;
out vec4 frag_color;

vec4 getFromColor( vec2 p)
{
  return texture( in_block_in, p);
}

vec4 getToColor( vec2 p)
{
  return texture( out_block_in, p);
}

float TransformCurve(float linear) {
  if (curve_in == EXPONENTIAL_CURVE) {
    return linear * linear;
  } else if (curve_in == LOGARITHMIC_CURVE) {
    return sqrt(linear);
  } else {
    return linear;
  }
}


const vec4 black = vec4(0.0, 0.0, 0.0, 1.0);
const vec2 boundMin = vec2(0.0, 0.0);
const vec2 boundMax = vec2(1.0, 1.0);

bool inBounds (vec2 p) {
  return all(lessThan(boundMin, p)) && all(lessThan(p, boundMax));
}

#define SCALE_FAC  0.8
#define LIFT  0.04

vec2 project (vec2 p) {
  return vec2(p.x, - p.y) * vec2(1.0, SCALE_FAC) + vec2(0.0, 1.0 + SCALE_FAC + LIFT);
}

vec4 bgColor (vec2 p, vec2 pto) {
  vec4 c = black;
  pto = project(pto);
  if (inBounds(pto)) {
    c += mix(black, getToColor(pto), reflection * mix(0.0, 1.0, pto.y));
  }
  return c;
}


vec4 transition (vec2 p, float progress) {
  vec2 pfr = vec2(-1.), pto = vec2(-1.);
  float middleSlit = 2.0 * abs(p.x-0.5) - progress;
  if (middleSlit > 0.0) {
    pfr = p + (p.x > 0.5 ? -1.0 : 1.0) * vec2(0.5*progress, 0.0);
    float d = 1.0/(1.0+perspective*progress*(1.0-middleSlit));
    pfr.y -= d/2.;
    pfr.y *= d;
    pfr.y += d/2.;
  }
  float size = mix(1.0, depth, 1.-progress);
  pto = (p + vec2(-0.5, -0.5)) * vec2(size, size) + vec2(0.5, 0.5);
  if (inBounds(pfr)) {
    return getFromColor(pfr);
  }
  else if (inBounds(pto)) {
    return getToColor(pto);
  }
  else {
    return bgColor(p, pto);
  }
}


void main(void) {
    frag_color = transition( ove_texcoord.xy, TransformCurve(1.0 - ove_tprog_all));
}